Quel est le Mieux disant !

[rusty3]

Bonjour,

J'ai besoin d'aide pour créer une formule reprenant quelques conditions :

Voilà je suis dans le transport et j'ai besoin de connaitre lorsque j'ai une expédition vers un département d'un poids X le transporteur le mieux placé.

Par exemple : j'ai pour le département 45 une expédition de 4312 kg : je souhaite pouvoir mentionner ce numéro de département dans une case, puis le poids, et Excel va chercher dans ma base de donnée composée d'une dizaine de transporteurs le tarif le moins cher => il l'indique dans une case à coté de celle du poids enregistré, calcule le prix final.

Je poste à ce message un exemple pour mieux illustrer mes besoins.

Si quelqu'un à une idée je suis preneur.

Merci

Rusty

 

[kjin]

Re : Quel est le Mieux disant !

Bonsoir,
Sommes nous chargés de créer la base de données ?
A+
kjin

 

[Hulk]

Re : Quel est le Mieux disant !

Hello,

Elle y est ami Kjin ... K15

 

[ROGER2327]

Re : Quel est le Mieux disant !

Bonjour à tous

Essayez

[COLOR="DarkSlateGray"][B]=MIN(DECALER(K18;EQUIV(B13;J18:J67;0)+INDEX(DECALER(K18;EQUIV(B13;J18:J67;0)-1;0;25;1);EQUIV(ENT(C13/1000);DECALER(K18;EQUIV(B13;J18:J67;0)-1;0;25;1)))-2;1;1;3))[/B][/COLOR]

en E13 et

[COLOR="DarkSlateGray"][B]=INDEX(L17:N17;1;EQUIV(E13;DECALER(K18;EQUIV(B13;J18:J67;0)+INDEX(DECALER(K18;EQUIV(B13;J18:J67;0)-1;0;25;1);EQUIV(ENT(C13/1000);DECALER(K18;EQUIV(B13;J18:J67;0)-1;0;25;1)))-2;1;1;3);0))[/B][/COLOR]

en D13.​

ROGER2327
#3051

 

[BOISGONTIER]

Re : Quel est le Mieux disant !

Bonjour,

Voir PJ

Noms de champ
dept =Feuil1!$J$18:$J$67
prix =Feuil1!$L$18:$N$42
tonnage =Feuil1!$K$18:$K$42
transport =Feuil1!$L$17:$N$17

E13:
=MIN(INDEX(DECALER(prix;EQUIV(B13;dept;0)-1;);EQUIV(C13/1000;tonnage);))

[B]D13:[/B]
=INDEX(transport;EQUIV(E13;INDEX(DECALER(prix;EQUIV(B13;dept;0)-1;);EQUIV(C13/1000;tonnage););0))

JB

 

[rusty3]

Re : Quel est le Mieux disant !

Merci pour vos réponses, cela m'a bien aidé c'est génial !

J'ai retenu plutôt les formules de BOISGONTIER plus facile pour moi à manier...

Néanmoins j'ai un petit bug : lorsque j'indique 25 000 cela ne prend pas en compte le département et la bonne tranche de poids, là je n'arrive pas à comprendre pourquoi.

BOISGONTIER peux tu encore m'aider ? Voici en PJ mon fichier modifié.

A plus

 

[ROGER2327]

Re : Quel est le Mieux disant !

Re...

Si vous aimez les plages nommées, voici une proposition sur la base de mes formules trop compliquées d'hier.

En H9 :

[COLOR="DarkSlateGray"][B]=MIN(TARDEPT)[/B][/COLOR]

(matricielle).

En G9 :

[COLOR="DarkSlateGray"][B]=INDEX(TAR;1;EQUIV(TMD;TARDEPT;0))[/B][/COLOR]

(matricielle).

Plages nommées :
DEST

[COLOR="DarkSlateGray"][B]=Feuil1!$E$9[/B][/COLOR]

TON

[COLOR="DarkSlateGray"][B]=Feuil1!$F$9[/B][/COLOR]

TMD

[COLOR="DarkSlateGray"][B]=Feuil1!$H$9[/B][/COLOR]

DEPT

[COLOR="DarkSlateGray"][B]=Feuil1!$A$15:$A$814[/B][/COLOR]

TAR

[COLOR="DarkSlateGray"][B]=Feuil1!$C$14:$M$14[/B][/COLOR]

TONDEPT

[COLOR="DarkSlateGray"][B]=DECALER(Feuil1!$B$15;EQUIV(DEST;DEPT;0)-1;0;25;1)[/B][/COLOR]

TARDEPT

[COLOR="DarkSlateGray"][B]=DECALER(Feuil1!$B$15;EQUIV(DEST;DEPT;0)+INDEX(TONDEPT;EQUIV(MAX(1;ENT(TON/1000));TONDEPT))-2;1;1;COLONNES(TAR))[/B][/COLOR]

ROGER2327
#3056

 

[rusty3]

Re : Quel est le Mieux disant !

Bonjour

Excellent ROGER2327 merci beaucoup, ça fonctionne d'enfer !!!

Je vais pouvoir mettre tout ça en application.

Encore merci !!

Rusty

 

[BOISGONTIER]

Re : Quel est le Mieux disant !

Bonjour,

>Néanmoins j'ai un petit bug :
Ce sont les noms de champ qui ne sont pas bons.

Noms de champ
dept =$A$15:$A$814
prix =$C$15:$M$39
tonnage =$B$15:$B$39
transport =$C$14:$M$14

=MIN(INDEX(DECALER(prix;EQUIV(E9;dept;0)-1;);EQUIV(F9/1000;tonnage);))
=INDEX(transport;EQUIV(H9;INDEX(DECALER(prix;EQUIV(E9;dept;0)-1;);EQUIV(F9/1000;tonnage););0))

http://boisgontierjacques.free.fr/pages_site/fonctionindex.htm#MoinsCher

JB

 

[JCGL]

Re : Quel est le Mieux disant !

Bonjour à tous,

Rusty : tu as des tarifs, pour le Transporteur 01, qui sont du texte en non du numérique (le résultats des formules proposées est faussé)

A+ à tous