XL pour MAC Fonctions du plus grand cumul en fonction de deux critères

[Dous]

Bonjour les excel addict, j'ai ce fichier ci-joint (TRG) où jai des TNP (Temps de Non Production) notées sur plusieurs journée de fabrication sur différents types de matériels.
Je souhaite maintenant connaître les fonctions qui me permettront de savoir : quelle machine a crée le plus de TNP (panne) sur 2015 ? Quel CE (chef d'équipe) a généré le plus de TNP (panne) sur l'année 2015 ? et les deux machines qui ont coûté le plus cher sur l'année 2016 ?

Merci d'avance

 

[JHA]

Bonjour à tous,

Un début de piste.

JHA

 

[job75]

Bonjoour Dous,

Voyez le fichier joint et les résultats demandés en N2:N5.

Les formules nécessitent les 3 colonnes auxiliaires I J K.

Salut JHA,.

A+

 

[job75]

En fait on peut utiliser une formule non matricielle en N5 :

=INDEX(D:D;EQUIV(MAX((K2:K22<MAX(K:K))*K2:K22);K:K;0))

 

[job75]

Les 2 premiers coûts peuvent être égaux alors il faut revenir à une formule matricielle en N5 :

=INDEX(D2:D22;EQUIV(MAX((D2:D22<>N4)*K2:K22);(D2:D22<>N4)*K2:K22;0))

Pour tester mettez 200 en G20.

 

[Dous]

Les 2 premiers coûts peuvent être égaux alors il faut revenir à une formule matricielle en N5 :

=INDEX(D2:D22;EQUIV(MAX((D2:D22<>N4)*K2:K22);(D2:D22<>N4)*K2:K22;0))

Pour tester mettez 200 en G20.

Bonjour Job75, merci pour ta formule qui marche bien sauf que dans le fichier avec lequel je travaille, il me faut les 8 premieres valeurs sur une longue plage de valeurs. J'ai essayé ta formule mais quand je tire, elle me renvoie les deux plus grandes valeurs de la plage à chaque fois. As-tu une formule à réadapter pour les 8 plus grandes valeurs ? merci

 

[Dous]

Bonjour à tous,

Un début de piste.

JHA

Merci JHA

 

[job75]

Bonjour Job75, merci pour ta formule qui marche bien sauf que dans le fichier avec lequel je travaille, il me faut les 8 premieres valeurs sur une longue plage de valeurs.

Ce n'est pas la question initiale, désolé mais je n'aime pas les questions à rallonge.

 

[Dous]

Ce n'est pas la question initiale, désolé mais je n'aime pas les questions à rallonge.

En fait, je me suis dis qu'en demandant pour les deux premières plus grandes valeurs, je ferai pour les 8 valeurs suivantes (histoire de m'entraîner un peu) en partant de la formule que vous m'aviez donnée :
=INDEX(D2:22;EQUIV(MAX((D2:22<>N4&N5)*K2:K22);(D2:22<>N4&N5)*K2:K22;0))

Malheureusement, ça n'a pas marché. Mais merci tout de même pour vos précédentes réponses.

 

[job75]

Bon puisque vous voulez travailler un peu voyez ce fichier (3) et la formule matricielle en N6 :

=INDEX(D$2:D$22;EQUIV(MAX((D$2:D$22<>N$4)*(D$2:D$22<>N$5)*K$2:K$22);(D$2:D$22<>N$4)*(D$2:D$22<>N$5)*K$2:K$22;0))

à adapter pour les cellules suivantes N7, N8....

 

[job75]

Allez avant d'aller dormir fichier (4) avec cette formule matricielle en N5, à tirer vers le bas :

=INDEX(D$2:D$22;EQUIV(MAX(NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22);NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22;0))

Bonne nuit.

 

[job75]

Bonjour Dous, le forum,

Quand le MAX est nul la formule précédente répète la machine inscrite en D2.

Pour l'éviter utilisez ce fichier (5) avec cette formule matricielle en N5 :

=SIERREUR(INDEX(D$2:D$22;EQUIV(1/(1/MAX(NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22));NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22;0));"")

A+

 

[Dous]

Bon puisque vous voulez travailler un peu voyez ce fichier (3) et la formule matricielle en N6 :

=INDEX(D$2:D$22;EQUIV(MAX((D$2:D$22<>N$4)*(D$2:D$22<>N$5)*K$2:K$22);(D$2:D$22<>N$4)*(D$2:D$22<>N$5)*K$2:K$22;0))

à adapter pour les cellules suivantes N7, N8....

Merci beaucoup Job75, cette formule matricielle marche très bien pour toutes les cellules ainsi j'ai pu extraire les 8premieres valeurs. C'est top, merci encore

 

[Dous]

Bonjour Dous, le forum,

Quand le MAX est nul la formule précédente répète la machine inscrite en D2.

Pour l'éviter utilisez ce fichier (5) avec cette formule matricielle en N5 :

=SIERREUR(INDEX(D$2:D$22;EQUIV(1/(1/MAX(NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22));NON(NB.SI(N$4:N4;D$2:D$22))*K$2:K$22;0));"")

A+

Je vais m'entraîner avec les différentes formules que tu m'as proposées pour ainsi mieux comprendre la différence, merciii