extraction de données d'une autre feuille

[bian-k]

bonjour,
j'aurai besoin d'un peu de votre temps, j'espère ne pas en abuser.
voilà, j'ai une base de données excel avec différents champs. j'aimerai remplir le champs population à partir de la colonne "j" de la feuille insee si:
- les deux premiers chiffre du code postal ( colonne A, feuille 1) sont les mêmes que le code département ds la feuille insee
- et si le nom de la ville (colonne b , feuille 1) est identique au nom de la commune dans la feuille insee.

j'ai essayé avec cette formule mais elle ne marche pas:
=etsi(gauche(A2;2)=feuille insee(A9:A2304);si(B2=feuille insee(G9:G2304);"J9""").

j'espère n'avoir pas trop massacré excel et merci d'avance.
ci-joint un fichier

 

[ERIC S]

Re : extraction de données d'une autre feuille

bonjour

pas de fichier joint...

 

[mth]

Re : extraction de données d'une autre feuille

Bonjour,

Ecrite comme ça, ta formule ne doit pas fonctionner, mais pour mieux te répondre, pourrais-tu joindre un petit extrait de fichier ?

@ +

mth

Edit: bonjour Eric

Edit 2: pokou Hub (euh.. c'est comme ça qu'on dit ?)

 

[ERIC S]

Re : extraction de données d'une autre feuille

re bonjour

au hasard, non testé

=sommeprod((gauche(A2;2)=feuille insee($A$9:$A$2304))*(B2=feuille insee($G$9:$G$2304))*($J$9:$J$2304))

un risque : que A2 ne soit pas du texte mais un nombre (ou même chose sur feuille insee)

 

[Cousinhub]

Re : extraction de données d'une autre feuille

Bonsoir petit k (traduction bretonne de bian.....)

Mireille

Bonsoir, Eric

Bian k, je pense qu'un filtre élaboré avec critères répondrait parfaitement à ton souci, mais comme dit par mes prédécesseurs (seuses...), un fichier exempt de toutes données confidentielles serait le bienvenu....

Bonne soirée.....

 

[bian-k]

Re : extraction de données d'une autre feuille

sorry, ci jo440int le fichier, j'ai du par contre réduire les lignes du coup, je n'ai plus 2304 ligne ds la feuille 2 mais environ 1000. merci

 

[Cousinhub]

Re : extraction de données d'une autre feuille

Re,

Bian-k

tu risques d'avoir des soucis, dans ce que tu veux obtenir...

Saint-Astier, dans la feuille "insee"

ST ASTIER, dans la feuille "base 1"

....

ça va pas être simple.....

 

[ERIC S]

Re : extraction de données d'une autre feuille

re à tous

=SOMMEPROD((GAUCHE(A2;2)=insee!$A$9:$A$2304)*(B2=insee!$B$9:$B$2304)*insee!$E$9:$E$2304)

les colonnes de ton exemple portent sur A, B et E de la feuille insee

par contre, tu as un gros soucis, tes noms de ville ne sont pas identiques

ST CYPRIEN <> Saint-Cyprien
....

pour tester j'ai modifié le nom sur l'Insee et là c'est bon
donc pas glop

 

[mth]

Re : extraction de données d'une autre feuille

re

Avec le problème des noms de villes qui comportent des tirets d'un coté et pas de l'autre ....

Une formule sans sommeprod car mon vieux PC était essoufflé sur 10000 lignes, donc une simple fonction Equiv index, puisque les données semblent uniques

à tester de ton coté, en C2 et copiée vers le bas :

=SI(ESTNA(EQUIV(SUBSTITUE(B2;" ";"-");insee!B6:B10000;0));"";INDEX(insee!E6:E10000;EQUIV(SUBSTITUE(B2;" ";"-");insee!B6:B10000;0);1))

@ +

mth

 

[ERIC S]

Re : extraction de données d'une autre feuille

bonjour mth

je n'ai pas testé mais ne risque-t-il pas d'y avoir un pb si plusieurs villes ont le même nom (département différent)?

 

[Cousinhub]

Re : extraction de données d'une autre feuille

Re,

Mireille, que le PC, d'essoufflé?

Si j'ai mis ST ASTIER, c'est parce qu'il existe dans 2 départements.....

24 et 47.....

Aussi, un Equiv ne peut convenir....

désolé

une solution simple ne semble pas exister, il faudrait une formule de l'espace-temps, ou Moniesque...

Bonne soirée

 

[mth]

Re : extraction de données d'une autre feuille

re,

sourire... tu as raison Eric, il n'y a pas à tester, j'ai pensé à gérer la feinte des tirets, mais s'il y a des noms identiques, la formule que j'ai proposée n'est pas adaptée du tout du coup.

Pour bian k..; tu mets ma formule à la poubelle

Pour Eric: peut-être avec l'aide de decaler() en plus, le fichier a l'air trié par département, on peut essayer ?

à plus tard ....

mth

 

[mth]

Re : extraction de données d'une autre feuille

re

Mireille, que le PC, d'essoufflé? :D:D

pffff, Hub, ta galanterie te perdra ...

En revanche coté formule à coucher dehors, tu as raison .... voici ce que j'ai et qui semble fonctionner dans le fichier joint:

SI(ESTNA(EQUIV(SUBSTITUE(B2;" ";"-");DECALER(insee!$A$1;EQUIV(GAUCHE('base 1'!A2;2);insee!$A$1:$A$10000;0)-1;1;NB.SI(insee!$A$9:$A$1000;GAUCHE(A2;2)););0));"";INDEX(insee!$E$1:$E$10000;(EQUIV(GAUCHE('base 1'!A2;2);insee!$A$1:$A$10000;0)-1)+(EQUIV(SUBSTITUE(B2;" ";"-");DECALER(insee!$A$1;EQUIV(GAUCHE('base 1'!A2;2);insee!$A$1:$A$10000;0)-1;1;NB.SI(insee!$A$9:$A$1000;GAUCHE(A2;2)););0));1))

euh ... un peu long je reconnais ....

Bise Hub,

@ + le fil

mth

 

[Monique]

Re : extraction de données d'une autre feuille

Bonjour,

Dans la feuille Insee :
=SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(B9;"-";" ");"é";"e");"è";"e");"Saint";"St");"'";" ");CAR(201);"E");"ô";"o")

Sinon, SommeProd avec 3 plages nommées par formule.
SommeProd ne prend en compte que les plages du département de la colonne A, de la ligne où se trouve la formule.

=SOMMEPROD((GAUCHE(A2;2)=CpInsee)*(B2=CommInsee);PopInsee)

Il ne reste que 9 ou 10 communes sans correspondance.
Une feuille ajoutée avec table de CP-Département
Département 47 enlevé.

Reste à voir si ça marche...

 

[bian-k]

Re : extraction de données d'une autre feuille

merci à tous!
en combinnant vos formules, je parviens à un excellent résultat, j'ai juste à modifier qq cellules. en effet, j'ai utiliser la formule substitue de monique que j'ai combiné à la somme prod de eric. merci encore et bonne soirée!!!!!!!!!!!!!!!!!!!!!!!!