ajouter nouvelle commande dans le menu contextuel du clic droit

[pascal21]

bonjour
me revoila avec mes drôles de questions
je cherche le moyen de colorer le fond de la cellule active par le menu contextuel
je pourrais le faire sur clic droit mais ça me bloquerait les autres commandes du menu contextuel
c'est pour cela que je pensais rajouter cette commande au menu
je crois qu'il s'agit d'une macro complémentaire
si ça pose un problème de la rajouter au menu, il doit être possible de la mettre sur la barre de menu
donc pour résumer
je cherche à mettre un bouton qui me fera colorer la cellule active en jaune clair
c'est peut-être tout simple à faire mais je ne vois pas comment on procède
merci

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

j'ai fini par trouver comment faire pour créer un nouveau bouton dan la barre de menu
il ne me reste plus qu'a le réserver au seul classeur concerné

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

Bonjour

une possibilté avec le click droit dans des plages déterminées
a mettre dans le module de la feuille

Option Explicit
'Ici sur l'évènement Clique droit !!
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Not Application.Intersect(Target, Range("C1:C30, E1:E30")) Is Nothing Then
Cancel = True
MsgBox "Parfait pour le click droit de 'C1:C30, E1:E30'"
ActiveCell.Interior.Color = 65535
End If
End Sub

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

sinon il y a cette possibilité à l'ouverture et à la fermeture du classeur pour avoir une ligne sup en bas dans le menu contextuel du click droit
à mettre dans le thisworkbook

Option Explicit
'-----------------------------------------------------------------------------------
Private Sub Workbook_Open()
Dim BtnC As CommandBarButton
     On Error Resume Next
    Set BtnC = Application.CommandBars("Cell").Controls("letruc")
    On Error GoTo 0
    If BtnC Is Nothing Then
        With Application.CommandBars("Cell").Controls.Add(msoControlButton, , , , True)
           .Caption = "letruc"
           .BeginGroup = True
           .FaceId = 100 ' n° de l'icone
            .Style = msoButtonIconAndCaption
           .OnAction = "macro"
        End With
    End If
   End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    If Me.Saved = False Then Me.Save
    Application.CommandBars("Cell").Controls("letruc").Delete
    On Error GoTo 0
    End Sub

sub macro()
activecell.interior.color = 65535
end sub

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

bonjour Gilbert merci
je vais essayer la 2eme solution pour voir ce que ça donne

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

bonjour Gilbert merci
je vais essayer la 2eme solution pour voir ce que ça donne

voilà un fichier test

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

pour avoir le n° des icones disponibles

Ce lien n'existe plus

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

re
ça fonctionne mais je n'arrive pas à changer la couleur du fond
j'ai mis 42 pour avoir un bleu et ça ne ma donne que du noir

 

[MJ13]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

Bonjour à tous

Pour les couleurs, le mieux est de passer par les couleurs RGB pour éviter les surprises entre les versions .

 

[JCGL]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

Bonjour à tous,
Salut Gilbert,
Salut Michel,

Dans le code "Macro" de Gilbert :

ActiveCell.Interior.ColorIndex = 42

A + à tous

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

re
ça fonctionne mais je n'arrive pas à changer la couleur du fond
j'ai mis 42 pour avoir un bleu et ça ne ma donne que du noir

pour simplifier tu peux mettre en colorindex

oups bonjour JCGL

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

bonjour à tous
c'est tout bon
j'ai mis colorindex comme vous l'avez suggéré
pour les faceid j'avais regardé sur le web et j'ai trouvé un tableau avec toutes les possiblités
bonne journée

edit:
je sens que je vais en mettre partout je vais avoir le menu clic le plus long du monde
sans dec.... c'est finalement bien pratique les boutons n'envahissent pas l'écran et ce n'est pas compliqué à mettre en oeuvre

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

Private Sub Workbook_Open()
'Sheets("planning").Activate


Dim BtnC As CommandBarButton 'bouton menu clic droit colore cellule quand ordre transmis au chauffeur
On Error Resume Next
Set BtnC = Application.CommandBars("Cell").Controls("ordre transmis")
On Error GoTo 0
If BtnC Is Nothing Then
With Application.CommandBars("Cell").Controls.Add(msoControlButton, , , , True)
.Caption = "ordre transmis"
.BeginGroup = True
.FaceId = 1248 ' n° de l'icone
.Style = msoButtonIconAndCaption
.OnAction = "ordre_donné"
End With
End If
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
On Error Resume Next
If Me.Saved = False Then Me.Save
Application.CommandBars("Cell").Controls("ordre transmis").Delete
On Error GoTo 0
End Sub

bonjour à tous
je reviens avec le code de Gilbert qui ne me permet pas d'avoir le choix de sauvegarder ou pas lors de la fermeture du classeur
j'aimerais garder ce choix
que modifier dans beforeclose pour celà
merci

 

[gilbert_RGI]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

Bonjour


c'est quoi cette ligne

If Me.Saved = False Then Me.Save

saved = Cette propriété a la valeur True si le classeur spécifié n'a pas été
modifié depuis son dernier enregistrement. Type de données Boolean en
lecture-écriture.

save = Cette méthode enregistre les modifications apportées au classeur spécifié

si cette méthode ne convient pas mettre une boite de dialogue du genre

Application.Dialogs(xlDialogSaveAs).Show

 

[pascal21]

Re : ajouter nouvelle commande dans le menu contextuel du clic droit

bonsoir et merci gilbert
je n'y avais pas regardé de très pres lorsque j'ai posté, car j'avais trouvé la solution peu après et oublié de revenir le signaler
j'ai en fait supprimé la ligne en question
bonne soirée