pair impair, cellule vide traité?

[yoyo71]

bonjour à tous,

je vous explique mon problème qui va certainement vous paraitre anodin.
dans le fichier excel en pièce jointe apparait :

-en colonne (A) des chiffres de référence
-en colonne (C) une formule qui calcul si le chiffre en colonne A est pair ou impair
voici la formule utilisée =SI(A2/2*2-TRONQUE(A2/2)*2=0; "1"; "0")
donc si le chiffre est pair il me marque "1" et "0" s'il est impair.

Mon problème apparait lorsque je prolonge ma formule en colonne C. si la case est vide en colonne A, il me marque quand même "1" donc pair (apriori il considère la case vide comme étant égal à 0 donc pair). j'aimerai que la formule prenne en compte la cellule vide comme n’étant pas à traiter, soit "si la case en colonne A est vide ne rien faire en colonne C.

merci pour votre aide

 

[Dull]

Re : pair impair, cellule vide traité?

Salut yoyo71, le Forum

En mettant une gestion des vides dans ta Formule

=SI(A2="";"";SI(A2/2*2-TRONQUE(A2/2)*2=0; "1"; "0"))

à copier vers le Bas

Bonne Journée

 

[yoyo71]

Re : pair impair, cellule vide traité?

Merci Dull pour ta réponse rapide, claire et précise

 

[Dull]

Re : pair impair, cellule vide traité?

Re le Fil

Pas de Quoi

Sinon ta formule peut-être raccourci comme cela

=SI(A2="";"";ABS(MOD(A2;2)-1))

Toujours à incrémenter vers le bas

EDITION: Salut Mon JC plaisir partagé

Bonne Journée

 

[JCGL]

Re : pair impair, cellule vide traité?

Bonjour à tous,
Salut mon Didier,

Pour le plaisir de croiser l'ami Dull :

=SI(A2="";"";EST.PAIR(A2)*1)

A+++
A + à tous

 

[yoyo71]

Re : pair impair, cellule vide traité?

je viens de tester ta proposition de formule simplifiée qui fonctionne très bien

je continu la construction de mon fichier et suis de nouveau bloqué
je souhaite a partir de ma colonne C ( 0 ou 1 pour pair/impair) pouvoir calculer les écarts entre les chiffres pair
.
j'ai donc utilisé cette formule en colonne E:
=FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30)))

mon problème est similaire, la formule matricielle étirée vers le bas puis validé par "ctrl+shift+enter", continue à calculer plusieurs 0 qui ne devraient pas apparaitre. Je ne comprend pas d'où viens l'erreur.
j'ai mis les écarts et chiffres pair/impair en couleur afin que cela soit plus parlant.

merci encore pour vos coups de pouce

 

[Dull]

Re : pair impair, cellule vide traité?

Re le Fil

pas sur de moi car les Matricielles ne sont pas mon fort, loin de la, mais essaye
la formule matricielle étirée vers le bas puis validée par "ctrl+shift+enter" comme tu le dit

=SI(FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30)))=0;"";FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30))))

les Zéros ne seront plus visibles et les #N/A le seront

A tester

Bonne Journée

 

[yoyo71]

Re : pair impair, cellule vide traité?

Merci Dull pour ta réponse

malgrès tout j'ai un problème qui persiste avec ta formule proposée:

=SI(FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30)))=0;"";FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30))))

en effet, elle me supprime tout les Zéro en colonne E, alors que les deux derniers 0 que j'ai coloré (parme et vert) correspondent aux deux derniers écarts en case C10 C11 (écart zéro).
Cela risque donc de fausser mes données.

si quelqu'un à la réponse à ce problème il est le bienvenue sur ce sujet
j'ai crée un exemple du résultat attendu en colonne G

merci

 

[yoyo71]

Re : pair impair, cellule vide traité?

bonjour.

Personne pour m'aider entre 2 pause café?

 

[JHA]

Re : pair impair, cellule vide traité?

Bonjour à tous,

pas très élégant mais avec une colonne sup.

Edit: modif de la formule en "F2" puis tirer vers le bas

=SI((LIGNES($E$2:E2))>ARRONDI.SUP(NBVAL($A$2:$A$30)/2;0);"#N/A";E2)

Modif en E2

=FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI(C2:C30>0;LIGNE(2:30)))

Formule matricielle

JHA

 

[R@chid]

Re : pair impair, cellule vide traité?

Bonjour @ tous,
sélectionner la plage E2:E30, coller cette formule,

=FREQUENCE(SI(C2:C30=0;LIGNE(2:30));SI((C2:C30=1)*(C3:C31<>"");LIGNE(2:30)))

Formule Matricielle @ valider par Ctrl+Maj+Entree
Amicalement

 

[yoyo71]

Re : pair impair, cellule vide traité?

Merci bcp pour vos réponses et pour m'avoir aidé dans la création de mon doc

au plaisir