Fonction recherche et renvoi d'une valeur

[naturellecomm]

Bonjour,

Je travaille actuellement sur la création d'un planning qui "s'auto-remplirait" en grande partie, pour me faciliter un peu la tâche !
Pour simplifier, le problème :
Colonne A :initiales du personnel
Colonne B : travail à effectuer
Colonne C : postes
Colonne D : personne correspondante

Les 3 premières colonnes sont "remplies" ; j'aimerai par exemple que dans la case D2 correspondant au poste ANX s'affiche l'initiale de la personne à qui a été affecté ce poste, dans ce cas là "A". Comme les travaux changent tous les jours, je souhaiterai que la formule recherche dans la plage A:B...
Je vous joins un fichier xls parce que je ne suis pas sûre d'avoir été très explicite !
Merci d'avance pour votre aide !

Chloé

 

[st007]

Re : Fonction recherche et renvoi d'une valeur

une idée à améliorer

 

[Dugenou]

Re : Fonction recherche et renvoi d'une valeur

Bonjour Naturelle, St007, le forum,
Tout d'abord il faudra faire un tableau qui donne l'équivalence entre le poste à 3 lettres et le travail à effectuer
Ensuite il faut que tu précises quelle réponse tu attends pour le poste Entretien car il y a deux réponses possibles.
Voir PJ une première possibilité. Il y a d'autres solutions si tu ne veux pas avoir 2 items différents pour l'entretien par exemple.
Cordialement

 

[naturellecomm]

Re : Fonction recherche et renvoi d'une valeur

Bonjour,

Merci à tous les deux pour vos réponses...
Celle du Dugenou me parait mieux adaptée à ce que je souhaite faire car je ne peux pas intervertir les 2 premières colonnes comme st007 le propose.
Du coup, je vous mets en pièce jointe le visuel de ce à quoi va ressembler le planning.
Question 1 : est-il possible de mettre le tableau d'équivalence "3 lettres" - "postes" dans une autre feuille ?
Question 2 : est-il possible de colorier la colonne qui détermine le poste de chacun avec la couleur du poste (par ex : J > ANX , avec ANX (K3) en jaune ? Il me semble que c'est une macro mais je ne m'y connais pas trop...

En vous remerciant encore, et d'avance pour votre aide !

Chloé

PS : j'ai omis de signaler que nous pouvons bien sûr nommer les postes ent1, ent2.

 

[st007]

Re : Fonction recherche et renvoi d'une valeur

Bonjour,

Au vu de ton modèle et des formules qui s'y trouvent, je ne vois plus d’intérêt des correspondance.
De simples mises en forme conditionnelles suffisent.

Pour agrémenter un peu les dates choisis en H1

 

[naturellecomm]

Re : Fonction recherche et renvoi d'une valeur

Bonsoir,

Pourrais-tu développer ta réponse ? Parce que je m'étais un peu creuser les méninges pour y arriver avec des mises en forme conditionnelles, mais je n'ai pas trouvé...
Merci

Chloé

 

[st007]

Re : Fonction recherche et renvoi d'une valeur

Bonsoir chloé, as-tu jeté un œil a la pièce jointe #5

 

[naturellecomm]

Re : Fonction recherche et renvoi d'une valeur

Pardon, j'avais pas vu !

Couleurs ok, de même que l'astuce pour la date, merci !

Je suis entrain de tester la solution de Dugenou pour les reports de personnes aux postes adéquates et effectivement ça fonctionne sauf bien-sûr quand j'ai 2 fois le même poste...

Y aurait-il moyen de faire en sorte que si la première case entretien est déjà remplie avec 1 personne (F par ex), la deuxième sélectionne automatiquement la 2e (FL par ex)...?
Sinon, dans la formule =INDEX($C6:$C12;EQUIV(INDEX(Postes!$B$1:$B$16;EQUIV($P6;Postes!$A$1:$A$16;0));$E6:$E12;0))
y a-t-il moyen de sélectionner 2 colonnes comme plages références, c'est à dire $C6:$C12 ET $F6:$F12 ?

Je suis super contente parce que ça avance bien Ci-dessous la dernière version !

Chloé

 

[st007]

Re : Fonction recherche et renvoi d'une valeur

Rebonsoir,

tes questions me dépassent un peu,
pour tes plages de recherche, je ne penses pas, on peut bien écrire ($C6:$C12;$F6:$F9), mais ne fonctionne pas avec equiv
pour tes plusieurs liste et entretien, j'ai numéroter

Pour faire simple, j'agrandirais le tableau de 7 à 11 lignes.

Pour ton ajout dans les jours en colonne A, j'ai pas trop saisi, y a pas un bug avec 8/4 c'est un lundi

 

[mapomme]

Re : Fonction recherche et renvoi d'une valeur

Bonjour naturellecomm, à tous,

Un essai avec gestion des doublons sans lignes supplémentaires.

Cinq noms fixes et quatre noms dynamiques ont été définis:

NOM	           DEFINITION
	
maTable	=Postes!$A$1:$B$20
	
Matin	=Planning!$C$6
ceMatin	=DECALER(Matin;8*ENT((LIGNE()-LIGNE(Matin))/8);0;7;6)
	
Apresmidi	=Planning!$I$6
cetAM	    =DECALER(Apresmidi;8*ENT((LIGNE()-LIGNE(Apresmidi))/8);0;7;6)
	
colP	=Planning!$P$6
macolP	=DECALER(colP;8*ENT((LIGNE()-LIGNE(colP))/8);0)
	
colR	=Planning!$R$6
macolR	=DECALER(colR;8*ENT((LIGNE()-LIGNE(colR))/8);0)

Une formule matricielle en Q6 (à copier vers les autres cellules de la colonne Q):

=SIERREUR(INDEX($A$1:$F$10000;PETITE.VALEUR(SI(RECHERCHEV(P6;maTable;2;FAUX)=ceMatin;LIGNE(ceMatin);""); NB.SI(macolP:P6;P6)); PETITE.VALEUR(SI(RECHERCHEV(P6;maTable;2;FAUX)=ceMatin;COLONNE(ceMatin)-2;""); NB.SI(macolP:P6;P6)));"")

Une formule matricielle en S6 (à copier vers les autres cellules de la colonne S):

=SIERREUR(INDEX($A$1:$N$10000;PETITE.VALEUR(SI(RECHERCHEV(R6;maTable;2;FAUX)=cetAM;LIGNE(cetAM);""); NB.SI(macolR:R6;R6)); PETITE.VALEUR(SI(RECHERCHEV(R6;maTable;2;FAUX)=cetAM;COLONNE(cetAM)-2;""); NB.SI(macolR:R6;R6)));"")

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

[naturellecomm]

Re : Fonction recherche et renvoi d'une valeur

Bonjour,

Merci à tous pour vos réponses, et merci à mapomme pour le fichier et les explications !
J'ai vraiment encore plein de choses à apprendre dans excel ! En tout cas, c'est déjà nickel comme ça !
Je n'y serai pas arrivée toute seule alors merci beaucoup !

Si je peux encore abuser un peu de vos compétences, il me reste un souci...
J'ai 3 binômes (A+AL, W+T et J+F)... qui sont de permanence à tour de rôle soit 1 semaine sur 3.
Je remplis ces personnes en Y2 et Z2 ; Je souhaiterai dans une case que soit noté la ou les personnes de perm.
Prenons le cas d'une semaine de perm pour A+AL ; si A n'est pas là, que AL s'affiche, si AL n'est pas là que A s'affiche et si tous les deux sont là que ça affiche A+AL... Idem pour les autres binômes.
J'avais pour l'instant rentré cette formule : =SI(J9="-";"AL";SI(J10="-";"A";"A+AL")) mais bien évidemment je ne peux pas y inclure les autres binômes car je ne peux pas cumuler autant de SI que j'aurai besoin...

Ci-joint la dernière version du fichier...

En vous remerciant !

Chloé

 

[mapomme]

Re : Fonction recherche et renvoi d'une valeur

Bonjour naturellecomm,

Avec une liste de validation en Y2. La cellule Z2 se met à jour en fonction de la valeur de Y2.

La formule en X12 (à copier vers les autres cellules) est:

=SI(NB.SI(D6:O12;$Y$2)>1;$Y$2;"") & SI(NB.SI(D6:O12;$Y$2)+NB.SI(D6:O12;$Z$2)>2;"+";"") & SI(NB.SI(D6:O12;$Z$2)>1;$Z$2;"")

 

[naturellecomm]

Re : Fonction recherche et renvoi d'une valeur

Merci ma pomme !
J'ai juste un petit bug : quand je tape A dans la Y2, j'ai un message d'erreur : "la valeur entrée ne se trouve pas dans la liste des valeurs requises"...
Je ne dois peut-être pas modifier cette cellule ?
Chloé

 

[mapomme]

Re : Fonction recherche et renvoi d'une valeur

(re)naturellecomm,

La cellule Y2 a une liste de validation. Utilisez-la !
Ou bien saisir directement une lettre en majuscule en Y2.

 

[mapomme]

Re : Fonction recherche et renvoi d'une valeur

(re),

Dans le fichier utilisé pour construire les formules des colonnes (fichier du post #8) l'en-tête des colonnes R et S était "Matin" et celui des colonnes P et Q était "Après-midi".

J'ai donc basé les formules de la colonne Q sur le fait qu'en colonne Q on s'intéressait qu'au planning du matin. Et idem pour la colonne S, on ne prend en compte que les valeurs du planning de l'après-midi.

Or je viens de m'apercevoir que dans votre fichier du post #11, il y a un en-tête commun (POSTES) aux quatre colonnes P, Q, R, S. Ce qui semblerait montrer que les formules des colonnes Q et S réfèrent aux plannings du matin et au planning de l'après-midi.

Si tel est le cas, alors les formules des colonnes Q et S sont inadaptées et sont devenues fausses !