(RÉSOLU) Par ordre alphabétique

[Clochard]

Bonjour le Forum,

J'aimerais bien savoir de votre part... s'il m'est possible d'ajouter un petit quelque chose à ma formule, afin que le classement se fasse par ordre alphabétique...

Merci beaucoup d'y regarder

Bonne journée
Clochard

 

[CISCO]

Re : Par ordre alphabétique

Bonjour

Tu peux faire en B6 avec

INDEX(H$1:H$35;MIN(SI(PETITE.VALEUR(NB.SI(H$6:H$35;"<"&H$6:H$35);LIGNES($1:1))=NB.SI(H$6:H$35;"<"&H$6:H$35);LIGNE($6:$35))))

en matriciel (Ctrl+maj tempo+entrer)

@ plus

 

[Clochard]

Re : Par ordre alphabétique

Merci Cisco,

La seule chose... c'est que ça inscrit tous les noms au lieu d'un condensé....

Clochard

 

[CISCO]

Re : Par ordre alphabétique

Bonjour

Tu ne veux pas avoir les doublons, c'est ça ?

@ plus

 

[Clochard]

Re : Par ordre alphabétique

Exact...

Est-ce possible?

Merci

 

[CISCO]

Re : Par ordre alphabétique

Bonjour

Si c'est cela, tu peux faire avec

SI(LIGNES($1:1)>SOMME(1/NB.SI(H$6:H$35;H$6:H$35));"";INDEX(H$1:H$35;MAX(SI(MAX(NB.SI(H$6:H$35;">"&H$6:H$35)*(NB.SI(B$5:B5;H$6:H$35)=0))=NB.SI(H$6:H$35;">"&H$6:H$35);LIGNE($6:$35)))))

toujours en matriciel

@ plus

 

[Clochard]

Re : Par ordre alphabétique

Merci beaucoup Cisco,

C'est résolu pour moi

Merci et bonne journée

Clochard

 

[Clochard]

Re : Par ordre alphabétique

Salut Cisco...

J'ai malheureusement un petit problème pour l'insérer dans mon vrai fichier qui lui contient 250 lignes

Ça me donne une erreur ????

Clochard

 

[BOISGONTIER]

Re : Par ordre alphabétique

Bonjour,

Un tri matriciel sans doublons beaucoup + rapide de David84 (<1 sec pour 500 lignes)

Accepte les lignes vides

On écrit une seule formule

-Sélectionner B6:B500
=INDEX(champ;EQUIV(PETITE.VALEUR(SI(champ<>"";SI(EQUIV(champ;champ;0)=LIGNE(INDIRECT("1:"&LIGNES(champ)));NB.SI(champ;"<"&champ)));LIGNE(INDIRECT("1:"&LIGNES(champ))));SI(champ<>"";SI(EQUIV(champ;champ;0)=LIGNE(INDIRECT("1:"&LIGNES(champ)));NB.SI(champ;"<"&champ)));0))
-Valider avec maj+ctrl+entrée

http://boisgontierjacques.free.fr/fichiers/Matriciel/TriMatSansDoublons.xls

Cf Remarques sur l'écriture des Formules Matricielles

-Si on a plus de 500 éléments, utiliser une fonction perso matricielle:

http://boisgontierjacques.free.fr/fichiers/fonctionsperso/Fonction_sansdoublonsTrie.xls



JB

 

[CISCO]

Re : Par ordre alphabétique

Bonsoir

Chez moi, ça fonctionne, mais c'est effectivement un peu long... Deux autres possibilités en colonnes D et E, avec des données jusqu'à la ligne 280.

@ plus

 

[CISCO]

Re : Par ordre alphabétique

Bonjour à tous

Puisque les formules matricielles validées en une seule fois sur une plage complète demandent moins de temps de calcul et moins de place mémoire, et pour ma culture, comment peut-on transformer la formule en E6 dans mon précédent fichier :

SI(LIGNES($1:1)>SOMME(1/NB.SI(H$6:H$280;H$6:H$280));"";INDEX(H$6:H$280;EQUIV(MAX((NB.SI(H$6:H$280;">"&H$6:H$280)*(H$6:H$280>E5)));NB.SI(H$6:H$280;">"&H$6:H$280);0)))

pour quelle soit acceptable en une seule fois sur toute la plage en dessous ? Le problème vient du E5 : Il faut que la formule écrite, une seule fois en E6 avec ce mode de validation, fasse intervenir E5 en E6, E6 en E7, E7 en E8 et ainsi de suite. J'ai essayé avec du INDIRECT ou du DECALER, mais soit je n'obtiens que 1 ou 2 prénoms, soit j'ai #VALEUR.

SI(LIGNES($1:1)>SOMME(1/NB.SI(H$6:H$280;H$6:H$280));"";INDEX(H$6:H$280;EQUIV(MAX(NB.SI(H$6:H$280;">"&H$6:H$280)*(H$6:H$280>DECALER(E4;LIGNE(INDIRECT("1:"&LIGNES(H$6:H$280)));)));NB.SI(H$6:H$280;">"&H$6:H$280);0)))

@ plus

 

[Clochard]

Re : Par ordre alphabétique

Merci M. Boisgontier et Cisco...

Franchement, je suis impressionné par ta ténacité avec mon problème...

Malheureusement... J'arrive vraiment pas l'insérer dans mon fichier... c'est vrai qu'il y a plusieurs autres formules sur chaque ligne qui d'après moi viennent surement interférer dans le bon fonctionnement... et me renvoie #DIV/0!

Merci Mr. Boisgontier... j'ai finalement réussi a la placer... mais j'arrive pas à cacher " #NOMBRE! " dans la colonne "C"

Clochard

 

[BOISGONTIER]

Re : Par ordre alphabétique

Bonjour,

>mais j'arrive pas à cacher " #NOMBRE! "

Il y a une mfc (=ESTERREUR(B6)) (cf fichier joint post #9)

jb

 

[Clochard]

Re : Par ordre alphabétique

Bonjour,

J'ai bien tenté par la MFC... mais rien n'arrive à les rendre non visible...

Clochard

 

[Clochard]

Re : Par ordre alphabétique

Bonjour Cisco,

J'ai finalement réalisé que si j'obtiens #DIV/0!.. c'est parce que la colonne H6:H280 a des cellules vides...

Ça fonctionne bien lorsque les cellules dans la colonne H6:H280 n'a aucune cellule vide

Le problème est que j'ajoute un nom à tous les jours....

Clochard