recherchev avec renvoi de plusieurs valeurs

[maxis6582]

[RESOLU] recherchev avec renvoi de plusieurs valeurs

Bonjour à tous et merci d'avance pour votre aide, je suis exposé à un petit problème, j'ai dans un onglet une base de donnée de produits et je souhaite attribuer chaque produits à une catégorie. j'ai dans un autre onglet une liste de catégories (colonne B) avec un identifiant (colonne A) pour chaque catégories.

Dans un soucis de rapidité, je souhaite rentrer dans une colonne de la base de donnée l'identifiant de la catégorie et que le nom de la catégorie apparaisse dans une autre colonne.

J'ai donc créer dans la base de donnée deux colonnes (D et E pour mieux comprendre) et j'ai mis dans E une formule recherche v ("=RECHERCHEV(D160;catég!A:B;2;FAUX")

jusque la tout fonctionne mais le problème c'est qu'un produit peut se trouver dans une ou plusieurs catégories, il faudrait donc que je trouve un moyen rapide en rentrant les identifiants dans "D" d'avoir dans "E" le nom des catégories séparés par une virgule.

Le mieux dans mon cas serait de rentrer les identifiants comme par exemple :

-"555"
ou
-"555+666"
ou
-"555+666+777"

ect...

Merci d'avance pour votre aide je ne sais vraiment pas comment faire.

 

[CISCO]

Re : recherchev avec renvoi de plusieurs valeurs

Bonsoir

Essayes de poster un petit fichier résumant ton problème, sans données confidentielles, si possible en utilisant la même configuration que ton fichier original. Ainsi, nous comprendrons mieux ton problème et te proposerons des formules adaptées à la situation.

@ plus

@ plus

 

[maxis6582]

Re : recherchev avec renvoi de plusieurs valeurs

voila un exemple

 

[CISCO]

Re : recherchev avec renvoi de plusieurs valeurs

Bonsoir

Cf une proposition en pièce jointe, valable si les identifiants sont tous composés de 5 chiffres, ni moins, ni plus.

@ plus

 

[maxis6582]

Re : recherchev avec renvoi de plusieurs valeurs

merci beaucoup c'est vraiment parfait!!! la formule à l'air compliquée je n'aurai jamais pu trouver cela tout seul.... merci beaucoup par contre je n'arrive pas vraiment à la comprendre, j'ai essayer de la modifiée pour faire en sorte de mettre plus de 3 catégories ( 4 ou 5) mais je n'arrive pas... je suis vraiment mauvais...

la formule qui fonctionne est :

=INDEX(catég!B$2:B$29;EQUIV(STXT(D16;1;5)*1;catég!A$2:A$29;0))&SI(NBCAR(D16)>5;", "&INDEX(catég!B$2:B$29;EQUIV(STXT(D16;7;5)*1;catég!A$2:A$29;0))&SI(NBCAR(D16)>11;", "&INDEX(catég!B$2:B$29;EQUIV(STXT(D16;13;5)*1;catég!A$2:A$29;0));""))

et moi j'ai modifier :

=INDEX(catég!B$2:B$29;EQUIV(STXT(D17;1;5)*1;catég!A$2:A$29;0))&SI(NBCAR(D17)>5;", "&INDEX(catég!B$2:B$29;EQUIV(STXT(D17;7;5)*1;catég!A$2:A$29;0))&SI(NBCAR(D17)>11;", "&INDEX(catég!B$2:B$29;EQUIV(STXT(D17;13;5)*1;catég!A$2:A$29;0))&SI(NBCAR(D17)>16;", "&INDEX(catég!B$2:B$29;EQUIV(STXT(D17;13;5)*1;catég!A$2:A$29;0));"")))

Pourrait-on me dire ou est l'erreur SVP?
merci d'avance

 

[CISCO]

Re : recherchev avec renvoi de plusieurs valeurs

Bonsoir

Attention, il ne s'agit pas d'une série de SI imbriqués, mais d'une suite de SI, du style ....&SI......&SI.....&SI.....

Cela devrait fonctionner avec ;
=INDEX(catég!B$2:B$29;EQUIV(STXT(D18;1;5)*1;catég!A$2:A$29;0))
&SI(NBCAR(D18)>5;","&INDEX(catég!B$2:B$29;EQUIV(STXT(D18;7;5)*1;catég!A$2:A$29;0));"")
&SI(NBCAR(D18)>11;","&INDEX(catég!B$2:B$29;EQUIV(STXT(D18;13;5)*1;catég!A$2:A$29;0));"")
&SI(NBCAR(D18)>17;","&INDEX(catég!B$2:B$29;EQUIV(STXT(D18;19;5)*1;catég!A$2:A$29;0));"")
&SI(NBCAR(D18)>23;","&INDEX(catég!B$2:B$29;EQUIV(STXT(D18;25;5)*1;catég!A$2:A$29;0));"")

A toi de tester.

@ plus

 

[maxis6582]

Re : recherchev avec renvoi de plusieurs valeurs

merci beaucoup j'ai compris le fonctionnement, cela va vraiment m'aider.