XL 2016 fonction somme.si plusieurs classeurs

[gds77]

Bonjour le Forum,

Quand j'ouvre mon fichier tendance banques qui est lié avec le fichier banque, le résultat des cellules affiche #valeur quand ce dernier est fermé. Il ne fonctionne que si celui ci est ouvert. En parcourant le forum, cela proviendrait de la formule somme.si.ens que l'on pourrait remplacer par sommeprod. Mais ma formule sur les feuilles "Mois" contient plusieurs critères dont un sur des dates et je ne sais pas comment modifier ma formule.

Merci d'avance

 

[Amilo]

Bonjour,
Un essai avec sommeprod() en cellule A3 dans l'onglet "Janvier" du fichier "Banques Tendances"

=SOMMEPROD(('Banques 2018.xlsm'!Tableau226[Date]>=DATE(ANNEE($D$1);MOIS($D$1);JOUR($D$1))*('Banques 2018.xlsm'!Tableau226[Date]<=DATE(ANNEE($D$1);MOIS($D$1)+1;0))*('Banques 2018.xlsm'!Tableau226[Catégorie]=[@Catégorie])*('Banques 2018.xlsm'!Tableau226[Montant]))

Cordialement

 

[job75]

Bonjour,

Juste 2 remarques.

@ gds77, votre fichier est en calcul manuel, il est urgent de le passer en automatique.

@ Amilo, vous n'avez pas testé votre formule, les parenthèses sont mal disposées, utilisez plutôt :

=SOMMEPROD(('Banques 2018.xlsm'!Tableau226[Date]>=D$1)*('Banques 2018.xlsm'!Tableau226[Date]<=FIN.MOIS(D$1;0))*('Banques 2018.xlsm'!Tableau226[Catégorie]=[@Catégorie])*'Banques 2018.xlsm'!Tableau226[Montant])

A+

 

[job75]

Re,

Cela dit SOMMEPROD renvoie aussi des valeurs d'erreur si le fichier source est fermé et qu'on revalide la formule.

A+

 

[job75]

Re,

Pour que la formule fonctionne quand on ferme le fichier source utiliser en jan!A3 :

=SOMMEPROD(('[Banques 2018.xlsm]Banque BP'!B$6:B$1000>=D$1)*('[Banques 2018.xlsm]Banque BP'!B$6:B$1000<=FIN.MOIS(D$1;0))*('[Banques 2018.xlsm]Banque BP'!F$6:F$1000=[@Catégorie])*'[Banques 2018.xlsm]Banque BP'!G$6:G$1000)

la dernière ligne 1000 pouvant être adaptée.

A+

 

[Amilo]

Bonjour job75, le forum,

Merci job75 pour votre retour et vos remarques,
Effectivement ma formule fonctionnait au départ jusqu'à ce que je vienne apporter une modification de dernière minute dans la partie suivante :
J'avais mis le début de formule :

=SOMMEPROD(('Banques 2018.xlsm'!Tableau226[Date]>=DATE(ANNEE($D$1);1;1)*(

que j'ai rapidement modifié à juste titre par celle ci-dessous mais malencontreuseument avec une parenthèse en moins

=SOMMEPROD(('Banques 2018.xlsm'!Tableau226[Date]>=DATE(ANNEE($D$1);MOIS($D$1);JOUR($D$1))*

Avec une parenthèse supplémentaire comme ci-dessous cela fonctionne :

=SOMMEPROD(('Banques 2018.xlsm'!Tableau226[Date]>=DATE(ANNEE($D$1);MOIS($D$1);JOUR($D$1)))*

Sinon, il y a effectivement quelques règlages à corriger dans ce fichier notamment le calcul manuel en automatique comme vous l'avez souligné,
Par ailleurs, certaines colonnes sont au format "Nombre positif" alors que d'autres sont en "standard".
Tout résutat négatif serait alors convertit en nombre positif....

Merci aussi pour votre dernière formule avec une plage manuelle au lieu de la colonne entière du tableau.
Cette formule fonctionne même après la "modification/mise à jour des liaisons",
C'est bon à savoir.

Bonne soirée à tous

 

[gds77]

Bonjour Le forum,

Merci à Amilo et particulièrement JOB75 pour votre aide. En effet, les mises à jour de Windows font souvent basculer le mode automatique en manuel sur mes fichiers . Pour répondre à Amilo, j'ai corrigé mes formats nombres qui étaient présents avant que je ne trouve la formule de valeur absolue pour mon graphique.

Bonne journée à vous tous