Microsoft 365 affichage fin de texte dans cellule

[Usine à gaz]

Bonjour à toutes et à tous,
Dans mon fichier de travail, je ne peux pas redimensionner mes cellules ou ajuster selon longueur du texte et nous n'affichons pas la barre de formule.
Je butte sur un simple affichage que je ne parviens pas à faire
Le fichier test joint sera plus explicite que les explications que je pourrais écrire Lol !
Si solution, ce serait génial
Je continue à chercher comment faire.
Avec mes remerciements,
Bon dimanche à toutes et à tous,
Amicalement,
lionel,

 

[sylvanu]

Mais alors dans ce cas là, on peut rajouter du VBA !!!

Je suppose aussi que le double click dans une cellule est interdit aussi ? car il permet de voir tout le texte.

 

[Usine à gaz]

Yes, ça serait super

 

[sylvanu]

Un exemple en PJ.
Si vous cliquez sur une cellule de la colonne B alors un msgbox s'ouvre avec le commentaire présent dans la cellule cliquée.

 

[patricktoulon]

re
met ça dans le module de la feuille concernée et clique droite sur B8 et reclique droite sur B8

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Address = "$B$8" Then
       Cancel = True
       With [B8]
            If .Comment Is Nothing Then
                .AddComment
                .Comment.Visible = False
                .Comment.Text Text:=.Value
                .Value = Replace(.Value, Split(.Value, "OUI + OK RDV SPV / a mis 1ag à 200m ")(0), "")
            Else
                .Value = .Comment.Text
                .Comment.Delete
            End If
        End With
   else
cancel=false
   End If
End Sub

 

[Usine à gaz]

Re-Sylvanu,
très bonne solution et ça marche. je t'en remercie

Re-Patrick,
Super aussi et ça marche nickel. Un grand merci à toi aussi
Mais je ne retire pas mon msg précédent LOL

Je pense que vos solutions pour cette possibilité vont intéresser d'autres utilisateurs qui n'auront ainsi pas besoin de modifier quoi que ce soit dans leurs fichiers.
Merci à vous deux
lionel,

 

[sylvanu]

Joli Patrick.
Une variante (dérivée) où on voit tout le commentaire :

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Address = "$B$8" Then
       Cancel = True
       With [B8]
            If .Comment Is Nothing Then
                .AddComment
                .Comment.Visible = False
                .Comment.Text Text:=.Value
                .Comment.Shape.ScaleWidth 2.58, msoFalse, msoScaleFromTopLeft
                .Comment.Shape.ScaleHeight 2.15, msoFalse, msoScaleFromTopLeft
            Else
                .Value = .Comment.Text
                .Comment.Delete
            End If
        End With
   Else
Cancel = False
   End If
End Sub

 

[Usine à gaz]

Merci Sylvanu,
Super aussi mais je préfère ta 1ère version car il n'y a pas de commentaire dans la cellule et vu le nombre de ligne à cliquer, si on double les clics ... on devient gâteux LOl
lionel

 

[job75]

Bonsoir Lionel, sylvanu, patricktoulon,

Tu n'as pas encore compris Lionel que c'est en multipliant les gadgets qu'on crée une usine à gaz ?

Mais bon tu fais ce que tu veux, en voici encore un avec ce code dans ThisWorkbook :

Private Sub Workbook_Open()
Workbook_SheetActivate ActiveSheet
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If TypeName(Sh) <> "Worksheet" Then Exit Sub
ActiveCell.Activate
Workbook_SheetSelectionChange ActiveSheet, Selection
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Dim s As Boolean, a
s = Me.Saved 'mémorise l'état
a = Split(CStr([mem]), Chr(1))
If UBound(a) > 0 Then Evaluate(a(0)).RowHeight = a(1)
Me.Names.Add "mem", Target(1).Address(External:=True) & Chr(1) & Target(1).RowHeight
If s Then Me.Saved = True 'évite l'invite à la fermeture si aucune modification
End Sub

Sub Afficher()
'se lance par les touches Ctrl+A
ActiveCell.Activate
Selection(1).Rows.AutoFit 'ajustement hauteur
End Sub

A+

 

[Usine à gaz]

Bsr Gérard,
merci encore une fois pour ton code et comme toujours super

OUI, je sais Lol mon usine à gaz mais qui fonctionne de mieux en mieux.
A moi de bien utiliser et à bon escient les codes supers qui me sont envoyés ainsi que les tiens.
Bientôt, mon usine à gaz sera un "bijou"
Merci Gérard
Bonne nuit à toi et au Forum
lionel,