separer lettres et chiffres dans plusieurs colonne

[fatalr]

Bonjour,
je me tourne vers les experts en la matiere.

Ils m'aideront et en plus je dormirai moins bete ce soir.


Je suis emplpoyé en comptabilité et j'ai une balance mais et le libellé et les montants sont dans la meme colonne. J'ai essayé avec convertir mais je galere.

exemple

colonne B

capitaux propres 40000
immobilisations corporelles 250000
.
.
.


Comment faire pour avoir


colonne B colonne c

capitaux propres 40000
immobilisations corporelles 250000




je me tourne donc vers vous.

merci

 

[Tibo]

Re : separer lettres et chiffres dans plusieurs colonne

Bonjour,

Une tentative avec deux formules matricielles :

en A1, ton libellé + montant

en B1 :

=GAUCHE(A1;MAX(NON(ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));2)*1))*
LIGNE(INDIRECT("1:"&NBCAR(A1)))))

Formule matricielle à valider par CTRL + MAJ + ENTREE

en C1, sa petite soeur :

=DROITE(A1;NBCAR(A1)-MAX(NON(ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));2)
*1))*LIGNE(INDIRECT("1:"&NBCAR(A1)))))*1

Formule également matricielle donc à valider par CTRL + MAJ + ENTREE

Je te laisse tester

Le principe consiste à repérer le rang du dernier caractère non numérique, donc en principe celui qui précède le montant.

@+

 

[fatalr]

Re : separer lettres et chiffres dans plusieurs colonne

merci pour cette reponse rapide mais je n'y arrive pas peut etre que si je mets le fichier sur le site vous pourrez y travailler dessus

 

[hoerwind]

Re : separer lettres et chiffres dans plusieurs colonne

Bonjour, salut Tibo,

Une variante non matricielle :

En C1

=STXT(A1;CHERCHE("µ";SUBSTITUE(A1;" ";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";""))))+1;10)*1

Elle extrait la valeur numérique.

En B1 :

=GAUCHE(A1;NBCAR(A1)-NBCAR(C1)-1)

Elle extrait la partie texte.

 

[hoerwind]

Re : separer lettres et chiffres dans plusieurs colonne

Re,

Le fichier joint ne correspond en rien à l'exemple sous le message #1 !

- Le nombre de mots de la partie texte est variable
- Les séparateurs de milliers sont des espaces
- Il y a deux nombres à extraire (dans la même cellule ?)

Encore perdu mon temps en essayant d'aider !

 

[fatalr]

Re : separer lettres et chiffres dans plusieurs colonne

desole hoerwind si je me suis mal expliqué mais faut pas le prendre comme ça!!

 

[Tibo]

Re : separer lettres et chiffres dans plusieurs colonne

re,
Salult hoerwind,

Une autre tentative avec une colonne intermédiaire :

en B1 :

=STXT(A1;EQUIV(VRAI;ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));2)*1);0)+1;99)

Formule matricielle à valider par CTRL + MAJ + ENTREE

en C1 :

=GAUCHE(A1;EQUIV(VRAI;ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));2)*1);0))

en D1 :

=SI(DROITE(A1)="-";"";SUBSTITUE(STXT(B1;TROUVE(".";B1)+4;99);"-";"")*1)

en E1 :

=SI(DROITE(A1)="-";SUBSTITUE(STXT(B1;TROUVE(".";B1)+4;99);"-";"")*1;"")

Formules à recopier vers le bas.

La colonne B peut ensuite être masquée.

Attention : si le libellé même du compte contient des chiffres, ça risque de ne plus fonctionner.

Je te laisse tester.

@+

 

[hoerwind]

Re : separer lettres et chiffres dans plusieurs colonne

Re,

Pour te faire pardonner !

Une formule qui extrait le nombre suivant l'exemple de ta pièce jointe :
=SUBSTITUE(SUBSTITUE(STXT(A1;CHERCHE(".";A1)+4;20);"-";"");" ";"")*1
cellule au format # ##0.00

Dès que j'ai cinq minutes, je cherche la formule pour extraire le texte.

 

[fatalr]

Re : separer lettres et chiffres dans plusieurs colonne

salut tibo

ça a marche trés bien avec tes formules b1 et c1.... super

MERCI A TOUS!!!!!!

 

[hoerwind]

Re : separer lettres et chiffres dans plusieurs colonne

Re,

Pendant que je cherchais la formule pour extraire le texte, je n'avais pas vu que la proposition de Tibo te convenait.

Puisque c'est fait voici une formule pour extraire le texte :
=GAUCHE(A1;NBCAR(A1)-2*NBCAR(STXT(A1;CHERCHE(".";A1)+4;20))-1)

Le tout est résumé sous la pièce jointe.

 

[Tibo]

Re : separer lettres et chiffres dans plusieurs colonne

re,

Après avoir lu la solution de hoerwind, je vois que j'ai un peu compliqué la chose.

fatalr, tu peux reprendre la formule de hoerwind pour séparer les déits et les crédits.

Si souci, reviens avec un fichier plus complet

@+

 

[hoerwind]

Re : separer lettres et chiffres dans plusieurs colonne

Salut Tibo,

Venant de toi, un commentaire vaut bien plus que tout autre chose, merci !