[Résolu] Tableau automatique à partir d'un autre tableau

[LaFeuille80]

Bonjour,
Je dispose d'un tableau de formation du personnel avec leurs noms, prénoms, dates d'obtention et dates de validité. A partir de ce tableau, je souhaiterai avoir de manière automatique un autre tableau qui donnera les personnes dont la validité de la formation expire dans 3 mois. Ce tableau devra afficher les noms, prénoms et dates de validité. Cependant je n'arrive pas à trouver la formule à mettre en place pour obtenir ce 2éme tableau...

 

[excfl]

Re : Tableau automatique à partir d'un autre tableau

Bonsoir LaFeuille80,

Si date de validité en A1 : =DATE(ANNEE(A1);MOIS(A1)+3;JOUR(A1))

excfl

 

[LaFeuille80]

Re : Tableau automatique à partir d'un autre tableau

Merci de votre réponse, j'utilisais déjà cette formule pour définir la validité en fonction de l'obtention.
Je met un fichier d'exemple en pièce jointe.
Pour faire simple je dispose du "Tableau formation" mais je veux que le "Tableau recyclage" actualise la liste seul. Et je ne vois pas comment cette fonction peux m'aider a automatiser ce tableau ...

 

[R@chid]

Re : Tableau automatique à partir d'un autre tableau

Bonsoir @ tous,
en I6,

=SIERREUR(INDEX(Table1[Nom];PETITE.VALEUR(SI(MOIS.DECALER(AUJOURDHUI();3)>Table1[Validité];LIGNE(INDIRECT("1:"&LIGNES(Table1[Nom]))));LIGNES($6:6)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

Adapter pour les 2 autres colonnes


@ + +

 

[LaFeuille80]

Re : Tableau automatique à partir d'un autre tableau

Au vue de la formule... je crois que je pouvais encore chercher longtemps!
Un grand merci à vous!
Je vais vous embêter encore une fois, pourquoi valider par Ctrl+Maj+Entrée? (J'ai remarqué qu'avec un simple Entrée il y a une erreur)

 

[R@chid]

Re : [Résolu] Tableau automatique à partir d'un autre tableau

Re,
On valide par Ctrl+Maj+Entree car c'est une formule matricielle et pas une formule classique

@ + +

 

[LaFeuille80]

Re : [Résolu] Tableau automatique à partir d'un autre tableau

J'ai un petit problème en adaptant la formule sur mon tableau, je m'explique.
Dans la formule que vous m'avez donné le symbole supérieur ">" mais lorsque j'utilise le symbole inférieur "<" le 2éme tableau m'affiche les personnes qui n'ont pas la formation (c'est a dire que dans l'exemple que j'ai donné en pièce jointe, le tableau affiche nom5 et nom7). Comment puis-je faire pour ne pas intégrer les cellules vides?
Cordialement

 

[R@chid]

Re : [Résolu] Tableau automatique à partir d'un autre tableau

Bonjour,

=SIERREUR(INDEX(Table1[Nom];PETITE.VALEUR(SI((Table1[Validité]<>"")*(MOIS.DECALER(AUJOURDHUI();3)<Table1[Validité]);LIGNE(INDIRECT("1:"&LIGNES(Table1[Nom]))));LIGNES($6:6)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

@ + +