Transformer un tableau double entrée en bdd - VBA

[varchamb]

Bonjour,

Comme le sujet l'indique, je cherche à transformer un tableau double entrée en bdd (avec du VBA). J'entends par bdd un tableau en liste, c'est à dire, uniquement avec des colonnes (le but étant de pouvoir réalisé un tcd avec les données).
L'exemple ci-joint est très parlant.

J'ai vu un sujet dans le forum qui s'approche de ma demande mais ce n'est pas tout à fait la même chose. Ne serait-ce parce que pour ma part, j'aimerai que les lignes dont la valeur est 0 n'apparaissent pas dans le tableau bdd.

Merci d'avance,

 

[Efgé]

Re : Transformer un tableau double entrée en bdd - VBA

Bonjour,
Une proposition
Le tableau est sur la feuille test et la liste créee sur la feuille Liste

Sub test()
Dim i&, j&, k&, Rw&, Col&, T As Variant
k = 1
With Sheets("Test")
    Rw = .Cells(Rows.Count, 1).End(xlUp).Row
    Col = .Cells(1, Columns.Count).End(xlToLeft).Column
    ReDim T(1 To (Rw * Col), 1 To 3)
    T(1, 1) = "Nom"
    T(1, 2) = "Projet"
    T(1, 3) = "Temps"
    For j = 2 To Col
        For i = 2 To Rw
            If .Cells(i, j).Value < > 0 Then
                k = k + 1
                T(k, 1) = .Cells(1, j).Value
                T(k, 2) = .Cells(i, 1).Value
                T(k, 3) = .Cells(i, j).Value
            End If
        Next i
    Next j
End With
With Sheets("Liste")
    .UsedRange.Clear
    .Cells(1, 1).Resize(k, 3) = T
    .Activate
End With
End Sub

Cordialement

 

[varchamb]

Re : Transformer un tableau double entrée en bdd - VBA

Excellente macro, qui fonctionne très bien.

MERCI Efgé

 

[YNEE]

Excellent, je vais faire de grandes choses a partir de ce macro