Reporter une donnée correspondant à une date saisie

[fisoccer]

Bonjour,

J'ai un petit problème pour trouver une formule :
Je voudrais à chaque fois qu'une date est saisie en feuille 1 que la valeur "dpt" correspondant soit automatiquement inscrite en feuille 2 sur un calendrier. Voila ma formule en feuille 2 : {=INDEX(Feuil1!$A$2:$A$8;EQUIV($B4;Feuil1!$B$2:$B$8;0))}
Cela marche sauf si je veux étendre B2:B8 à B2:E8 (je voudrais le faire sur les 4 colonnes)
De plus pour les cellules où il n’a pas de date des #N/A apparaissent et j'aimerais ne pas les afficher.

Merci pour vos réponses,

Fi

 

[Staple1600]

Re : Reporter une donnée correspondant à une date saisie

Bonsoir


Pour les NA
voir ici


et également ici
La gestion des erreurs dans Excel - Club d'entraide des développeurs francophones

A titre d'exemple une formule qui gere le probleme
=SI(ESTNA(EQUIV(A1;2));"erreur";EQUIV(A1;2))

PS:EQUIV() est la pour l'exemple

 

[Monique]

Re : Reporter une donnée correspondant à une date saisie

Bonjour,

Dates en colonne C seulement :
=SI(NB.SI(a!$C$2:$C$8;$B2);INDEX(a!$A$2:$A$8;EQUIV($B2;a!$C$2:$C$8;0));"")
à valider par "Entrée" seulement

Dates sur 4 colonnes et s'il n'y a pas plusieurs fois la même date
=SI(NB.SI(a!$C$2:$F$8;$B2)=0;"";INDEX(a!$A$1:$A$8;SOMMEPROD((a!$C$2:$F$8=$B2)*(LIGNE(a!$A$2:$A$8)))))
à valider par "Entrée" seulement

S'il y a plus d'une fois la même date
=SI(NB.SI(a!$C$2:$F$8;$B2)=0;"";INDEX(a!$A$1:$A$8;MIN(SI(a!$C$2:$F$8=$B2;LIGNE(a!$A$2:$A$8)))))
Formule matricielle, à valider par ctrl, maj et entrée

 

[fisoccer]

Re : Reporter une donnée correspondant à une date saisie

Merci beaucoup pour ces réponses !

Fi