affiché les + grande valeur

[Surfeur En Serie]

Bonjour tt le monde et meilleur voeux à tous

J'ai un tableau A1:I27 qui comporte des nombres ( aleatoire et non nul ) ,des annotations et des lignes vierges.
Je souhaiterai affiché en bas en A28 le nombre qui apparrait le plus souvent , en B28 le nombre qui apparrait le plus souvent apres celui du A28 etc jusqu en I28.

je joins un fichier pour vous aider
merci de m aider

 

[Tibo]

Re : affiché les + grande valeur

Bonjour,

Avec ce que j'ai compris, une tentative avec :

en A28 :

=MODE(A1:H26)

en B28, une formule matricielle :

=MODE(SI(A1:G26=1;B1:H26))

Formule matricielle à valider par CTRL + MAJ + ENTREE

Je te laisse tester

@+

 

[Surfeur En Serie]

Re : affiché les + grande valeur

merci de t 'interresser a mon probleme
pour la formule en A28 ( =MODE(A1:H26) ) , ça a l'air de fonctionner
pour la formule matriciel, ça ne fonctionne pas .
en modifiant mes données tu verra que l on se retrouve avec le meme resultat en matriciel ou en formule en case A28 et B28
je te remet mon fichier modifié
PS: je pense que tu n as pas compris ( ou je me suis mal exprimé ) mais en ligne A28 jusqu a I28 les cases sont rempli du plus grand au plus petit nombre entrée.

 

[hoerwind]

Re : affiché les + grande valeur

Bonjour, salut Tibo,

Une proposition avec colonne intermédiaire.
Il subsiste le problème d'éventuels doublons, sous l'exemple 3 et 13, 10 fois chacun.

 

[Surfeur En Serie]

Re : affiché les + grande valeur

hello et merci hoerwind
ça a l'air de fonctionner pour le moment, je testerai ça correctement ( ce soir ou demain maxiumum ) avec les valeurs alleatoires et je te dirrai si OFFICIELLEMENT ça fonctionne ou non.

 

[david84]

Re : affiché les + grande valeur

Bonsoir, Hoerwind Tibo,
même idée qh'Hoerwind mais les 0 sont pris en compte et les égalités traitées.
A+

Edit : fichier retiré(erreur)

 

[david84]

Re : affiché les + grande valeur

Re
ci-joint nouvelle proposition à tester.
A+

 

[olivowitch]

Re : affiché les + grande valeur

Salut,

vos formules marchent très bien.
Pouvez-vous m'indiquer ce que signifie =NB.SI(zone;LIGNE()-1)
Pour que j'essaye de comprendre comment vous avez procédé pour y arriver.

Merci

 

[david84]

Re : affiché les + grande valeur

Re
ci-joint proposition sans colonne intermédiaire (cf fichier) :en fait, il fallait trouver le moyen d'utiliser mode correctement mais j'ai eu du mal à cerner la fonction.

=MODE(SI((zone<>"")*(ESTNUM(zone))*(NB.SI($A28:A28;zone)=0);zone))

Validation matricielle.
A+

Edit : on peut encore simplifier :

=MODE(SI((ESTNUM(zone))*(NB.SI($A28:A28;zone)=0);zone))

 

[Surfeur En Serie]

Re : affiché les + grande valeur

hello le fil
donc pour moi , ça correspond parfaitement a ce que je voulais. je n ai plus qu a mettre ça en place correctement sur mon fichier final.

Merci a tous

 

[david84]

Re : affiché les + grande valeur

Re
Dans le précédent fichier, la formule ne prend pas en compte des nombres dont mode ramène 1 (dans ce cas, la fonction Mode n'est pas utilisée car elle ramène "#N/A").
Si cela ne pose pas de problème, la formule proposée initialement fait donc l'affaire. Dans le cas contraire, l'affaire se complique !
Ci-joint un nouveau fichier remédiant à cela avec plusieurs possibilités :
- 1ère ligne avec la fonction Mode ramenant l'ensemble des nombres dont le Mode est >= à 1;
- 2ème ligne avec une autre formule ramenant le reste des nombres dont le Mode est = à 1;
- 3ème ligne combinant les 2 formules.
Dans ces 3 lignes, les valeurs d'erreur sont masquées via l'utilisation de MFC.
- 4ème ligne combinant les 2 formules et sans utilisation de MFC : j'ai dû nommer certaines parties de la formule pour que les versions antérieures à 2007 la prenne en compte (si tu as 2007, tu peux recopier la formule complète placée dans la zone de texte et l'adapter à la ligne dans laquelle tu la copies). Sinon, tu as la possibilité d'utiliser les propositions précédentes avec une colonne intermédiaire que tu peux masquer si besoin.
A+

 

[Surfeur En Serie]

Re : affiché les + grande valeur

merci david84
Je ferrai un autre teste avec ton fichier pour voir si cela serrai plus pratique pour moi dans l evolution de mon projet.
je n 'oublierai de faire un poste pour te dire si oui ou non cela fonctionne bien sur
merci encore

 

[david84]

Re : affiché les + grande valeur

Re,re
en fait, j'ai trouvé plus simple que de passer par Adresse : utiliser min

=SI(COLONNES($A:A)>SOMME(SI((zone<>"")*(ESTNUM(zone));1/NB.SI(zone;zone)));"";SI(ESTNA(MODE(SI((ESTNUM(zone))*(NB.SI($A31:A31;zone)=0);zone)));MIN(SI((zone<>"")*(ESTNUM(zone))*(NB.SI(zone;zone)=1)*(NB.SI($A31:A31;zone)=0);zone));MODE(SI((ESTNUM(zone))*(NB.SI($A31:A31;zone)=0);zone))))

et là tu as tout : tous les nombres (Mode >1 et les valeurs uniques), les valeurs d'erreurs qui n'apparaissent pas grâce à l'utilisation d'un test logique inclus dans la formule et une formule compatible avec les versions antérieures à 2007.
A+

 

[Tibo]

Re : affiché les + grande valeur

Salut David,

Pas grand chose à dire.

A part : BRAVO

@+

 

[david84]

Re : affiché les + grande valeur

Re
Merci Tibo.
un peu plus court :

=SI(COLONNES($A:A)>SOMME(SI(ESTNUM(zone);1/NB.SI(zone;zone)));"";SI(ESTNA(MODE(SI((ESTNUM(zone))*(NB.SI($A31:A31;zone)=0);zone)));MIN(SI((ESTNUM(zone))*(NB.SI(zone;zone))*(NB.SI($A31:A31;zone)=0);zone));MODE(SI((ESTNUM(zone))*(NB.SI($A31:A31;zone)=0);zone))))

Formule à rentrer en l'état en B31 (ou à adapter) et à valider par Ctrl, Maj et entrée.
A+