XL 2016 macros et MFC lentes

[halecs93]

Bonjour,

J'ai "bricolé" quelques formules sur ma feuille excel.

Il s'agit de colorer des cellules en fonction de leur contenu et/ou d'automatiser un contenu en fonction de leur couleur.

J'ai l'impression que les temps de calcul sont extrêmement longs.

Peut-être une autre approche ?

Un grand merci

 

[TooFatBoy]

Bonjour,

Il n'y a qu'une seule MFC dans ta feuille. C'est bien ça ?

La formule de cette MFC est actuellement :

=(JOURSEM(DECALER(A5;;-(MOD(COLONNE()-1;32)));2)>5)*(DECALER(A5;;-(MOD(COLONNE()-1;32)))<>"")

Elle est censée faire quoi ? Juste colorier les samedis et dimanches ?

Si c'est ça, alors cette formule devrait également convenir :

=JOURSEM($A5;2)>5

 

[TooFatBoy]

D'autre part, dans tes macros, tu as :

Set plage = Me.Range("C4:Y34")

Est-ce que ça ne devrait pas être C5:Y35 ?

 

[halecs93]

Bonjour,

Il n'y a qu'une seule MFC dans ta feuille. C'est bien ça ?

La formule de cette MFC est actuellement :

=(JOURSEM(DECALER(A5;;-(MOD(COLONNE()-1;32)));2)>5)*(DECALER(A5;;-(MOD(COLONNE()-1;32)))<>"")

Elle est censée faire quoi ? Juste colorier les samedis et dimanches ?

Si c'est ça, alors cette formule devrait également convenir :

=JOURSEM($A5;2)>5

Oui...totalement... malgré tout, lorsque j'applique une couleur sur une ou plusieurs cellules, le calcul me semble encore long pour voir s'y inscrire MB ou autre...

 

[halecs93]

D'autre part, dans tes macros, tu as :

Set plage = Me.Range("C4:Y34")

Est-ce que ça ne devrait pas être C5:Y35 ?

Oui...en effet...juste que j'ai décalé des lignes après avoir mis en place la macro... mais merci pour le détail important

 

[TooFatBoy]

A chaque fois qu'on change la "sélection", tu réécrits le contenu de toutes les cellules dont le fond est colorié ?!?
Ce qui en plus appelle, à chaque écriture, la macro Worksheet_Change !

 

[halecs93]

A chaque fois qu'on change la "sélection", tu réécrits le contenu de toutes les cellules dont le fond est colorié ?!?

...je n'ai pas trouvé comment faire autrement...encore une fois "j'ai bricolé"

 

[sylvanu]

Bonsoir Halecs, TooFatBoy,
Pourquoi ne pas analyser que la cellule concernée ?
En remplaçant "plage" dans les 2 macros par :

Set plage = Me.Range(Target.Address)

Ne serait ce pas suffisant ?

 

[TooFatBoy]

...je n'ai pas trouvé comment faire autrement...encore une fois "j'ai bricolé"

Ah... bienvenue au club des "bricoleurs".
Moi je fais par tâtonnements, mais ça revient à peu près au même...


Que veux-tu faire exactement ?

 

[halecs93]

Bonsoir Halecs, TooFatBoy,
Pourquoi ne pas analyser que la cellule concernée ?
En remplaçant "plage" dans les 2 macros par :

Set plage = Me.Range(Target.Address)

Ne serait ce pas suffisant ?

Oui, mais lorsque je colorie, par exemple, W11:X11 en jaune...rien ne s'inscrit dans les cellules... il faut que je clique à nouveau dessus....

 

[TooFatBoy]

Oui, mais lorsque je colorie, par exemple, W11:X11 en jaune...rien ne s'inscrit dans les cellules... il faut que je clique à nouveau dessus....

Donc tu veux colorier et qu'en fonction de la couleur ça écrive le texte ?

 

[halecs93]

Donc tu veux colorier et qu'en fonction de la couleur ça écrive le texte ?

J'avoue ne pas être sûr de la clarté de mes propos

 

[TooFatBoy]

Pour moi, si tu veux faire une boucle (pas sûr que ce soit bien utile) For Each cell In Plage, il faut d'abord faire un Set plage = Intersect(Target, Me.Range("C5:Y35")).

Mais si je pige bien :
- soit tu colores en jaune et ça écrit "MB",
- soit tu mets "MB" et ça colore en jaune.

 

[halecs93]

Pour moi, si tu veux faire une boucle (pas sûr que ce soit bien utile) For Each cell In Plage, il faut d'abord faire un Set plage = Intersect(Target, Me.Range("C5:Y35")).

Mais si je pige bien :
- soit tu colores en jaune et ça écrit "MB",
- soit tu mets "MB" et ça colore en jaune.

tout à fait...et si je supprime le contenu d'une cellule, ça efface la couleur

 

[TooFatBoy]

Peut-être ça :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'
Dim plage As Range, cell As Range

    ' Définir la plage de cellules à surveiller sur la feuille active
    Set plage = Intersect(Target, Me.Range("C5:Y35"))

    ' Vérifier si la plage de cellules sélectionnée est dans la plage spécifiée
    If plage Is Nothing Then Exit Sub

    Application.EnableEvents = False

    ' Parcourir chaque cellule de la plage
    For Each cell In plage
        Select Case cell.Interior.Color
        Case RGB(255, 255, 0)   ' Jaune
            cell.Value = "MB"
        Case RGB(146, 208, 80)  ' Vert
            cell.Value = "RG"
        Case RGB(0, 176, 240)   ' Bleu
            cell.Value = "SP"
        Case RGB(247, 150, 70)  ' Orange
            cell.Value = "SC"
        Case RGB(218, 150, 148) ' Chaire
            cell.Value = "MN"
        Case RGB(192, 0, 0)     ' Rouge 1
            cell.Value = "MG"
        Case RGB(150, 54, 52)   ' Rouge 2
            cell.Value = "MP"
        End Select
    Next cell

    Application.EnableEvents = True

End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
'
Dim plage As Range, cell As Range

    ' Définir la plage de cellules à surveiller sur la feuille active
    Set plage = Intersect(Target, Me.Range("C5:Y35"))

    ' Vérifier si les cellules modifiées sont dans la plage spécifiée
    If plage Is Nothing Then Exit Sub

    Application.EnableEvents = False ' Désactiver temporairement les événements pour éviter une boucle infinie

    ' Parcourir chaque cellule modifiée
    For Each cell In plage
        ' Si la cellule est maintenant vide, effacer la couleur de fond
        If cell.Value = "" Then
            cell.Interior.ColorIndex = xlNone
        Else
            ' Mettre à jour la couleur de fond en fonction de la valeur de la cellule
            Select Case cell.Value
            Case "MB"
                cell.Interior.Color = RGB(255, 255, 0) ' Jaune
            Case "RG"
                cell.Interior.Color = RGB(146, 208, 80) ' Vert
            Case "SP"
                cell.Interior.Color = RGB(0, 176, 240) ' Bleu
            Case "SC"
                cell.Interior.Color = RGB(247, 150, 70) ' Orange
            Case "MN"
                cell.Interior.Color = RGB(218, 150, 148) ' Chaire
            Case "MG"
                cell.Interior.Color = RGB(192, 0, 0) ' Rouge
            Case "MP"
                cell.Interior.Color = RGB(150, 54, 52) ' Rouge_2
            Case Else
                ' Réinitialiser la couleur de fond si la valeur n'est pas reconnue
                cell.Interior.ColorIndex = xlNone
            End Select
        End If
    Next cell

    Application.EnableEvents = True ' Réactiver les événements

End Sub