XL pour MAC SI(SOMMEPROD

[pilou010]

Bonjour à tous,
Une fois de plus je viens prendre de l'aide ici...
Dans le fichier que j'ai joint à ce message je souhaiterai faire une somme par mois avec 2 conditions (suivant le contenu d'autres cellule).

La formule que j'utilise :

=SI(SOMMEPROD(MOIS(Tableau1[[#En-têtes];[Date]])=K$2)*(Tableau1[[#En-têtes];[Rubrique]]=I$3)*(Tableau1[[#En-têtes];[Libellé]]=J$3);INDEX(Tableau1;;4))

Merci d'avance pour votre patience et votre aide

Pilou

 

[R@chid]

Bonjour @ tous,
Voir PJ
J'ai créé des champs dynamiques, voir Gestionnaire de Noms.


Cordialement

 

[Dugenou]

Bonjour Pilou, Bonjour R@chid (c'est mieux cette photo que le dessin d'araignée précédent
Une solution en pj avec somme.si.ens et une colonne supplémentaire dans le tableau. et une ligne avec le N° du mois : donc beaucoup moins élégant que ce qu'a fait R@chid
La synthaxe un peu spéciale : Tableau1[[Débit]:[Débit]] en doublant le nom de colonne permet d'éviter le changement de colonne quand on recopie à droite.
Cordialement
PS R@chid : trop fort le MOIS("1/"&K$3). Par contre j'ai pensé qu'il fallait faire le total des débits, pas des soldes !

 

[R@chid]

Re,
Salut Dugenou
les noms des champs des tableaux structurés et les noms de leurs cellules rend la formule trop lognue et moins lisible.

j'ai pensé qu'il fallait faire le total des débits, pas des soldes !

Ce n'était pas précisé, donc c'est à lui de prendre nos formules et de les adapter à son besoin.

Au plaisir

 

[R@chid]

Re,

R@chid (c'est mieux cette photo que le dessin d'araignée précédent

J'ai supprimé le dessin d'araignée et j'ai mis ma propre photo espérant vous faire peur mais ça n'a pas réussi apparemment

 

[vgendron]

Hello le fil
avec cette formule en L4

SOMMEPROD((MOIS(Tableau1[[Date]:[Date]])=MOIS("1/"&K$3))*(Tableau1[[Rubrique]:[Rubrique]]=$I4)*(Tableau1[[Libellé]:[Libellé]]=$J4)*Tableau1[[Débit]:[Débit]])

Permet d'éviter les zones nommées et d'utiliser les noms de colonnes de la table excel

et en passant: Merci Rachid pour le mois("1/"&....) je ne connaissais pas
et merci Dugenou pour le doublement des [] pour éviter que les colonnes se déplacent.... je ne connaissais pas non plus et me tapait à chaque fois toutes les formules... :-D

 

[pilou010]

SOMMEPROD((MOIS(Tableau1[[Date]:[Date]])=MOIS("1/"&K$3))*(Tableau1[[Rubrique]:[Rubrique]]=$I4)*(Tableau1[[Libellé]:[Libellé]]=$J4)*Tableau1[[Débit]:[Débit]])

Permet d'éviter les zones nommées et d'utiliser les noms de colonnes de la table excel

En faisant mes essais je remarque que si il n'y a pas de date inscrites dans le tableau 1, les sommes de débit s’additionnent en janvier !
Y a t-il une possibilité de l'éviter ?
Sinon toutes les solutions sont au top...
Merci à tous pour votre aide.
Pilou

 

[Dugenou]

Ajoutez une condition précisant que la date doit être supérieure à 1 : SOMMEPROD((MOIS(Tableau1[[Date]:[Date]])=MOIS("1/"&K$3))*(Tableau1[[Date]:[Date]]>1)*(Tableau1[[Rubrique]:[Rubrique]]=$I4)*(Tableau1[[Libellé]:[Libellé]]=$J4)*Tableau1[[Débit]:[Débit]])

 

[pilou010]

Génial, MERCI A TOUS ! ! !
Bon dimanche

 

[R@chid]

Bonjour @ tous,

Ajoutez une condition précisant que la date doit être supérieure à 1 : SOMMEPROD((MOIS(Tableau1[[Date]:[Date]])=MOIS("1/"&K$3))*(Tableau1[[Date]:[Date]]>1)*(Tableau1[[Rubrique]:[Rubrique]]=$I4)*(Tableau1[[Libellé]:[Libellé]]=$J4)*Tableau1[[Débit]:[Débit]])

On peut écrire la formule comme ci-dessous :

=SOMMEPROD((Tableau1[Rubrique]=[@Rubrique])*(Tableau1[Libellé]=[@Libellé])*(MOIS(Tableau1[Date])=MOIS("1/"&K$3));Tableau1[Débit])

et pour contourner le problème d'incrémentation vers la droite, je vous conseille de ne pas le faire avec la souris, car c'est en tirant vers la droite avec la souris qui pose le problème de changement de champs.


Sélectionner tout le tableau K4:V15
Copier/Coller la formule dans la barre de formule
Puis valider avec la combinaison des 2 touches Ctrl+Enter


Cordialement


EDIT :
Une astuce :
Ctrl+D ==> copier vers la droite
Ctrl+B ==> copier vers le bas

Taper la formule dans K4, valider par simple Enter (ou Ctrl+Enter pour garder le curseur dans K4)
Sélectionner toute la plage K4:V15, Ctrl+D puis Ctrl+B et c'est fait

 

[pilou010]

Bonjour,
En créant un nouveau fichier je suis revenu ici pour reprendre les formules que j'avais demandées ici mais je rencontre un souci...
Je ne change que Débit en Crédit et cela me renvoie une erreur ! ! !

Edit : il manquait 1 crochets de chaque cotés de Crédit.

Pilou
=SOMMEPROD((OPERATIONS[Rubrique]=[@Rubrique])*(OPERATIONS[Libellé]=[@Libellé])*(ANNEE(OPERATIONS[Date])=ANNEE("1/"&$A$8))*(MOIS(OPERATIONS[Date])=MOIS("1/"&E$9));OPERATIONS[[Crédit]])