Recherche sur plusieurs classeurs fermés

[SALAH]

Bonjour à tous

Mon souci c' est cette macro qui est très bien conçue que j' ai trouvé sur le net qui fait une recherche sur plusieurs classeurs
elle fonctionne très bien mais le seul souci pour moi c ' est quand il s' agit de doublon elle m' affiche qu' un seul nom alors que moi j' aimerais qu' il m' affiche tout

Pourriez-vous m' aidez svp
je joins le fichier. Merci

 

[Robert]

Re : Recherche sur plusieurs classeurs fermés

Bonjour Salah, bonjour le forum,

Peut-être comme ça :

Sub ListeFichiersTxt()
Dim Dossier As Object, Fichier As Object, Ws As Object
Dim StrSearchString As String, Chemin As String
Dim I As Byte
Dim FoundCell As Range
Dim PA As String

Application.ScreenUpdating = False
I = 10
StrSearchString = InputBox(Prompt:="Saisir Le Nom du Client ?.", Title:="Recherche")
If StrSearchString = "" Then Exit Sub
Range("B10:B50").ClearContents
Chemin = ThisWorkbook.Path
Set Dossier = CreateObject("Scripting.FileSystemObject").GetFolder(Chemin)
For Each Fichier In Dossier.Files
    If Right(Fichier.Name, 3) = "xls" Then
    If Fichier.Name <> ThisWorkbook.Name Then
        Workbooks.Open Filename:=Fichier
        For Each Ws In Worksheets
            With Ws
                .Activate
                Set FoundCell = .Cells.Find(What:=StrSearchString, LookIn:=xlValues, LookAt:=xlPart)
                If Not FoundCell Is Nothing Then
                    PA = FoundCell.Address
                    Do
                        FoundCell.Activate
                        ThisWorkbook.Sheets(1).Cells(I, 2).Value = Fichier.Name & " --> Feuille: " & Ws.Name & "--> Cellule " & FoundCell.Address
                        I = I + 1
                        FoundCell = .Cells.Findext(FoundCell)
                    Loop While Not FoundCell Is Nothing And FoundCell.Address <> PA
                End If
            End With
        Next Ws
    ActiveWorkbook.Close savechanges:=False
    End If
    End If
Next Fichier
Application.ScreenUpdating = True
End Sub

Je précise que la recherche ne se fait pas sur des classeurs fermés, puisque ils sont d'abord ouverts avant d'effectuer la recherche pour être ensuite refermés...

 

[SALAH]

Re : Recherche sur plusieurs classeurs fermés

Bonjour le Forum, Bonjour Robert

Merci pour votre aide mais apparemment quand je teste il m' indique une erreur d' exécution '438' : Propriété ou méthode non gérée par cet objet qui bloque au niveau de la ligne "FoundCell = .Cells.Findext(FoundCell)"

Merci

 

[Robert]

Re : Recherche sur plusieurs classeurs fermés

Bonsoir Salah, bonsoir le forum,

Désolé Salah ! Une faute de frappe... et pas de test derrière (Kékon !)
Remplacer :

FoundCell = .Cells.Findext(FoundCell)

par :

FoundCell = .Cells.FindNext(FoundCell)

FindNext avec le N en plus...

 

[SALAH]

Re : Recherche sur plusieurs classeurs fermés

Bonjour le forum, Robert

Robert, c 'est beaucoup mieux mais seulement il y a un hic il ne m' affiche pas les doublons
sur l' exemple j' ai 2 DUPONT et il m' en affiche qu 'un seul

Merci

 

[Robert]

Re : Recherche sur plusieurs classeurs fermés

Bonjour Salah, bonjour le forum,

Ha mais quelle feignasse je suis ! Bon, cette fois j'ai pris le temps de tester et donc de corriger mon erreur...
D'abord, tu peux supprimer la ligne :

FoundCell.Activate

qui ne fait que ralentir le code...

Ensuite, remplace :

FoundCell = .Cells.FindNext(FoundCell)

par :

Set FoundCell = .Cells.FindNext(FoundCell)

Et comme c'est le dernier Set, tu gagnes le match...

 

[SALAH]

Re : Recherche sur plusieurs classeurs fermés

Bonjour Robert, Bonjour le forum

Robert, pas mal le jeu de mot mais c' est plutôt toi qui gagne le math car tout marche à merveille
je ne serais jamais te remercier pour ton aide

Merci encore une fois à vous tous