Naviguer et figer les tableau dans la feuille

chaelie2015

XLDnaute Accro
Bonjour Forum

En premier lieu les lignes de 1 à 10 sont figées, avec un bouton fixe
Je souhaite naviguer dans la feuille par le bouton MENU
Si je clic sur le bouton MENU : boton TAB Bord 1T donc aller vers lignes 14 et figer horizontalement de 14 a 21 et ainsi de suite pour les bouton Budget , Tab Bord 2T Tab Bord 3T Tab Bord 4T
Salutations
 

Pièces jointes

  • CHARLIE NAVIGUER ET FIGER.xlsx
    12.4 KB · Affichages: 42

job75

XLDnaute Barbatruc
Re : Naviguer et figer les tableau dans la feuille

Bonsoir chaelie2015,

Votre histoire de "figer" des zones ne tient pas la route.

Voyez le fichier joint avec une liste de validation en C1.

Et cette macro dans le code de la feuille (clic droit sur l'onglet et Visualiser le code) :

Code:
Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [C1]) Is Nothing Then Exit Sub
Dim i As Variant
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Hidden = False
i = Application.Match([C1], [A:A], 0)
If IsError(i) Then Exit Sub
Rows("2:" & Rows.Count).Hidden = True
Rows(i).Resize(Cells(i + 1, 1).MergeArea.Count + 1).Hidden = False
End Sub
Bien voir que les cellules jaunes sont fusionnées pour permettre le repérage avec MergeArea.

A+
 

Pièces jointes

  • CHARLIE NAVIGUER(1).xlsm
    18.2 KB · Affichages: 42

mapomme

XLDnaute Barbatruc
Supporter XLD
Re : Naviguer et figer les tableau dans la feuille

Bonsoir chaelie2015, job75 :),

Une version plus tarabiscotée et moins élégante de celle de job75 (que je salue :)) mais après deux mois d'inactivité sur XLD & Excel, la reprise est difficile :eek:.

La feuille masquée "Vers" contient le paramétrage des différentes zones.

Pour changer de vue, cliquer sur le bouton bleu clair "Vers..." ou bien taper la combinaison des deux touches Ctrl+m
 

Pièces jointes

  • chaelie201-NAVIGUER ET FIGER-v1.xlsm
    56.7 KB · Affichages: 55
Dernière édition:

job75

XLDnaute Barbatruc
Re : Naviguer et figer les tableau dans la feuille

Re, bonsoir mapomme, heureux de te croiser,

S'il y a peu de zones à afficher on peut utiliser des cases à cocher et leur affecter cette macro :

Code:
Sub Afficher()
Dim o As Object, i As Variant
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Hidden = True
For Each o In ActiveSheet.DrawingObjects
  If TypeName(o) = "CheckBox" Then
    If o = 1 Then
      i = Application.Match(o.Text, [A:A], 0)
      If IsNumeric(i) Then _
        Rows(i).Resize(Cells(i + 1, 1).MergeArea.Count + 1).Hidden = False
      If o.Text = "Tout" Then Rows.Hidden = False
    End If
  End If
Next
End Sub
Fichier (2).

Bonne nuit.
 

Pièces jointes

  • CHARLIE NAVIGUER(2).xlsm
    24 KB · Affichages: 43

job75

XLDnaute Barbatruc
Re : Naviguer et figer les tableau dans la feuille

Bonjour chaelie2015, mapomme, le forum,

Si l'on veut pouvoir mettre en forme les textes des objets utiliser des contrôles ActiveX.

Dans un Module de classe :

Code:
Public WithEvents CB As MSForms.CheckBox

Private Sub CB_Click()
Dim o As Object, i As Variant
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Hidden = True
For Each o In CB.Parent.OLEObjects
  If o.Name Like "CheckBox*" Then
    o.Object.ForeColor = IIf(o.Object, &HFF&, &H0&) 'rouge/noir
    If o.Object Then
      i = Application.Match(o.Object.Caption, [A:A], 0)
      If IsNumeric(i) Then _
        Rows(i).Resize(Cells(i + 1, 1).MergeArea.Count + 1).Hidden = False
      If o.Object.Caption = "Tout" Then Rows.Hidden = False
    End If
  End If
Next
ActiveCell.Activate
End Sub
Dans ThisWorkbook, pour initialiser la classe :

Code:
Dim CB() As New Classe1

Private Sub Workbook_Open()
Dim o As Object, n%
For Each o In Feuil1.OLEObjects
  If o.Name Like "CheckBox*" Then
    ReDim Preserve CB(n)
    Set CB(n).CB = o.Object
    n = n + 1
  End If
Next
End Sub
Fichier (3).

Bonne journée.
 

Pièces jointes

  • CHARLIE NAVIGUER(3).xlsm
    37.1 KB · Affichages: 44
Dernière édition:

Discussions similaires

Statistiques des forums

Discussions
311 725
Messages
2 081 944
Membres
101 849
dernier inscrit
florentMIG