Redimentionner Commentaire

[kknd04]

Bonjour a tous,

Je suis tout nouveau sur le forum, en fait cela fait quelque temps que j'utilise Excel de mieux en mieux
D'habitude je trouve mes réponses en parcourant des forums comme le votre, et, le votre bien sur, mais sans jamais avoir besoin de poser une question, jusqu’a aujourd'hui lol

Voila, en fait j'ai créé un classeur Excel avec plusieurs feuilles contenant entre autre, des cases avec des commentaires don le fond correspond a une photo (pour qu'au passage de la sourie elle s'affiche)
Tout était nickel, de bonne taille, jusqu'au jour ou Excel décida de me les redimensionner tout seul (me demandez pas pourquoi...)

Ma question est donc comment redimensionner des commentaires, mais en série, sans effacer les photos. Car en effet ces commentaires sont au nombre de +/- 1000 je me vois vraiment pas me retaper ca un par un.

merci de votre aide... AIDEZ MOIIIII

 

[Roland_M]

Re : Redimentionner Commentaire

bonjour

si j'aui bien compris !?
tu doucle clic sur le commentaire et dans les propriétés
"alignement" tu coches taille automatique

EDIT: excuses j'avais pas bien tout lu tu en as 1000 !
là il faudrait un macro !
si j'ai encore un peu de temps je te prépare cela !

 

[mromain]

Re : Redimentionner Commentaire

bonjour,

voici un petit code à adapter :

Sub test()
Dim curCell As Range
For Each curCell In ThisWorkbook.Sheets("Feuil1").Cells.SpecialCells(xlCellTypeComments)
    curCell.Comment.Shape.Width = 150
    curCell.Comment.Shape.Height = 100
Next curCell
End Sub

il fixe les dimensions de tous les commentaires de la feuille.

a+

 

[Pierrot93]

Re : Redimentionner Commentaire

Bonjour kknd, Roland

regarde le code ci-dessous, si j'ai bien compris, boucle sur tous les commentaires de la feuille active :

Option Explicit
Sub test()
Dim c As Comment
For Each c In ActiveSheet.Comments
    c.Shape.OLEFormat.Object.AutoSize = True
Next c
End Sub

bon après midi
@+

 

[Roland_M]

Re : Redimentionner Commentaire

re

pour toute les feuilles du classeur

Sub Macro1()
Dim Sh As Worksheet, Comm As Comment
For Each Sh In Worksheets
    For Each Comm In Sh.Comments
        Comm.Shape.OLEFormat.Object.AutoSize = True
    Next
Next
End Sub

EDIT: Salut mromain, Pierrot93

 

[jetted]

Re : Redimentionner Commentaire

Un autre variante

Sub CommentFitter2()
    Application.ScreenUpdating = False
    Dim x As Range, y As Long
    For Each x In Cells.SpecialCells(1)
        Select Case True
        Case Len(x.NoteText) <> 0
            With x.Comment
                .Shape.TextFrame.AutoSize = True
                If .Shape.Width > 250 Then
                    y = .Shape.Width * .Shape.Height
                    .Shape.ScaleHeight 0.9, msoFalse, msoScaleFromTopLeft
                    .Shape.ScaleWidth 1#, msoFalse, msoScaleFromTopLeft
                End If
            End With
        End Select
    Next x
    Application.ScreenUpdating = True
End Sub

 

[kknd04]

Re : Redimentionner Commentaire

Et bin, ca en fait des réponses en si peu de temps, MERCI BEAUCOUP

OUPS, j'ai pas précisé que je suis sous excel 2007, je sais pas si ca change quelque chose...

Bon alors je vais essayer tout ca, par contre les codes macro, je suis une branque, sais même pas ou je les places...

Avec vos méthodes, tous les commentaires d'une feuille retrouves la même taille, et ce, sans effacer la couleur de fond qui sont toutes des photos différentes...

Je vous tiens au courant

Merci encore

 

[kknd04]

Re : Redimentionner Commentaire

re,

Bon alors le "double clic sur le commentaire et dans les propriétés
"alignement" tu coches taille automatique"
Marche pas du tout lol

Les macros, j'essaye, mais ca m'a l'air compliqué...
Je vais poser une question surement tres bête, mais je dois changer quoi dans celles que vous m'avez donné pour les adapter?

re re,

Bon, alors ca y est je viens de réussir a faire fonctionner une macro sur une feuille, bon pas encore la bonne dimension, mais ca a tout changé... COOL

C'est bon NIKEL chui super content lol
Par contre c'est bizarre, ils ne peuvent pas êtres sauvegardés... M'enfin au moins c'est redimensionné

Merci, grand Merci a vous tous, vous m'avez enlevé une grosse épine du pied me voyais pas du tout passer des heures pour tout redimensionner lol mdr

 

[kknd04]

Re : Redimentionner Commentaire

Heu, HéHéHé, je m'épate tellement je suis nul sur se coup la...

J'avais des feuilles avec des commentaires dont la taille devait être différentes...

Exemple colonne "B" 100/150
Colonne "A" 300/300

Et bien sur, le macro, j'ai pas fais gaffe et ils sont tous en 100/150...

Peut on demander a redimensionner QUE les commentaires d'une colonne?

PS j'ai utilisé la macro de mromain

Sub test()
Dim curCell As Range
For Each curCell In ThisWorkbook.Sheets("Feuil1").Cells.SpecialCells(xlCellTypeComments)
curCell.Comment.Shape.Width = 150
curCell.Comment.Shape.Height = 100
Next curCell
End Sub

C'est la seul que j'ai compris

 

[Pierrot93]

Re : Redimentionner Commentaire

Bonjour,

pour la colone A par exemple, modifies ainsi :

For Each curCell In ThisWorkbook.Sheets("Feuil1").[B][COLOR="Red"]Range("A:A")[/COLOR][/B].SpecialCells(xlCellTypeComments)

bon après midi
@+

 

[kknd04]

Re : Redimentionner Commentaire

si vous n'existiez pas faudrais vous inventer lol ca marche parfaitement

Merci