Trier données dans graphiques

[leaales]

Bonjour,
J'ai un tableau de données que je veux visualiser en graphique. une colonne supplémentaire du tableau contient la lettre A ou B. Je sais faire un tri pour n'afficher dans le tableau que les lignes contenant A (ou B). Mais je voudrais que ce tri marche aussi pour l'affichage du graphique (ne voir que les points correspondant à des A ou ceux correspondant à des B). Est-ce possible avec une macro par exemple?
Merci!
léa.

 

[MichelXld]

Re : Trier données dans graphiques

bonjour

C'est possible par macro à condition que le graphique ne contienne pas trop de données:
dans cet exemple les données sont les colonne A/B et les lettres filtres dans la colonne C

Option Explicit
Option Compare Text

Sub creationGraphiqueParTabAbscisses()
    Dim Cell As Range
    Dim i As Byte
    Dim TabAbscisses() As Variant
    Dim TabOrdonnees() As Single
    Dim Cible As String
    
    'Lettre filtre contenue dans la colonne C
    Cible = "A"
    
    'Les lettres A ou B sont dans la colonne C
    For Each Cell In Range("C1:C10")
        If Cell = Cible Then
            i = i + 1
            'Redimensionne le tableau
            ReDim Preserve TabAbscisses(1 To i)
            ReDim Preserve TabOrdonnees(1 To i)
            
            TabAbscisses(i) = Cell.Offset(0, -2) 'Col A
            TabOrdonnees(i) = Cell.Offset(0, -1) 'Col B
        End If
    Next Cell
    
    'Création graphique
    Charts.Add
    'Définit la localisation du graphique:
    'dans la feuille de calcul Feuil1 pour cet exemple
    ActiveChart.Location _
        Where:=xlLocationAsObject, Name:="Feuil1"
    
    'Ajoute une série dans le graphique
    With ActiveChart
        .SeriesCollection.NewSeries
        .SeriesCollection(1).XValues = TabAbscisses() 'Abscisses
        .SeriesCollection(1).Values = TabOrdonnees() 'Ordonnées
        'Définit le type (Courbe)
        .ChartType = xlLine
    End With
End Sub

Bonne journée
MichelXld

 

[CB60]

Re : Trier données dans graphiques

Bonjour à tous
Tu peut aussi le faire avec un TCD