Départager avec un critère "Temps" en cas d'égalité

[jalucyne]

Bonjour à tous les spécialistes.
Il y a quelques mois, j'ai posé sur le forum une question presque similaire (encore merci à Rachid pour sa réponse), ma question était: départager des équipes à égalité à partir d'un 2eme critère.

Dans ma question précédente je pouvais départager avec un second critère sous le format de "POINTS"

Cette fois ci mon 1er critère est un total de points, mais en cas d'égalité je veux les départager avec un critère "TEMPS":

Le classement est basé sur le total des points (colonne U, formule: =SI(U5="";"";RANG(U5;($U$5:$U$32);1))) entraine des égalités que je dois départager au temps, (colonne V).

Le résultat de la colonne W est donc incomplet , je recherche le bon résultat dans la colonne X.

Voir le classeur ci joint.

Dans l'attente de vos lumières.
Amicalement.
Jalucyne de Tahiti

 

[CISCO]

Re : Départager avec un critère "Temps" en cas d'égalité

Bonjour

Tu peux faire avec

EQUIV(U5+V5/100;PETITE.VALEUR(U$5:U$13+V$5:V$13/100;LIGNE(INDIRECT("1:"&LIGNES(V$5:V$13))));0)

en matriciel, donc à valider avec Ctrl+maj tempo + entrer

Le principe : On pondère le nombre de points en U avec le temps en V divisé par 100.

On pourrait faire avec RANG (U5+V5/100;U$5:U$13+V$5:V$13/100;1) en matriciel mais cela ne fonctionne pas, même en "trichant" en nommant la série de valeurs U$5:U$13+V$5:V$13/100.

Donc, j'ai contourné ce problème en classant par ordre croissant les valeurs de la série U$5:U$13+V$5:V$13/100 avec

PETITE.VALEUR(U$5:U$13+V$5:V$13/100;LIGNE(INDIRECT("1:"&LIGNES(V$5:V$13))))

.

Ensuite, on recherche avec EQUIV la position de U5+V5/100 dans cette série classée dans l'ordre croissant.

Il y a bien sûr des variantes, par exemple, on peut remplacer LIGNES(V$5:V$13) par NBVAL(V$5:V$13).

Le mieux serait, je pense, de travailler avec des plages dynamiques en colonnes U et V pour que la formule s'adapte automatiquement aux nombres de concurrents, et ne s'arrêtent pas forcément à la ligne 13.

@ plus

 

[job75]

Re : Départager avec un critère "Temps" en cas d'égalité

Bonjour jalucyne, CISCO,

Formule en W5 à tirer vers le bas :

=SI(U5="";"";SOMMEPROD(SIGNE(U$5:U$32)*(U$5:U$32+V$5:V$32/1000<U5+V5/1000))+1)

Edit : en fait on peut ne pas mettre "/1000" si les points sont toujours des nombres entiers et les temps toujours inférieurs à 24 h...

A+

 

[job75]

Re : Départager avec un critère "Temps" en cas d'égalité

Re,

Puisqu'on en est aux SOMMEPROD formule en U5:

=SOMMEPROD(MOD(COLONNE(C5:S5);2)*C5:S5)

Et en V5 :

=SOMMEPROD(MOD(COLONNE(C5:S5);2)*D5:T5)

A+

 

[job75]

Re : Départager avec un critère "Temps" en cas d'égalité

Re,

Du coup on peut conserver la formule avec RANG en W5.

D'abord formule en V5 :

=SI(NB(C5:T5);SOMMEPROD(MOD(COLONNE(C5:S5);2)*D5:T5);"")

Puis formule en U5 :

=SI(V5="";"";SOMMEPROD(MOD(COLONNE(C5:S5);2)*C5:S5)+V5/1000)

Comme déjà dit les "/1000" sont facultatifs.

Fichier joint.

 

[CISCO]

Re : Départager avec un critère "Temps" en cas d'égalité

Bonjour

Re,

Du coup on peut conserver la formule avec RANG en W5.

Et oui, en mettant directement le temps dans la colonne U (même si l'affichage fait qu'on ne voit pas ce changement).

@plus

 

[job75]

Re : Départager avec un critère "Temps" en cas d'égalité

Re,

En fait la bonne formule en V5 est celle-ci :

=SI(NB.VIDE(C5:T5);"";SOMMEPROD(MOD(COLONNE(C5:S5);2)*D5:T5))

En effet si le temps d'une étape manque le total de l'équipe ne doit pas être calculé.

Fichier (2).

PS : j'ai aussi ajouté les formules en colonnes C E G I K M O Q S.

A+

 

[jalucyne]

Re : Départager avec un critère "Temps" en cas d'égalité

Merci pour ces nombreux message, toujours aussi pertinents.
Cela fait toujours aussi drôle avec ce décalage horaire de se lever et de voir que des passionnés ont bossé pendant que je dormais.
Encore merci.
Jalucyne de Tahiti

 

[jalucyne]

Re : Départager avec un critère "Temps" en cas d'égalité

A propos de la remarque de Job 75:
PS : j'ai aussi ajouté les formules en colonnes C E G I K M O Q S.

Cela n'est pas nécessaire de les départager au temps,car il ne peut pas y avoir d'égalité dans une étape danscce type de course ( de Va'a, pirogues Polynésiennes.)
Je renouvelle mes remerciements à tousz les membres de la discussion.
Jalucyne de Tahiti
PS: l'Eimeo Va'a Race est une course de pirogues scolaires faisant le tour de l'Ile de Moorea par le lagon , samedi prochain , 42 équipes de 6 rameurs se disputeront la victoire 2015.

 

[job75]

Re : Départager avec un critère "Temps" en cas d'égalité

Re,

A propos de la remarque de Job 75:
PS : j'ai aussi ajouté les formules en colonnes C E G I K M O Q S.

Cela n'est pas nécessaire de les départager au temps,car il ne peut pas y avoir d'égalité dans une étape danscce type de course ( de Va'a, pirogues Polynésiennes.)

Les formules que j'ai mises déterminent la place en appliquant la fonction RANG aux temps.

Il est quasiment impossible d'avoir des ex-aequo.

A+

 

[CISCO]

Re : Départager avec un critère "Temps" en cas d'égalité

Bonsoir

PS: l'Eimeo Va'a Race est une course de pirogues scolaires faisant le tour de l'Ile de Moorea par le lagon , samedi prochain , 42 équipes de 6 rameurs se disputeront la victoire 2015.

J'irai bien les voir, mais c'est un peu loin...

@ plus