Rechercher et se positionner sur cellule identique avec plusieurs feuilles

[REDGS]

Bonjour le forum,
Après avoir renseigné la cellule M3, je voudrais que le curseur se positionne sur la cellule identique quelque soit la feuille du classeur (colonne C sur 3 feuilles ). Je précise qu’il n’y a pas de doublon. Merci pour votre aide.
Redgs

 

[job75]

Re : Rechercher et se positionner sur cellule identique avec plusieurs feuilles

Bonsoir REDGS,

A placer dans le code de la feuille contenant cette cellule M3 :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [M3]) Is Nothing Then Exit Sub
Dim w As Worksheet, cible As Range
For Each w In Worksheets
  Set cible = w.[C:C].Find([M3], , xlValues, xlWhole)
  If Not cible Is Nothing Then Application.Goto cible: Exit For
Next
End Sub

A+

 

[DoubleZero]

Re : Rechercher et se positionner sur cellule identique avec plusieurs feuilles

Bonjour, REDGS, le Forum,

Une solution, peut-être, dans cette discussion.

A bientôt

P. S. : Bonjour, job75

 

[job75]

Re : Rechercher et se positionner sur cellule identique avec plusieurs feuilles

Bonjour REDGS, bonjour chère ânesse

Quelque chose de plus élaboré avec coloration de la cellule nommée Cible et mémorisation :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [M3]) Is Nothing Then Exit Sub
Dim w As Worksheet, c As Range
If TypeName([Cible]) = "Range" Then
  [Cible].Interior.Color = [couleur]
  ThisWorkbook.Names("Cible").Delete
  ThisWorkbook.Names("couleur").Delete
End If
For Each w In Worksheets
  Set c = w.[C:C].Find([M3], , xlValues, xlWhole)
  If Not c Is Nothing Then
    ThisWorkbook.Names.Add "Cible", c, Visible:=False  'nom masqué
    ThisWorkbook.Names.Add "couleur", c.Interior.Color, Visible:=False
    c.Interior.ColorIndex = 3 'rouge
    Application.Goto c
    Exit Sub
  End If
Next
MsgBox "Pas de correspondance..."
End Sub

A+

 

[REDGS]

Re : Rechercher et se positionner sur cellule identique avec plusieurs feuilles

Bonjour Job75 et doubleZero,

Merci pour vos réponses. Le code de Job75 me convient très bien. Merci encore à vous deux et peut être à une autre fois pour un autre problème. Cordialement Redgs