Microsoft 365 Mois, date, heure et minute

[GUERET]

Bonsoir,
Dans ce fichier, j'ai, par trois formules, obtenu le compte à rebours en mois, jours et heures.
Est-il possible de fusionner tout cela en une seule et unique formule en y ajoutant les minutes au quotidien ?
D'avance, merci

https://we.tl/t-MfIgvBtbG0

 

[patricktoulon]

bonsoir en voilà une idée
qui a été évoqué plusieurs fois dans le forum
histoire de changer voici une methode
en A1 une date(celle que tu veux et plus vielle qu'aujourd'hui meme heure)
et dans la cellule resultat
ceci

=SUBSTITUE(SI( MOIS(MAINTENANT())=MOIS(A2);SUBSTITUE(SUBSTITUE(TEXTE(MAINTENANT()-(A2);"aaaa"" an(s) ""mm "" mois "" jj"" jour(s) "" hh ""heure(s) ""mm"" minute(s) ""ss""sec""");ANNEE(MAINTENANT()-A2);ANNEE(MAINTENANT()-A2)-1900;1);"01 mois";" ");SUBSTITUE(TEXTE(MAINTENANT()-A2-31;"aaaa"" an(s) ""mm "" mois "" jj"" jour(s) "" hh ""heure(s) ""mm"" minute(s) ""ss""sec""");ANNEE(MAINTENANT()-A2);ANNEE(MAINTENANT()-A2)-1900;1));"0 an(s)";"")

 

[Jean-Eric]

Bonjour,
Une autre proposition !?
Cdlt.

=LET(
début;MAINTENANT();
fin;B6+C6;
m;DATEDIF(début;fin;"ym") & " mois, ";
j;DATEDIF(début;fin;"md");
d;MOD(fin-début;1);
h;ENT(d*24);
mn;ENT(MOD(d*24;1)*60);
m&SI(j>1;j&" jours, ";j&" jour, ")&SI(h>1;h&" heures et ";h&" heure et ")&SI(mn>1;mn&" minutes";mn&" minute"))

 

[GUERET]

Merci pour ta réponse Jean-Éric. Ça fonctionne .

 

[GUERET]

Bonjour,
Une autre proposition !?
Cdlt.

=LET(
début;MAINTENANT();
fin;B6+C6;
m;DATEDIF(début;fin;"ym") & " mois, ";
j;DATEDIF(début;fin;"md");
d;MOD(fin-début;1);
h;ENT(d*24);
mn;ENT(MOD(d*24;1)*60);
m&SI(j>1;j&" jours, ";j&" jour, ")&SI(h>1;h&" heures et ";h&" heure et ")&SI(mn>1;mn&" minutes";mn&" minute"))

Bonjour Jean-Éric, je me suis servi de ta formule qui fonctionne mais quand j'ai voulu ajouter les secondes , j'obtiens 4 chiffres avec ma formule modifiée :

=LET(début;MAINTENANT();fin;B6+C6;m;DATEDIF(début;fin;"ym")&" mois ";j;DATEDIF(début;fin; "md");d;MOD(fin-début;1);h; ENT(d*24);mn;ENT(MOD(d*24;1)*60);ss;ENT(MOD(d*24;1)*3600);m&SI(j>1;j&" jours ";j&" jour, ")&SI(h>1;h&" heures ";h&" heure ")&SI(mn>1;mn&" minutes ";mn& " minute et ")&SI(ss>1;ss&" secondes ";ss&" seconde "))

Où se situe ma boulette stp ? Je la communiquerai aussi à un ami qui bosse avec moi sur le sujet

 

[Deadpool_CC]

Bonjour...
simple remarque à @GUERET : d'habitude on coche comme solution le post du XlDnaute qui a apporté la solution. par son propre post de réponse.
l'objectif étant que les autres puissent voir et accéder directement au bon post de solution
Si tu peux corriger STP. Merci et à bientot sur notre forum

 

[GUERET]

OK mais pourrais-tu me donner la soluce à stp ?

 

[Deadpool_CC]

ps : ma version d'excel ne contient pas LET() ... je peux pas tester et te proposer une solution ... désolé

 

[GUERET]

Ben c'est pour ça que j'ai tenté de joindre Jean-Éric, l'auteur de cette formule avec laquelle je me bats moi aussi

 

[Deadpool_CC]

Je ne peux pas tester ou vérifier ... mais en ajoutant un formatage avec la fonction TEXTE() ?

=LET(
début;MAINTENANT();
fin;B6+C6;
m;DATEDIF(début;fin;"ym")&" mois ";
j;DATEDIF(début;fin; "md");
d;MOD(fin-début;1);
h; ENT(d*24);
mn;ENT(MOD(d*24;1)*60);
ss;ENT(MOD(d*24;1)*3600);
m & SI(j>1;j&" jours ";j&" jour, ")
  & SI(h>1;h&" heures ";h&" heure ")
  & SI(mn>1;mn&" minutes ";mn& " minute et ")
  & SI(ss>1;TEXTE(ss;"00")&" secondes ";TEXTE(ss;"00")&" seconde "))

 

[GUERET]

Je viens juste de tester mais cela bloque la fonction compte à rebours.

 

[GUERET]

Je viens juste de tester mais cela bloque la fonction compte à rebours.

ss;ENT(MOD(d*24;1)*3600);
Je crois que le problème se situe à ce niveau, dans la division du temps

 

[TooFatBoy]

Bonjour,

Peut-être

ss;ENT(MOD(d*24*60;1)*60)

 

[Deadpool_CC]

Après décomposition de chaque étape dans Excel avec cette formule, je trouve le bon nombre de seconde ...
y peut-être plus simple

ss ; ARRONDI((MOD(MOD(d*24;1)*60;1)*60);0)

 

[TooFatBoy]

Tu peux tester ma proposition de la même façon, stp, juste histoire que je sache si ça marche ou pas ?