découper en jours

[sangarmatha]

Bonjour,

Suite à une extraction de SAP, j'obtiens une date de début et un nombre d'heures pour les congés par exemple.
J'aimerai découper ce résultat en une liste de date sur la base de 10h/J (si possible par formule) mais je sèche!!!
Exemple ci-joint dans excel
Merci d'avance de votre aide

 

[chris]

Bonjour

Peux-tu préciser ta version Excel et dans ton profil et dans l'en-tête du fil...

 

[sangarmatha]

Bonjour

Peux-tu préciser ta version Excel et dans ton profil et dans l'en-tête du fil...

 

[sangarmatha]

Bonjour,
Office pro plus ou excel 2013, j'ai les 2

 

[Jocelyn]

Bonjour le Forum,
Bonjour sangarmatha, Chris ,

Hum hum faire ce que tu demande de façon verticale je ne vois pas trop par contre le faire horizontalement sur chaque ligne de l'extraction en considérant la première date comme déjà inscrite en essai

Cordialement

 

[sangarmatha]

Merci mais c'est vraiment du vertical dont j'ai besoin sous forme de liste. Ceci car c'est intégré à d'autres valeurs (jusqu'a 200 personnes différentes) pour des indicateurs d'analyse...

 

[Jocelyn]

Re

A ce moment la j'ai bien que le VBA soit la solution, et je suis une bille à ce jeu la alors désolé je passe la main

Cordialement

 

[chris]

Re

Office pro plus c'est une variante mais quelle version ? 2016, 365.

Je demande car faisable avec PowerQuery add on sur 2010 et 2013 et intégré dans 2016

 

[sangarmatha]

C'est Office 365

 

[chris]

Donc PowerQuery intégré

 

[sangarmatha]

Effectivement.... J'ai plus qu'a chercher et essayer de comprendre "powerquery" qui est aujourd'hui une totale découverte.... Merci

 

[job75]

Bonjour sangarmatha, chris, Jocelyn,

Sinon voici 2 méthodes très classiques qui fonctionnent sous toute version Excel.

1) Fichier (1) si le tableau des résultats n'est pas trop grand (quelques centaines de lignes) :

Sub Objectif()
Dim dest As Range, i&
Set dest = [J2] '1er titre de la plage de destination
Application.ScreenUpdating = False
dest(2).Resize(Rows.Count - dest.Row, 7).Delete xlUp 'RAZ
With [A1].CurrentRegion
    For i = 3 To .Rows.Count
        Set dest = dest(2)
        .Rows(i).Copy dest
        While dest(1, 7) > 10
            dest.Resize(, 7).Copy dest(2)
            dest(2, 7) = dest(1, 7) - 10: dest(1, 7) = 10
            dest(2, 6) = dest(1, 6) + 1
            Set dest = dest(2)
        Wend
    Next
End With
With UsedRange: End With 'actualise la barre de défilement verticale
End Sub

L'intérêt de cette méthode c'est que les formats sont copiés.

2) Fichier (1 bis) dans tous les cas :

Sub Objectif()
Dim dest As Range, t, i&, n&, resu(), j%
Set dest = [J2] '1er titre de la plage de destination
t = [A1].CurrentRegion.Offset(2).Resize(, 7)
For i = 1 To UBound(t) - 2
    n = n + 1
    ReDim Preserve resu(1 To 7, 1 To n)
    For j = 1 To 7: resu(j, n) = t(i, j): Next
    While resu(7, n) > 10
        n = n + 1
        ReDim Preserve resu(1 To 7, 1 To n)
        For j = 1 To 7: resu(j, n) = resu(j, n - 1): Next
        resu(7, n) = resu(7, n - 1) - 10: resu(7, n - 1) = 10
        resu(6, n) = resu(6, n - 1) + 1
    Wend
Next
'---transposition---
If n Then
    ReDim t(1 To n, 1 To 7)
    For i = 1 To n
        For j = 1 To 7
            t(i, j) = resu(j, i)
    Next j, i
    If FilterMode Then ShowAllData 'si la feuille est filtrée
    dest(2).Resize(n, 7) = t
End If
'---RAZ sous le tableau---
dest(2).Offset(n).Resize(Rows.Count - n - dest.Row, 7).ClearContents
With UsedRange: End With 'actualise la barre de défilement verticale
End Sub

Cette méthode est beaucoup plus rapide grâce aux tableaux VBA.

A+

 

[sangarmatha]

Bonjour Job75
Je viens de tester la 2ème méthode avec 200 lignes : NICKEL!!!
Merci beaucoup, ça va me simplifier la suite et me donner du temps quant à l'usage de Powerquery

 

[job75]

Bonjour sangarmatha,

Pour tester j'ai copié la plage A3:G9 sur A10:G7002 :

- macro du fichier (1) => 68 secondes

- macro du fichier (1 bis) => 0,5 seconde.

A+