Eclater cellule première lettre de mot est en majuscule

[Coco-31]

Bonjour le forum,

Je me heurte à un problème pour éclater le contenu d’une cellule contenant le nom et prénom. La particularité est que les mots sont liés, seul point commun est que chaque première lettre est en majuscule exemple DupontPierre parfois DupontPierreJean

Lorsque les mots sont séparés par des espaces ou autre pas de problème,
Lorsque le Nom est en majuscule et le prénom minuscule excepté la première lettre ex. DUPONTPierre, pas de problème avec ces deux formules matricielles

=GAUCHE(A1;MIN(SI(CODE(STXT(A1;LIGNE(INDIRECT("$1:$"&NBCAR(A1)));1))>96;LIGNE(INDIRECT("$1:$"&NBCAR(A1)));9^9))-2)

=STXT(A1;MIN(SI(CODE(STXT(A1;LIGNE(INDIRECT("$1:$"&NBCAR(A1)));1))>96;LIGNE(INDIRECT("$1:$"&NBCAR(A1)));9^9))-1;60)

Par contre pour ce genre de saisis DupontPierre parfois DupontPierreJean je n’arrive pas à trouver la bonne formule pour séparer chaque mot, en espérant trouver la solution sur le forum, je remercie d’avance tous ceux qui me viendrons en aide

 

[BOISGONTIER]

Re : Eclater cellule première lettre de mot est en majuscule

Bonjour,

=STXT(A1;1;EQUIV(VRAI;EXACT(STXT(A1;LIGNE($2:$255);1);MAJUSCULE(STXT(A1;LIGNE($2:$255);1)));0))
Valider avec maj+ctrl+entrée


=STXT(A1;EQUIV(VRAI;EXACT(STXT(A1;LIGNE($2:$255);1);MAJUSCULE(STXT(A1;LIGNE($2:$255);1)));0)+1;999)
Valider avec maj+ctrl+entrée


JB

 

[Coco-31]

Re : Eclater cellule première lettre de mot est en majuscule

Bonjour,

Merci pour cette excellente réponse, je tournais autour sans pouvoir la finaliser.
Ah il vaut mieux un qui sait que deux qui cherchent
Merci encore
@+
Coco-31