XL 2016 VBA Curiosité ComboBox

[Dudu2]

Bonjour,

Lorsqu'une ComboBox:
- (1) est chargée via la propriété ComboBox.List
et
- (2) parmi les valeurs chargées certaines sont numériques,
la valorisation ultérieure de la ComboBox.Value = x avec une valeur numérique de sa propre liste ne positionne pas le ComboBox.ListIndex sur la valeur en question et est valorisé à -1.

Ce n'est pas le cas si les conditions (1) et (2) ne sont pas réunies où le ComboBox.ListIndex prend alors une valeur correcte correspondant à la position de la valeur dans la liste.

J'ai tout essayé mais la seule option a été de passer par une fonction qui charge les valeurs de ComboBox.List en Tableau et les compare à la valeur à charger pour corriger le ComboBox.ListIndex.
Mais peut-être y a -t-il un moyen plus direct ? (Un petit sujet de réflexion sans caractère essentiel)

Edit: fichier corrigé à 18h33

 

[laurent950]

Bonsoir

Sub ComboBox1_ValueFromList()
Dim macombo As MSForms.ComboBox
    Set macombo = Feuil1.ComboBox1
    macombo.List = Feuil1.Range("A1:A3").Value
'    macombo.ListIndex = -1 ' Rien
'    macombo.ListIndex = 0 ' AAA
    macombo.ListIndex = 1 ' BBB
    ' Etc.
End Sub

 

[patricktoulon]

bonsoir
en effet @Dudu2 l’accès a la combo se comporte différemment sur une feuille
étonnant
je suppose qu'il n'y a plus accès en charge avec un ".value" peut être un peu plus lourd a digérer alors que fillrange est mieux intégré en callback

 

[Dudu2]

Bonsoir @patricktoulon,
J'ai posé la question histoire de distraire un peu la compagnie parce qu'à mon avis, y a rien qu'on puisse faire.
Je pense à un bug VBA ComboBox.

J'ai eu à faire face à ça lors d'un rechargement de formulaire à partir de données enregistrées.
Et j'ai dû faire cette fonction pour repositionner le ListIndex.

'----------------------------------------------------
'Lorsqu'une ComboBox (1) est chargée via sa propriété
'List (ComboBox.List =) et non pas avec sa propritété
'ListFillRange (ComboBox.ListFillRange =) et qu'on la
'valorise (ComboBox.Value =) avec une de ses valeurs
'de liste (2) numérique, sa propriété ListIndex est
'valorisée à -1 !
'Ce n'est pas le cas si les conditions (1) & (2) ne
'sont pas réunies, auquel cas sa propriété ListIndex
'indique bien la position de la valeur dans la liste.
'----------------------------------------------------
Private Sub ComboBoxValeur(ByRef ComboBox As ComboBox, ByVal Valeur As Variant)
    Dim i As Integer
    Dim TabValeurs() As Variant
 
    'Valorise la ComboBox
    ComboBox.Value = Valeur
 
    'ComboBox valorisée avec une de ses valeurs texte
    If ComboBox.ListIndex >= 0 Then Exit Sub
 
    'ComboBox valorisée avec une de ses valeurs numériques
    TabValeurs = ComboBox.List
 
    For i = LBound(TabValeurs, 1) To UBound(TabValeurs, 1)
        If CStr(TabValeurs(i, 0)) = CStr(Valeur) Then Exit For
    Next i
 
    'Valeur trouvée, corrige le ListIndex
    If i <= UBound(TabValeurs) Then
        ComboBox.ListIndex = i
    End If
End Sub

 

[patricktoulon]

je sais pas
si c'est un bug ou une histoire d'accès
je me dis que si il y a une fonction listfillrange intégré c'est que peut être pas pour rien
ou listfillrange est la seule correction qu'ils on été capable de faire
découverte intéressante en tout cas

 

[Dranreb]

Bonsoir.
Personnellement je ne garnis jamais une List de ComboBox avec un tableau contenant des nombres.
Je les convertis toujours préalablement en String. Et je vous recommande de faire de même. De toute façon sa Value sera un Variant/String, alors autant que tous les éléments de sa List en soient aussi. J'avais depuis longtemps constaté des anomalies de ce genre à la frappe notamment: il ne propose pas de suite prise de sa List si ce sont des nombres.

 

[patricktoulon]

re
Dudu2
Tiens fait cette petite expérience
ajoute l'event dans la feuille de la combo

Private Sub ComboBox1_Change()
If ComboBox1.ListIndex > -1 Then ComboBox2_ValueFromList True
End Sub

et modifie ta sub comme suit

Public Sub ComboBox2_ValueFromList(Optional active As Boolean = False)
   If Not active Then
   'ActiveSheet.ComboBox2.ListFillRange = ""
    ActiveSheet.ComboBox2.List = ActiveSheet.Range("B1:B3").Value
    ActiveSheet.ComboBox2.Value = 2020
    'ActiveSheet.ComboBox2.Value = CDbl(2020)
    'ActiveSheet.ComboBox2.Value = CStr(2020)
    'ActiveSheet.ComboBox2.Value = Format(2020, "0000")
    End If
    If active = True Then MsgBox "ComboBox2.ListIndex = " & ActiveSheet.ComboBox2.ListIndex
End Sub

1er essai lance la macro a partir du menu macro
2d essai click sur ton bouton
donc le focus sur la shape appelante'bouton 4'
surprenant non!!!
en même temps pas tant que ça si observe de plus près

ça confirme mon idée sur l’accès en charge

maintenant 3eme essai test tout simplement ta sub d'origine en l'appelant du menu macro

voila maintenant tu sais ce que fait listfillrange parallèlement a remplir ta liste

et donc tout devient plus clair quand on connait le comportement d'une shape sélectée

pour moi ça n'est donc pas un bug mais bel et bien une méthode

 

[job75]

Bonjour les amis,

en effet @Dudu2 l’accès a la combo se comporte différemment sur une feuille

Je l'ai cru aussi mais j'ai vérifié : c'est la même chose sur un UserForm.

Pour l'éviter il faut comme l'a dit Bernard que la liste soit du texte :

ActiveSheet.ComboBox2.List = ActiveSheet.Range("B1:B3").Formula

A+

 

[Dudu2]

@patricktoulon, Ok, je vois. Merci pour ce test.

 

[Dudu2]

@job75,

Tout transformer en String est en effet une méthode pour palier ce comportement étrange.
Mais alors ça veut dire qu'il faut toujours faire attention au chargement à partir d'un Range et passer par un table de String.

Sub ComboBox2_ValueFromList()
    Dim TabVal() As Variant
    Dim i As Integer
    Dim j As Integer
    
    'Chargement du Range en table
    TabVal = ActiveSheet.Range("B1:B3").Value
    
    'Transformation des valeur en String
    For i = 1 To UBound(TabVal, 1)
        For j = 1 To UBound(TabVal, 2)
            TabVal(i, j) = CStr(TabVal(i, j))
        Next j
    Next i
    
    ActiveSheet.ComboBox2.ListFillRange = ""
    
    'Chargement de la table de String en ComboBox
    ActiveSheet.ComboBox2.List = TabVal
    
    ActiveSheet.ComboBox2.Value = "2020"
    MsgBox "ComboBox2.ListIndex = " & ActiveSheet.ComboBox2.ListIndex
End Sub

 

[patricktoulon]

re
ou

Sub ComboBox2_ValueFromList()
    Dim TabVal() As Variant
    Dim i As Integer
    Dim X&
    'Chargement du Range nen table
    TabVal = ActiveSheet.Range("B1:B3").Value
    
    'Transformation des valeur en String
    'For i = 1 To UBound(TabVal, 1)
        'TabVal(i, 1) = CStr(TabVal(i, 1))
    'Next i
    
    ActiveSheet.ComboBox2.ListFillRange = ""
    
    'Chargement de la table de String en ComboBox
    ActiveSheet.ComboBox2.List = TabVal
    
    x = Application.IfError(Application.Match(2020, ActiveSheet.ComboBox2.List, 0), -1) - 1
       ActiveSheet.ComboBox2.ListIndex = x
    'ActiveSheet.ComboBox2.Value = "2020"
    MsgBox "ComboBox2.ListIndex = " & ActiveSheet.ComboBox2.ListIndex
End Sub

 

[job75]

Si la plage source est constituée de constantes la propriété Formula les transforme en String.

 

[Dudu2]

Ok, donc soit mise en formule des valeurs numériques (si on y pense), soit recherche avec Application.Match.

Je crois que je vais finir par charger les ComboBox avec un fonction généraliste (autant que possible).

'------------------------------------------------------------
'Chargement d'une ComboBox à partir d'un Range ou d'une Table
'en s'assurant que les items de la ComboBox sont tous de type
'String pour éviter les comportements étranges sur les items
'de type valeurs numériques.
'------------------------------------------------------------
'https://www.excel-downloads.com/threads/vba-curiosite-combobox.20051806/
'------------------------------------------------------------
Sub ComboBoxListLoad(ByRef Cmb As ComboBox, ByRef RngOrTab As Variant, Optional ItemFormat As String = "@")
    Dim TabVal() As Variant
    Dim TabValArea() As Variant
    Dim Area As Range
    Dim i As Long
    Dim k As Long
    Dim ErrNumber As Variant
    
    'Suppression du ListFillRange / RowSource éventuel
    On Error Resume Next
    Cmb.ListFillRange = ""  'ComboBox non UserForm
    Cmb.RowSource = ""      'ComboBox UserForm
    On Error GoTo 0

    'L'argument est de type Range
    If TypeOf RngOrTab Is Range Then
        
        'D'une seule  cellule
        If RngOrTab.Cells.Count = 1 Then
            ReDim TabVal(1 To 1)
            TabVal(1) = RngOrTab.Value
        
        'De plusieurs cellules
        Else
            ReDim TabVal(1 To RngOrTab.Cells.Count)
            k = 0
            
            'Parcours des Areas du Range
            For Each Area In RngOrTab.Areas
                TabValArea = Area.Columns(1).Value
                
                For i = 1 To UBound(TabValArea, 1)
                    TabVal(k + i) = TabValArea(i, 1)
                Next i
                k = k + UBound(TabValArea, 1)
            Next Area
        End If
        
    'L'argument est de type Tableau
    Else
        On Error Resume Next
        i = UBound(RngOrTab, 2)
        ErrNumber = Err.Number
        On Error GoTo 0
        
        'Table à 1 dimension
        If ErrNumber <> 0 Then
            TabVal = RngOrTab
        
        'Table à 2 dimensions
        Else
            For i = LBound(TabVal, 1) To UBound(TabVal, 1)
                TabVal(i) = RngOrTab(i, 1)
            Next i
        End If
    End If

    'Conversion des valeurs en String ou mise au format
    For i = LBound(TabVal) To UBound(TabVal)
        TabVal(i) = Format(TabVal(i), ItemFormat)
    Next i
    
    'Chargement de la ComboBox
    Cmb.List = TabVal
End Sub

 

[Dudu2]

Merci à tous pour vos contributions explicatives toujours enrichissantes

 

[Dranreb]

Il y a plein de fonctionnalités généralistes dans cette ressource :

ComboBox liées et contrôles associés

Définit deux types d'objets à évènements: ComboBoxLiées prenant en charge les ComboBox pour la saisie des données d'identification de la ligne à créer, puis, ultérieurement, à consulter voire modifier, et ControlsAssociés prenant en charge les...

www.excel-downloads.com

(dont celle dont il était question: toutes les listes fabriquées son composées de String, classées et sans doublon, et la réécriture dans un tableau des valeurs de la ligne les retransforme en nombres s'il y a lieu, sauf demande expresse à l'initialisation.)