XL 2013 [RESOLU]Convertir somme.si en sous.total.si

[ozzii]

Bonjour le forum,

actuellement j'ai cette formule :
=SI($K25="";"";SOMME.SI($I$2:$I21;$K25;M$2:M21))

Ce que j'aimerais c'est l'avoir en formule "sous.total" car j'ai besoin de faire des filtres sur mon tableau.
Je n'arrive pas à trouver comment faire.
Une âme charitable pour une aide ?

P.S. : je pense ne pas avoir besoin de fichier pour la démo. Au besoin dîtes-le moi et j'en ferais un.

 

[job75]

Bonjour ozzii,

=SOMMEPROD((I2:I21=K25)*SOUS.TOTAL(9;DECALER(M2;LIGNE(M2:M21)-2;)))

Je vous laisse voir pour les signes $ si vous devez en placer.

A+

 

[ozzii]

Merci job75.
Je n'avais pas pensé à sommeprod.
Je teste et je reviens pour le verdict

 

[ozzii]

Bon ben me revoilà.
Cela fonctionne à merveille.
Et en bonus un petit "decaler"
Merci encore job75

 

[ozzii]

Bonjour,
j'essaye de faire un truc mais cela ne fonctionne pas.
J'ai cela :

SOMMEPROD((CAT_TABLEAU=$K25)*SOUS.TOTAL(9;DECALER(M$2;LIGNE(M$2:DECALER(M$2;0;0;LIGNE()-5;1))-2;)))

Mais quand je met ça, cela ne fonctionne pas (à la place du décaler je met sons nom)

SOMMEPROD((CAT_TABLEAU=$K25)*SOUS.TOTAL(9;COLONNEM))

Une idée ?

 

[job75]

Bonjour ozzi,

Si l'on nomme "COLONNEI" la plage en colonne I et "COLONNEM" la plage en colonne M :

=SOMMEPROD((COLONNEI=$K25)*SOUS.TOTAL(9;DECALER(INDEX(COLONNEM;1);LIGNE(COLONNEM)-LIGNE(INDEX(COLONNEM;1));)))

Les 2 plages doivent avoir bien sûr les mêmes dimensions.

A+

 

[ozzii]

Et moi qui pensais qu'il fallait enlever le decaler.
Merci encore job75 pour l'aide (et qui plus est, rapide).

 

[job75]

Re,

DECALER permet d'introduire la matrice LIGNE(plage) qui est indispensable.

A+

 

[ozzii]

Mais c'est marrant que je puisse mettre M1:M10 et non COLONNEM (qui est M1:M10)!!
Enfin bon, l'essentiel c'est que cela fonctionne.
Merci encore

 

[job75]

Une référence de plage peut toujours être remplacée par le nom de la plage.

 

[ozzii]

Oui, mais pas dans ce cas car il faut y rajouter des decaler et des index.
C'est ce que je voulais dire.