colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne)

[Evelynetfrancois]

Bonjour tout le monde

Dans la colonne "A" j ai des groupes de mots, toujours séparés par une ligne vide.
Comment en VBA , colorer le premier mot de chaque groupe
Merci d'avance pour toutes vos propositions
Bonne journée à tous....

evelynetfrancois

 

[Modeste]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

Bonjour Evelynetrancois,

Sans fichier, on ne peut pas affirmer que ça fonctionnera ... j'essaierais quelque chose comme

Sub couleur()
    [A:A].SpecialCells(xlCellTypeBlanks).Offset(1, 0).Interior.ColorIndex = 3
End Sub

... épithète que ça marchera

 

[Dugenou]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

Salut Evelynetfrançois, Modeste,
pitèt pitèt mais à mon avis ça va colorer toute la cellule et pas seulement le premier mot

je suis le sujet car je trouve la question intéressante même si je ne peux être d'aucune aide dans ce cas.

 

[Modeste]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

Hey, salut Dugenou (avec tout mon respect, s'entend!)

pitèt pitèt

oh vous avez un drôle d'accent, à Lille

Ceci dit, t'as p'têt raison, mais j'ai considéré "le premier mot de chaque groupe" comme "la première cellule de chaque groupe" ... si ce n'est qu'un seul mot, ma proposition ne conviendra pas, œuf corse!

 

[job75]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

Bonjour Evelynetfrançois, Modeste, Dugenou,

Une solution plus générale mais nettement plus compliquée :

- elle fonctionne même s'il y a plusieurs cellules vides entre les groupes

- la cellule A1 est colorée si elle est remplie (1er groupe).

Sub PremiereCellule()
Dim ncol%, colaux As Range
Application.ScreenUpdating = False
With ActiveSheet.UsedRange
  .Columns(1).Interior.ColorIndex = xlNone 'RAZ
  If Application.CountA(.Columns(1)) = 0 Then Exit Sub
  .Rows(1).Insert xlDown
  ncol = .Columns.Count
  Set colaux = .Columns(ncol + 1) 'colonne auxiliaire
  colaux = "=1/(RC[-" & ncol & "]<>"""")/(R[-1]C[-" & ncol & "]="""")"
  Intersect(colaux.SpecialCells(xlCellTypeFormulas, 1) _
    .EntireRow, .Columns(1)).Interior.ColorIndex = 3
  colaux.ClearContents
  .Rows(0).Delete xlUp
End With
End Sub

A+

 

[Si...]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

salut

dans la page de code de l'onglet

Sub titre()
  [A:A].Interior.ColorIndex = xlNone
  Dim R As Range
  If [A1] <> "" Then [A1].Interior.ColorIndex = 4
  For Each R In Range("A2", [A65000].End(xlUp)).SpecialCells(4)
    If R(2, 1) <> "" Then R(2, 1).Interior.ColorIndex = 4
  Next
End Sub

 

[Modeste]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

Re,
Salut job
Salut Si...

Dans le genre qui colore la première ligne et les autres, avec un nombre de lignes vides variable, il y avait aussi cette possibilité (si je ne me trompe pas!?)

Sub couleur()
    For Each pl In [A:A].SpecialCells(xlCellTypeConstants).Areas
        pl.Cells(1, 1).Interior.ColorIndex = 3
    Next pl
End Sub

 

[Si...]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

re

Merci Modeste de me rappeler que je manque d’Aire !
Et dans mon style de découpeur (en long, en large et en travers)

Sub couleur()
  For Each Pl In [A:A].SpecialCells(2).Areas
    Pl(1, 1).Interior.ColorIndex = 2
  Next
End Sub

 

[Evelynetfrancois]

Re : colorer la premiere cellule de chaque groupe de mots (tjrs séparés par une ligne

bonjour tout le monde
merci pour tout votre boulot

j étais parti avec le 1 er cadeau de modeste qui est pas mal du tout et que j avais un peu modifié pour être au top (pour mon classeur)
puis est arrivé une 2° proposition , qui elle est sans faille ...
encore un grand merci
E et F