[Résolu] Calcul d'horaires avec répartition multiple de %

[Guyzinho]

Bonjour à tous,

Je vous expose mon "problème".

Je dois créer un tableau dans lequel je dois insérer une heure d'entrée et une heure de sortie. En fonction des heures et des jours, je dois répartir les heures dans différentes cases. Je m'explique :

Du lundi au vendredi, de 7h00 à 17h00, il faut que "10:00" apparait dans la colonne "Heure normale". Si la sortie est à 18h00, il faut toujours "10:00" dans la colonne "Heure normale" et "1:00" dans la colonne "Heure 50%". Toutefois, si l'entrée se fait après 17h00, il ne faut plus rien dans la colonne "Heure normale" mais le laps de temps doit s'afficher dans la colonne "50%". En outre, après 22h00, chaque heure doit s'indiquer dans la colonne "Av. Nocturne".

J'ai plus ou moins réussi l'exercice MAIS j'ai un gros soucis avec les heures de nuit et je n'ai pas encore intégré les samedi, dimanche et fériés. Pour ces derniers, je pensais à intégrer une condition supplémentaire dans la colonne jour "S" pour samedi, "D" pour dimanche et "F" pour fériés.

Je vous joins mon fichier dans lequel vous trouverez également le tableau de répartition des heures et pourcentages.

Toute aide sera la bienvenue car cela fait quelques jours que je m'arrache les cheveux.

Je vous remercie pour le temps que vous avez consacré à mon post et à celui que vous prendrez pour m'aider.

Guy.

 

[Victor21]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour, et bienvenue sur XLD

Un essai en pj avec les exemples que vous avez fournis.

 

[Guyzinho]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour Victor,

Tout d'abord merci pour votre aide.

Je pense que je me suis mal exprimé. Si l'entrée est, par exemple, à 18h00 et la sortie à 23h00, dans la colonne 50%, il faut 5h et dans la colonne Nocturne il faut 1H. L'heure de la colonne nocturne ne doit pas être décomptée de la colonne 50%.

En outre, lorsque j'entre 2 horaires (j'ai pris comme exemple : entrée 23h00 et sortie 4:00) sur la ligne 6, aucun calcul ne se fait alors que les formules s'y trouvent.

Je ne remets pas en cause votre aide, loin de moi cette idée, car, étant moi-même perdu, j'attraperai toutes les bouées qu'on veut bien me lancer

Dites-moi, auriez-vous une idée sur la faisabilité de ces calculs par rapport à samedi, dimanche et férié svp ?

Bien cordialement,

Guy.

 

[Victor21]

Re : Calcul d'horaires avec répartition multiple de %

Re,

transmettez un exemple avec tous les cas possibles, et les résultats souhaités (calculés manuellement).

Concernant les samedis, dimanches, la fonction joursem() et pour les fériés, la fonction nb.si permettent de faire les tests.
Alors oui, c'est possible.
A condition que les résultats souhaités soient clairement explicités. (je n'ai pas compris la colonne Nocturne(20%)

 

[Guyzinho]

Re : Calcul d'horaires avec répartition multiple de %

Re,

Vous trouverez, ci-joint, un fichier avec exemples manuels comme demandé.

Pour donner un exemple de l'utilité de la colonne nocturne, admettons qu'une personne travaille de 17h00 à 23h00, il preste 6 heures (à 50%) dont une "nocturne" qui est avantage en plus. La case 50% aura comme résultat 6 heures et la case nocturne aura, quant à elle, 1H (comme vous pourrez le constater dans les exemples manuels).

Edit : Juste une précision, il n'y a que des heures pleines ou demies-heures à prendre en compte.

Merci pour votre aide,

Guy.

 

[Victor21]

Re : Calcul d'horaires avec répartition multiple de %

Re,

Merci pour ces infos. Devant m'absenter, je vous suggère de relancer le fil dimanche prochain si, entre temps, vous n'avez pas de proposition.

 

[Guyzinho]

Re : Calcul d'horaires avec répartition multiple de %

Re Victor,

C'est moi qui vous remercie pour l'aide que vous souhaitez m'apporter

C'est entendu, si, d'ici là, je n'ai pas pu avancer et que je n'ai pas reçu d'autres propositions, je relancerais le sujet.

Au plaisir,

Guy.

 

[piga25]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour Guyzinho, Victor21

Peut-être un début de piste comme cela en E2 :

=SI(OU(B2=férié;JOURSEM(B2;2)>5);"";SI(C2>=N$2;"";MOD(MIN(N$2;MAX(D2;N$2))-MAX(M$2;MAX(C2;M$2));1)))

 

[piga25]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour à tous,

Sur une base de formules créées par Roger 2327.

Pour les heures normales en E2 :

=SI(ET(C2="";D2="");"";SI(B2="";MAX(MIN($D2+($D2<$C2);17/24)-MAX($C2;7/24);0)+MAX(MIN($D2+($D2<$C2);17/24)-MAX($C2;31/24);0);""))

Pour les heures 50% en F2 :

=SI(ET(B2="";C2="";D2="");"";SI(B2="";MAX((MIN($D2+($D2<$C2);1)-MAX($C2;17/24));0)+MAX(MIN($D2+($D2<$C2);7/24)-MAX($C2;0);0)+MAX((MIN($D2+($D2<$C2);31/24)-MAX($C2;1));0)+MAX((MIN($D2+($D2<$C2);2)-MAX($C2;41/24));0);SI(B2="S";MAX(MIN($D2+($D2<$C2);16/24)-MAX($C2;7/24);0)+MAX(MIN($D2+($D2<$C2);16/24)-MAX($C2;31/24);0);"")))

Pour les heures 100% en G2 :

=SI(B2="S";MAX((MIN($D2+($D2<$C2);1)-MAX($C2;16/24));0)+MAX(MIN($D2+($D2<$C2);7/24)-MAX($C2;0);0)+MAX((MIN($D2+($D2<$C2);31/24)-MAX($C2;1));0)+MAX((MIN($D2+($D2<$C2);2)-MAX($C2;40/24));0);SI(OU(B2="D";B2="F");MAX(MIN($D2+($D2<$C2);16/24)-MAX($C2;7/24);0)+MAX(MIN($D2+($D2<$C2);16/24)-MAX($C2;31/24);0);""))

Pour les heures 150% en H2 :

=SI(OU(B2="D";B2="F");MAX((MIN($D2+($D2<$C2);1)-MAX($C2;16/24));0)+MAX(MIN($D2+($D2<$C2);7/24)-MAX($C2;0);0)+MAX((MIN($D2+($D2<$C2);31/24)-MAX($C2;1));0)+MAX((MIN($D2+($D2<$C2);2)-MAX($C2;40/24));0);"")

Pour les heures Av.nocturne en I2 :

=SI(C2="";"";MAX((MIN($D2+($D2<$C2);1)-MAX($C2;11/12));0)+MAX(MIN($D2+($D2<$C2);7/24)-MAX($C2;0);0)+MAX((MIN($D2+($D2<$C2);31/24)-MAX($C2;1));0)+MAX((MIN($D2+($D2<$C2);2)-MAX($C2;23/12));0))

 

[Guyzinho]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour Piga,

Tout d'abord, merci pour ton aide.

Je viens de voir, ce jour, tes messages mais je n'aurais pas la possibilité de les tester de suite.

Dès que cela est possible, je teste ça et vous tiens informés via ce fil.

Passez un bon dimanche

Guy.

 

[Guyzinho]

Re : Calcul d'horaires avec répartition multiple de %

Bonjour à tous,

Un tout grand merci à vous, Victor, Piga et également Roger pour la base des formules.

Cela répond tout à fait à mes besoins.

C'est fantastique, vous m'ôtez une épine du pied !

Encore merci !

Guy.