Dé-sélectionner

[nadir****]

Bonjour
est-il possible de retirer une cellule (ou plusieurs cellules, ou une ligne ou une colonne) d'une plage déjà sélectionnée?
Il est facile de rajouter des cellules (avec la touche Ctrl) mais je ne sais pas faire le contraire.
Merci.

Nadir

 

[Pierrot93]

Re : Dé-sélectionner

Bonjour,

pareil tu re-click avec la touche CTRL appuyée...

bon après midi
@+

 

[Softmama]

Re : Dé-sélectionner

Bonjour nadir***, Pierrot93

Effectivement CTRL permet de déselectionner une cellule, mais pas une zone (obligé de cliquer les cellules une par une)
Je t'ai donc fait une petite macro pour réparer ça :

Dim MemoSel As Range, NewSel As Range

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If MemoSel Is Nothing Then Set MemoSel = Selection: Exit Sub
If MemoSel.Address = Target.Address Then Exit Sub
Dim cel As Range
If Union(Target, MemoSel).Address = MemoSel.Address Then
    Application.EnableEvents = False
    Set NewSel = Nothing
    For Each cel In MemoSel
        If Intersect(cel, Target) Is Nothing Then
            If NewSel Is Nothing Then
                Set NewSel = cel
            Else
                Set NewSel = Union(NewSel, cel)
            End If
        End If
    Next
     NewSel.Select
    Application.EnableEvents = True
End If
Set MemoSel = Selection
End Sub

fichier exemple :

 

[Pierrot93]

Re : Dé-sélectionner

Re, bonjour Softmama

Effectivement CTRL permet de déselectionner une cellule, mais pas une zone (obligé de cliquer les cellules une par une)

Euh.. même pas en fait, sous 2003 active désactive la cellule mais pas de déselection...

@+

 

[Softmama]

Re : Dé-sélectionner

Re,

Un bug de Union(Plages) et Intersect(Plages) qui renvoient pas tjs les mêmes adresses de cellules fait que le fichier joint était parfois incorrect. Je l'ai corrigé ainsi :

Dim MemoSel As Range, NewSel As Range

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If MemoSel Is Nothing Then Set MemoSel = Selection: Exit Sub
If MemoSel.Address = Target.Address Then Exit Sub
Dim c As Range, cel As Range
For Each c In Target
    If Intersect(c, MemoSel) Is Nothing Then GoTo 1
Next c
  Application.EnableEvents = False
    Set NewSel = Nothing
    For Each cel In MemoSel
        If Intersect(cel, Target) Is Nothing Then
            If NewSel Is Nothing Then
                Set NewSel = cel
            Else
                Set NewSel = Union(NewSel, cel)
            End If
        End If
    Next
     NewSel.Select
  Application.EnableEvents = True
1 Set MemoSel = Selection
End Sub

Le fichier corrigé ici :

 

[nadir****]

Re : Dé-sélectionner

Merci pour votre aide.
La touche Ctrl ne permet effectivement pas de dé-sélectionner une cellule (ou plus d'une). Dommage.
Je comprends la macro. En travaillant avec des union et des intersect de plages on y arrive, mais c'est un peu une galère.
Merci en tout cas pour ton aide Softmama.
A+
Nadir.