cherche formule complexe de calcul...

[Baroud]

Bonjour,
Je réalise actuellement un carnet informatique de suivi et de gestion du carburant pour une flotte de véhicules.
J’ai déjà rédigé la majorité des formules, afin d’en ressortir les données dont j’ai besoins mais je bloque sur la dernière.
Vous trouverez bien sur le fichier en PJ.
Je rentre en O ma flotte de véhicules que je peux sélectionner en E par un menu déroulant. En P leurs kilométrages à T+0, c'est-à-dire à partir de la date de lancement du programme, et je n’y toucherais plus.
Je voudrais que lorsque je rentre un kilométrage dans la colonne G, suivant l’engin sélectionné en E, s’affiche en H les Kms parcourus.
Facile, me direz vous…effectivement j’ai dans ces cellules une formule qui fait cela mais elle reprend à chaque fois les Kms d’origines.
Exemple :
Je démarre pour un VSAB avec un compteur à 50 Kms :

Engin Litres Kilométrage Km parcourus

VSAB 60 100 50
FPT 60 1 000 100
FPT 60 1 110 210
CCF 60 1 060 810
VSAB 12 120 70


Pour la première ligne c’est bon, j’ai bien fait 50 bornes, mais pour la cinquième ligne rouge je voudrais voir apparaitre 20.
Amusez vous avec le fichier, pour mieux comprendre car je ne sais pas si j’ai été bien clair.
Merci de l’aide que vous pourrez m’apporter.
Cordialement ; Jérôme.

 

[KenDev]

Re : cherche formule complexe de calcul...

Bonjour Baroud,

Une proposition par formule matricielle (à valider avec CTRL+MAJ+ENTER), en H20

=SI(NB.SI(E$20:E20;E20)=1;SOMMEPROD((O$1:O$7=E20)*(P$1:P$7));G20-INDEX(G:G;MAX(SI(E19:E$20=E20;LIGNE(19:$20)))))

et faire glisser.

Cordialement

KD

 

[Tibo]

Re : cherche formule complexe de calcul...

Bonjour,

J'ai un peu cherché, donc je livre quand même. Il y a des similitudes avec la solution de KenDev :

=SI(NB.SI($C$20:$C20;$C20)=1;-RECHERCHEV($C20;$N$1:$O$7;2;0);0)+G20-INDEX($G$1:$G20;MAX(($C$19:C19=C20)*LIGNE($C$19:C19)))

Matricielle également, donc à valider par CTRL + MAJ + ENTREE

@+

 

[tototiti2008]

Re : cherche formule complexe de calcul...

Bonjour Baroud, Bonjour KenDev, Bonjour Tibo,

Allez, ma version pour compléter
toujours matriciel

=G20-SI(NB.SI($E$17:E19;E20)=0;RECHERCHEV(E20;$O$1:$P$7;2;FAUX);INDEX($G$1:G19;MAX(LIGNE($E$17:E19)*($E$17:E19=E20))))

Edit : Bonjour hoerwind, bien vu

 

[hoerwind]

Re : cherche formule complexe de calcul...

Bonjour, salut les autres,

Essaie cette formule non matricielle en H20 :

=G20-RECHERCHEV(E20;$O$1:$P$7;2;0)-SOMME.SI(E$19:E19;E20;H$19:H19)

à copier vers le bas

Elle renvoie les mêmes résultats que celle de tototiti, je n'ai pas testé les autres.

 

[Baroud]

Re : cherche formule complexe de calcul...

Bonsoir,
un grand merci pour vôtre réactivité...et vôtre serieux coup de main, c'était vraiment la partie bloquante de mon fichier.
Grace à vous je vais pouvoir sauver des arbres.
Cordialement; Jérôme.