XL 2013 jour de la semaine

[patrick7676]

bonjour
un petit problème sous un ciel bleu de Normandie

je souhaiterais que les jour de la semaine ne soit inscrit comme :
Lundi Mardi Mercredi Jeudi etc mais par des lettres

L pour lundi M pour mardi Me pour mercredi .

je souhaiterais en utilisant la formule Date que je n'ai pas à recopier tous mes tableaux

en attendant de vous lire

 

[Dugenou]

Re : jour de la semaine

Bonjour,
On peut commencer avec (si ta date en A1) : =MAJUSCULE(GAUCHE(TEXTE(A1;"jjj");1))
et pour avoir les deux lettres pour les mercredis : =NOMPROPRE(GAUCHE(TEXTE(A1;"jjj");SI(JOURSEM(A1;1)=4;2;1)))

Cordialement

 

[Caillou]

Re : jour de la semaine

Bonjour,

si date en A1 :

=CHOISIR(JOURSEM(A1;2);"L";"M";"Me";"J";"V";"S";"D")

Caillou

 

[Dugenou]

Re : jour de la semaine

Bravo Caillou ! c'est tellement plus simple! : j'ai honte !

 

[Modeste geedee]

Re : jour de la semaine

Bonsour®
plus court !!!
=CHOISIR(JOURSEM(A1);"D";"L";"M";"Me";"J";"V";"S")


autres propositions :
=STXT("D L M MeJ V S ";2*JOURSEM(A1)-1;2)
ou bien :
=MAJUSCULE(GAUCHE(TEXTE(A1;"jjj")))&REPT("e"; JOURSEM(A1)=4)
ou encore :
=INDEX({"D";"L";"M";"Me";"J";"V";"S"};JOURSEM(A1))
et puis
=STXT("DLMMJVS";JOURSEM(A1);1)&REPT("e";JOURSEM(A1)=4)
=STXT("DLMMJVS";JOURSEM(A1);1)&SI(JOURSEM(A1)=4;"e";"")
=GAUCHE(NOMPROPRE(TEXTE(A1;"jjj"));1+(JOURSEM(A1)=4))

en nommant la Matrice
NJ fait référence à :
={"D";"L";"M";"Me";"J";"V";"S"}
=INDEX(NJ;JOURSEM(A1))

 

[ROGER2327]

Re : jour de la semaine

moins deux caractères :
=STXT("S D L M MeJ V ";2*MOD(A1;7)+1;2)

 

[patrick7676]

Re : jour de la semaine

je n'arrive à résoudre ce problème
je vous joint un fichier

 

[ROGER2327]

Re : jour de la semaine

Re...

Voyez si la pièce jointe vous convient...​

Bonne soirée.


ℝOGER2327
#8216

Vendredi 6 Pédale 143 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXIV, 7,6450h - bêche
2016-W09-1T18:20:52Z

 

[Jocelyn]

Re : jour de la semaine

Bonjour le Forum,
Bonjour patrick7676, Dugenou, Caillou, Modeste geedee, Roger2327,

en partant de la formule de Roger2327 tu peux mettre en C5 cette formule

=STXT("S D L M MeJ V ";2*MOD(DATE($A$5;MOIS($C$4&1);C6);7)+1;2)

et l'étirer vers la droite

Cordialement

EDIT : Désolé Roger je n'avais pas vu que tu étais connecté

 

[job75]

Re : jour de la semaine

Bonjour à tous,

En C5 à tirer sur D5:AG5 :

=SIERREUR(NOMPROPRE(GAUCHE(TEXTE(DATEVAL(C6&$C4&$A5);"jjj");1+(JOURSEM(C6&$C4&$A5)=4)));"")

Bonne soirée.

Edit : pas terrible pour mon 20000ème post, je n'avais pas regardé les solutions précédentes...

 

[patrick7676]

Re : jour de la semaine

bonjour
quelle différence avec celle de Roger 2327

 

[Modeste geedee]

Re : jour de la semaine

Bonsour®

en nommant la Matrice
NJ fait référence à :
={"D";"L";"M";"Me";"J";"V";"S"}
=INDEX(NJ;JOURSEM(A1))

 

[patrick7676]

Re : jour de la semaine

je remercie tous pour l'aide apportée
merci