complément de code

[Lipadec]

Bonsoir le Forum, Bobsoir tout le monde

Dans un classeur où il y a 2 feuilles, je voudrai, à l'aide d'un USF placer les données de la feuille 2, sur la feuille 1.
Ci-joint, un exemple
Le code qui me manque, c'est comment faire pour faire apparaitre le nom du commercial, quand je choisi le client, et le nom de l'emballage quand je choisi le produit
L'USF est déjà fait, il me manque ce code

Merci pour votre aide

Lipadec

 

[PMO2]

Re : complément de code

Bonjour,

Voici du code à ajouter

1) Impérativement en tête de votre code la portion suivante
(si Option Explicit est spécifiée alors placez-le juste après)

'######## Modifs PMO #######
Dim var
'###########################

2) A la fin de votre code (ou ailleurs)

'############# Modifs PMO #######
Private Sub UserForm_Initialize()
Dim S As Worksheet
Set S = Sheets("Feuil2")
var = S.UsedRange
ComboBox1.RowSource = S.Name & "!" & S.Range(S.Cells(2, 4), _
S.Cells(UBound(var, 1), 4)).Address
ComboBox2.RowSource = S.Name & "!" & S.Range(S.Cells(2, 7), _
S.Cells(UBound(var, 1), 7)).Address
End Sub

Private Sub ComboBox1_AfterUpdate()
Dim i&
txtCommercial.Text = ""
For i& = 2 To UBound(var, 1)
If var(i&, 4) = ComboBox1.Value Then
txtCommercial.Text = var(i&, 5)
Exit For
End If
Next i&
End Sub

Private Sub ComboBox2_AfterUpdate()
Dim i&
txtEmballage.Text = ""
For i& = 2 To UBound(var, 1)
If var(i&, 7) = ComboBox2.Value Then
txtEmballage.Text = var(i&, 8)
Exit For
End If
Next i&
End Sub
'#############################

Cordialement.

PMO
Patrick Morange

 

[Lipadec]

Re : complément de code

Bonjour tout le monde

Merci PMO, c'est ce que je voulais, je vais l'adapter à mon fichier, et j'espère ne pas faire d'erreur

Merci

Lipadec