Trouver la valeur inférieure ou supérieure la plus proche recherchev

[aeque]

Bonsoir le fofo

Encore une fois j'ai grandement besoin de vos lumières.

Dans mon tableau, j'utilise la fonction recherchev (cellules pourcentage en gris). Tout fonctionne bien sauf qu'Excel trouve pas défaut la valeur inférieure la plus proche.

En G5 j'ai 465000 excel me trouve bien une correspondance 60%. Mais vu que 465000 est proche de 467004 j'aimerai qu'il me trouve 70%.

Note: si au lieu de 465000 en G5 j'avais 460000 la valeur 60% serait là bonne

En fait j'aimerai que selon ma valeur en G5 on trouve la correspondance la plus proche (inférieure ou supérieure)

Je ne sais pas du tout si je suis clair, mais je pense qu'avec ce fichier ca devrait aider

Merci

 

[mth]

Re : Trouver la valeur inférieure ou supérieure la plus proche recherchev

Bonsoir aeque,

une formule de Jean-Marie:

=SI(G5<$R$6;"0";INDEX($Q$6:$Q$16;EQUIV(G5+SI(ABS(PETITE.VALEUR($P$6:$P$16;NB.SI($P$6:$P$16;"<=" &G5))-G5)>PETITE.VALEUR($P$6:$P$16;NB.SI($P$6:$P$16;"<"&G5)+1)-G5;PETITE.VALEUR($P$6:$P$16;NB.SI($P$6:$P$16;"<"&G5)+1)-G5;PETITE.VALEUR($P$6:$P$16;NB.SI($P$6:$P$16;"<="&G5))-G5);$P$6:$P$16;0)))

cf le fil d'origine ici: https://www.excel-downloads.com/threads/trouver-une-valeur-proche-dans-une-colonne.30059/

Bonne soirée/nuit,

mth

 

[hoerwind]

Re : Trouver la valeur inférieure ou supérieure la plus proche recherchev

Bonjour, salut mth,

Autre approche, en F5 :

=SI(E5>$P$16;$Q$16;SI(E5<$P$6;0;INDEX($Q$6:$Q$16;EQUIV(E5;$P$6:$P$16)+(E5-INDEX($P$6:$P$16;EQUIV(E5;$P$6:$P$16))>INDEX($P$6:$P$16;EQUIV(E5;$P$6:$P$16)+1)-E5)*1)))

formule à copier en H5, J5, L5

Voir la pièce jointe.

 

[Monique]

Re : Trouver la valeur inférieure ou supérieure la plus proche recherchev

Bonjour,

Une autre

En F5 :

=SI(E5<$P6;0;MIN(SI(ABS($P6:$P16-E5)=MIN(ABS($P6:$P16-E5));$Q6:$Q16)))

(défusionner les cellules, coller la formule, valider par ctrl, maj et entrée et refusionner)

Edit - La condition ne sert à rien

=MIN(SI(ABS($P6:$P16-E5)=MIN(ABS($P6:$P16-E5));$Q6:$Q16))

 

[aeque]

Re : Trouver la valeur inférieure ou supérieure la plus proche recherchev

Merci beaucoup!!!!!! vos solutions correspondent exactement à ma recherche!!!!

Encore une fois merci!