Bonjour,
Il est vrai qu'avec un petit fichier exemple ce serait plus simple.
En attendant : CHERCHE(texte cherché; texte (; N° départ)) facultatif
=CHERCHE(" - ";A1)
te renvoie un chiffre qui est la position de ce que tu cherche : ici " - " (espace tiret espace) dans le texte de la cellule A1
=GAUCHE(A1;5)
te renvoie le texte situé à gauche de A1 sur une longueur de 5 caractères et donc
=GAUCHE(A1;CHERCHE(" - ";A1)-1) te renvoie la partie gauche jusqu'au caractère situé juste avant espace tiret espace
La fonction STXT(texte, N° départ, nb de caractères) renvoie une partie du texte d'une cellule.
Il faut calculer le caractère de début : CHERCHE(" - ";A1)+3 (espace tiret espace = 3 caractères).
Pour le nb de caractères : on va chercher le "-" qui se trouve après le premier " - " : on va utiliser le N° départ
CHERCHE(" - ";A1;CHERCHE(" - ";A1)+1).
et on va déduire la longueur de ce qui se trouve avant le premier "-" : -CHERCHE(" - ";A1)-3
donc all in one :
=STXT(A1;CHERCHE(" - ";A1)+3;CHERCHE(" - ";A1;CHERCHE(" - ";A1)+1)-CHERCHE(" - ";A1)-3)
Même principe ensuite pour DROITE qui te donne la partie droite : sa longueur est égale au nb de caractères - l'emplacement du second " - " - 2 caractères
Si ton groupe de séparation ne fait pas 3 caractères, mais 2 il faut remplacer les + et - 3 par + et - 2
En général pour les réglages +1 ou -1 j'écris chaque partie dans des cellules différentes que j'utilise dans la formule et quand tout fonctionne je remplace la cellule par la formule qu'elle contient (méthode inculquée par notre regrettée Monique)
Cordialement