durée avant échéance

[azaghar27]

Bonjour tout le monde,

Mon problème est le suivant; je voudrais calculer en années mois et jours avant l'échéance par rapport à aujourd'hui.

Pièce jointe.

Merci beaucoup
Azaghar27

 

[hoerwind]

Re : durée avant échéance

Bonjour,

En E9 :

=DATEDIF(AUJOURDHUI();D9;"y")&" année(s) "&DATEDIF(AUJOURDHUI();D9;"ym")&" mois "&DATEDIF(AUJOURDHUI();D9;"md")& "jour(s)"

formule à copier vers le bas.

Le résultat de cette formule peut être amélioré en n'affichant pas les données égales à 0 et en automatisant les singuliers et pluriels des années et jours.

 

[phlaurent55]

Re : durée avant échéance

Bonjour à tous,

Le résultat de cette formule peut être amélioré en n'affichant pas les données égales à 0 et en automatisant les singuliers et pluriels des années et jours.

Voici pour les accords de grammaire et pour la suppression des zéros

=SI(D9>=AUJOURDHUI();SI(DATEDIF(AUJOURDHUI();D9;"y")=0;"";SI(DATEDIF(AUJOURDHUI();D9;"y")>1;DATEDIF(AUJOURDHUI();D9;"y")&" années ";DATEDIF(AUJOURDHUI();D9;"y")&" année "))&SI(DATEDIF(AUJOURDHUI();D9;"ym")>0;DATEDIF(AUJOURDHUI();D9;"ym")&" mois ";"")&SI(DATEDIF(AUJOURDHUI();D9;"md")>0;SI(DATEDIF(AUJOURDHUI();D9;"md")>1;DATEDIF(AUJOURDHUI();D9;"md")&" jours";DATEDIF(AUJOURDHUI();D9;"md")&" jour");"");"La date est dépassée de "&SI(AUJOURDHUI()-D9>1;AUJOURDHUI()-D9&" jours ";AUJOURDHUI()-D9&" jour "))



encore une chance que le mot "mois" est invariable sinon la formule eut été un peu plus longue
il est possible d'allonger la formule en calculant le dépassement en année(s), mois et jour(s)

@ hoerwind, ............................ si tu te sens d'attaque
............... à moins que Roger passe par ici et nous sorte une formule à nous donner des maux de tête pendant des années
Encore un grand BRAVO à Roger

à+
Philippe