Sommeprod

[C@thy]

Bonjour,

ceci :
=SOMMEPROD((AU1:AU4="non liée")*(AV1:AV4="centre de service"))

marche parfaitement (sur 4 lignes),
mais vu que je ne sais pas combien j'ai de lignes remplies,
j'ai remplacé par AU:AU et AV:AV et là, KATASTROPH!!! a marche pu!

On fait comment???

Merciiiiiiii de votre aide.

Bises

C@thy

 

[CISCO]

Re : Sommeprod

Bonjour

Pour faire simple, pourquoi pas avec
=SOMMEPROD((AU1:AU6000="non liée")*(AV1:AV6000="centre de service")) ?

@ plus

 

[Catrice]

Re : Sommeprod

Bonsoir,

Ceci fontionne :

=SOMMEPROD((AU1:AU65535="non liée")*(AV1:AV65535="centre de service"))

D'apres ce que j'ai compris dans l'aide, c'est "normal" :
Spécifications relatives au calcul :
Matrices de feuilles de calcul Limité par la quantité de mémoire disponible. Les matrices ne renvoient pas toujours à des colonnes entières. Par exemple, une matrice ne peut pas renvoyer à la colonne entière C:C ou à la plage C1:C65536. Une matrice peut toutefois renvoyer à la plage C165535 parce que la plage comporte une ligne de moins que la taille de feuille de calcul maximale et ne contient pas la colonne C ou D entière.

 

[C@thy]

Re : Sommeprod

Merci Cisco, j'y avais pensé, en effet.

Je viens de faire des recherches et j'ai trouvé une réponse de Jocelyn à ce sujet,
donc j'ai nommé mes plages comme ceci :

=DECALER(interactions!$B$2;;;NBVAL(interactions!$A:$A)-1)
=DECALER(interactions!$E$2;;;NBVAL(interactions!$A:$A)-1)

ça fonctionne.

Merci à vous, et à Jocelyn.

Bises

C@thy

 

[C@thy]

Re : Sommeprod

Coucou Catrice, j't'avais pâ vu, j'étais en train d'écrire ma réponse.

Eh oui, SOMMEPROD ne veut pas de colonne entière, j'avais remarqué!

Bizzz

C@thy

 

[abcd]

Re : Sommeprod

Bonjour .... ,

Avec une matricielle sur 6000 lignes cela pourrait prendre du temps lors des calculs !

Pourquoi ne pas nommer les plages :
AU → =DECALER($AU$1;;;NBVAL($AU$1:$AU$6000))
idem pour AV.

abcd

Edition
Ah ce foutu téléphone qui ne rafraichit pas XLD quand je dépose le cornet !
Il faudra que je trouve une petite formule.

 

[Catrice]

Re : Sommeprod

Re,

La plage nommée ne fontionnera pas s'il y a des trous
Il faut utiliser alors la formule de la derniere cellule pleine avec recherchev (je crois) dont je ne me souviens plus.

Edit : A priori, d'apres la formule de Cathy, la colonne A est la reference et doit etre pleine ...

 

[C@thy]

Re : Sommeprod

Oui, la colonne A est toujours remplie, c'est le code de l'incident, il est indispensable, c'est pourquoi j'ai pris cette colonne en référence, car les autres ont des trous...

Merci pour tout

Bibises

C@thy

 

[C@thy]

Re : Sommeprod

Catrice, pour récupérer le contenu de la dernière cellule remplie :
=INDIRECT("A"&MAX(SI(A1:A65535<>"";LIGNE(A1:A65535))))
valider en matricielle

ceci donne le numéro de ligne de la dernière cellule remplie, à condition qu'il n'y ait pas de trous.
=LIGNE(DECALER(A1;NBVAL(A:A)-1)
Pour avoir la 1ère vide on enlève le -1 bien sûr.

Bises

C@thy

 

[abcd]

Re : Sommeprod

C@thy,

Pour récupérer le contenu de la dernière cellule remplie :
=RECHERCHE("zz";A:A)

Pour récupérer le numéro de la ligne de la dernière cellule remplie :
=EQUIV(RECHERCHE("zz";A:A);A:A)
ne fonctionne pas s'il y a des doublons
ou bien tout simplement s'il n'y a pas de cellules vides : =NBVAL(A:A)

abcd

 

[C@thy]

Re : Sommeprod

Merci à toi, abcd, tes formules sont plus courtes!

Bises

C@thy

 

[Monique]

Re : Sommeprod

Bonjour,

N° de la dernière ligne remplie

Pour des nombres
=EQUIV(9^9;A:A)

Pour du texte
=EQUIV("zz";A:A)