Aperçu avant impression d'un UserForm voir d'une Frame dans un UserForm Possible?

[glemoin]

Bonjour,
Alors je vous explique ma situation, j'ai un fichier Excel sur lequel j'ai créé des UserForm et je souhaiterais pouvoir faire un aperçu avant impression de ceux-ci voir d'une Frame à l'intérieur d'un UserForm.
Es ce que cela parait possible ?
Par ce que la je cale, j'ai trouvé la solution pour imprimer le UserForm mais pas d'aperçu ni de possibilité d'imprimer une Frame.

Je remercie d'avance celui qui va surement trouvé la solution

Cordialement

 

[PMO2]

Re : Aperçu avant impression d'un UserForm voir d'une Frame dans un UserForm Possible

Bonjour,

Pour ce qui concerne le UserForm essayez la démarche suivante

1) créez un UserForm1 avec un CommandButton1
2) copiez le code suivant dans la fenêtre de code du UserForm

Private Declare Sub keybd_event Lib "user32" ( _
  ByVal bVk As Byte, ByVal bScan As Byte, _
  ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Sub CommandButton1_Click()
keybd_event vbKeySnapshot, 1, 0&, 0&
DoEvents
Set ShApercu = Sheets.Add
ShApercu.Paste
With ShApercu.PageSetup
  .CenterHorizontally = True
  .CenterVertically = True
End With
Application.OnTime Now + TimeValue("00:00:00"), "ApercuImpression"
Unload Me
End Sub

3) copiez le code suivant dans un module standard

Public ShApercu As Worksheet

Sub LanceUserForm()
UserForm1.Show
End Sub

Sub ApercuImpression(Optional dummy As Byte)
ActiveWindow.SelectedSheets.PrintPreview
Application.DisplayAlerts = False
ShApercu.Delete
Application.DisplayAlerts = True
Set ShApercu = Nothing
End Sub

4) lancez la macro LanceUserForm

Ce n'est pas l'idéal mais cela a le mérite de faire.

Cordialement.

PMO
Patrick Morange