Calculer le nombre de dates antérieures à une date spécifique

[apfwl.87]

Bonjour le forum,
J'ai un fichier dans lequel j'ai des dates auxquelles des mailings ont été envoyés aux clients ainsi que la date à laquelle les clients ont fait un voyage. J'aimerais savoir quels sont les clients qui ont effectué un voyage après avoir reçu le mailing. Est-ce que quelqu'un peut m'aider? merci d'avance

 

[JCGL]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour à tous,

Peux-tu essayer :

=OU(B2>C2;B2>D2;B2>E2)

A+ à tous

Edition : Hello Patrick. Plaisir partagé.

 

[Victor21]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonsoir, apfwl.87.

=SI(OU(B2>C2;B2>D2;B2>E2);"oui";"non")

devrait le faire.

Edit : Bonsoir, Jean-Claude. Heureux de te croiser

 

[apfwl.87]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonsoir Victor 21 et JCGL

merci à tous les deux pour vos réponses. Malheureusement ça ne fonctionne pas dans mon fichier original. Je le joins à ce message. Savez-vous pourquoi la réponse et vrai ou oui alors que le voyage a eu lieu avant les envois de mailings?

merci pour votre aide

 

[Victor21]

Re : Calculer le nombre de dates antérieures à une date spécifique

Re,

B3 renseigné sera toujours plus grand qu'une cellule vide, et donc renverra oui.
Ajoutez la condition :

=SI(OU(ET(B3>C3;C3<>"");ET(B3>D3;D3<>"");...);"oui";"non")

Edit : Bonjour, Gérard

 

[job75]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour apfwl.87, Jean-Claude, Patrick,

Formule matricielle en W3 du fichier joint :

=SI(NB(LN(SUBSTITUE(B3;".";"/")-SUBSTITUE(C3:V3;".";"/")));"oui";"non")

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

Bonne journée.

 

[apfwl.87]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour à tous les deux

Merci pour vos réponses. Malheureusement, lorsque je copie les formules dans mon fichier d'origine, cela ne fonctionne pas. J'ai extrais la feuille et je la joins à ce message. Je ne comprends pas pourquoi ça fonctionne dan le fichier d'hier et pas dans celui-ci. Merci d'avance pour votre aide.

 

[JCGL]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour à tous,
Salut Gérard,

Commence par mettre des dates en B.
Bien que la formule de Job75 pallie le problème...

A+ à tous

 

[apfwl.87]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour JCGL

Excuses-moi mais les dates de voyage sont dans la colonne B. Est-ce que je comprends mal quelque chose?

Merci et à +

 

[JCGL]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour à tous,

Je voulais "dire des véritables dates car 22.07.2014 'dans ton fichier est du texte.
Passe en 22/07/2014.

Ce n'est qu'un détail car la formule de Job75 est censée remplacer les . par des /

A+ à tous

 

[JCGL]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour à tous,

Je viens d'ouvrir ton fichier #7.
Job75 avait bien préciser la validation matricielle....

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

C'est à dire :

• Copier la formule en V3.
• Cliquer dans la barre de formule.
• Appuyer simultanément sur les touches Ctrl+Maj+Entrée.
• Tirer vers le bas.

A+ à tous

 

[apfwl.87]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour JCGL,

J'ai converti les dates comme tu me l'as indiqué et ça fonctionne parfaitement. Merci INFINIMENT

Bonne soirée à tous et bel été

 

[job75]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonsoir les amis,

Visiblement apfwl.87 est allergique à la validation matricielle.

Alors on peut s'en passer avec :

=SI(SOMMEPROD(N(ESTNUM(LN(SUBSTITUE(B3;".";"/")-SUBSTITUE(C3:V3;".";"/")))));"oui";"non")

J'espère qu'au moins apfwl.87 connaît la fonction LN() et les logarithmes.

Attention : le fichier était en mode de calcul manuel je l'ai mis en automatique.

Fichier (2).

Bonne soirée.

 

[job75]

Re : Calculer le nombre de dates antérieures à une date spécifique

Bonjour le fil, le forum,

Si les dates sont toujours de vraies dates (avec des /) c'est bien sûr plus simple :

=SI(SOMMEPROD(N(ESTNUM(LN(B3-(""&C3:V3)))));"oui";"non")

Fichier (3).

Bonne journée.