Conversion horaire de HHMM à HH:MM

[Calico79]

Chers internautes, bien le bonjour !

Je viens à vous pour demander votre aide

J’ai dans un tableau deux colonnes qui représentent l’heure de début et respectivement l’heure de fin d’une opération. Ces deux valeurs sont dans un format « Militaire » (1420 pour dire 14h20).

Mon fichier doit être capable de calculer le temps entre le début et la fin de l’opération mais pour se faire, le format de ces deux colonnes doit être modifié préalablement. Et c’est là que tout le bât blesse…

J’ai essayé 1-2 formules trouvées sur ce site mais sans succès car l’application tenait compte également des secondes ce dont je n’ai pas besoin dans mon cas.

Est-ce que quelqu’un aurait une idée pour mon problème ?

En vous remerciant d’avance, je souhaite une agréable après-midi.

Salutations,
Calico

 

[Guest]

Re : Conversion horaire de HHMM à HH:MM

Bonjour Calico,

formule en C2:

=TEMPSVAL(GAUCHE(B2;2) & ":" & DROITE(B2;2))-TEMPSVAL(GAUCHE(A2;2) & ":"&DROITE(A2;2))

A tirer vers le bas

A bientôt

 

[Monique]

Re : Conversion horaire de HHMM à HH:MM

Bonjour,

A essayer :
=MOD(TEXTE(B2;"00"":""00")-TEXTE(A2;"00"":""00");1)

(cellule au format heure)

 

[abcd]

Re : Conversion horaire de HHMM à HH:MM

Bonjour,

Autre approche :

=MOD(ENT((B2-A2)/100)/24+MOD(B2-A2;100)/1440;1)
Cette formule renvoie 1:30 en C2, ce qui semble exact puisque 1510-1420 = 90 (minutes).

abcd

 

[jp14]

Re : Conversion horaire de HHMM à HH:MM

Bonjour

Ci joint le fichier avec une fonction personnalisée.

Principe :
Transformation des valeurs en heures, minutes.
Si l'heure de fin est supérieure à l'heure de départ on fait la différence
dans le cas contraire
on calcule le nombre d'heure jusqu'à minuit puis de minuit à l'heure de fin

A tester

JP

 

[Calico79]

Re : Conversion horaire de HHMM à HH:MM

Hasco, Monique, abcd et jp14,

Merci pour vos réponses rapides.

Hasco ta proposition fonctionne parfaitement pour des valeurs à 4 chiffres. Par contre, si on veut calculer :de 820 à 1000 (pour de 8h20 à 10h00) ou si l’heure de début est avant minuit et celle de fin après, la fonction ne donne pas de valeur.

Monique et jp14, vos propositions fonctionnent à merveille, je vous remercie beaucoup !!

Abcd, 1510-1420 = 90 mais pas 90 minutes. Entre 14h20 et 15h10 il y 50 minutes. Je tiens quand même à te remercier pour ta proposition.

C’est un homme heureux qui vous souhaite une agréable après-midi

A bientôt
Calico

 

[Lord Nelson]

Re : Conversion horaire de HHMM à HH:MM

Bonjour à tous,

J'arrive un peu après la bataille, mais voici une solution possible :

=SI(B2>=A2;0;1)+(MOD(B2;100)/24/60+ENT(B2/100)/24)-(MOD(A2;100)/24/60+ENT(A2/100)/24)

A+
Horatio

 

[Calico79]

Re : Conversion horaire de HHMM à HH:MM

Merci Horatio

 

[drefkore]

Autre approche
Si E2 est la case contenant le donnée HHMM
=TEMPS(ARRONDI.INF(E2/100;0);MOD(E2;100);0)

 

[Modeste geedee]

Chers internautes, bien le bonjour !

Je viens à vous pour demander votre aide

J’ai dans un tableau deux colonnes qui représentent l’heure de début et respectivement l’heure de fin d’une opération. Ces deux valeurs sont dans un format « Militaire » (1420 pour dire 14h20).

Mon fichier doit être capable de calculer le temps entre le début et la fin de l’opération mais pour se faire, le format de ces deux colonnes doit être modifié préalablement. Et c’est là que tout le bât blesse…

J’ai essayé 1-2 formules trouvées sur ce site mais sans succès car l’application tenait compte également des secondes ce dont je n’ai pas besoin dans mon cas.

Est-ce que quelqu’un aurait une idée pour mon problème ?

En vous remerciant d’avance, je souhaite une agréable après-midi.

Salutations,
Calico

dans le cas ou les secondes ne sont jamais saisies...
formule :
=1*TEXTE(A2;"00\:00")
format de cellule hh:mm