Tri automatique dans plusieurs feuille

[titom59280]

Bonjour a tous,

J'aimerais savoir si il été possible d'effectuer un tri automatique d'une feuille sur plusieurs autres feuille.

Je vous explique plus précisément mon souhait :

imaginons que sur la feuille 1 nous ayons 3 colonnes :
colonne A des noms de personnes
colonne B des numéro de téléphone
colonne C des codes postaux

ce que j'aimerais c'est que le tri se fasse sur les codes postaux, en gros tous les données des personnes qui habitent dans la même ville ce copie dans une autre feuille intitulé avec la même donnée que le code postal et ainsi de suite.

est ce réalisable?

Merci a tous pour votre aide

 

[Staple1600]

Re : Tri automatique dans plusieurs feuille

Bonjour à tous

titom59280
Oui c'est réalisable
mais pas avant que tu ais joint un fichier exemple dans ta discussion.
Allez zou au boulot (parce qu'il faut anonymiser ton fichier si besoin avant de le poster ici)

PS: Tu peux aussi faire des recherches (grâce à la loupe en haut à droite) car ce genre de question a déjà été traité sur le forum.
Donc tu trouveras dans les archives des exemples de solutions qui pourraient t'aider ou t'inspirer.

 

[titom59280]

Re : Tri automatique dans plusieurs feuille

Voici en fichier joint ce que j'aimerais obtenir

 

[Staple1600]

Re : Tri automatique dans plusieurs feuille

Re

Merci pour le fichier exemple, mais là il est l'heure de déjeuner.
Donc je je repasse un peu plus tard.
Sinon tu as fais des recherches avec la loupe?

 

[titom59280]

Re : Tri automatique dans plusieurs feuille

oui je suis sur les autres discussion qui pourrait avoir un lien avec ma demande mais pour le moment rien qui pourrait m'aider je continu dans tous les cas.

Merci pour ton aide en tous cas

 

[Staple1600]

Re : Tri automatique dans plusieurs feuille

Re


Tu étais tombé sur ce fil?
Regardes ma proposition (à adapter car ici on créait un classeur au lieu d'une feuille)
https://www.excel-downloads.com/threads/macro-qui-eclate-un-tableau-en-plusieurs-fichier.141554/

EDITION: Il aussi cette proposition de JB (à adapter également)
https://www.excel-downloads.com/threads/ventiler-mon-fichier-xls-en-plusieurs-fichiers-xls.115355/

 

[titom59280]

Re : Tri automatique dans plusieurs feuille

J'ai regarder ton deuxiéme lien est c'est exactement ce dont j'ai besoin merci encore pour ton aide

 

[JCGL]

Re : Tri automatique dans plusieurs feuille

Bonjour à tous,

Très en retard mais j'avais commencé avant le déjeuner...

Option Explicit
Sub CP()
    Dim Sh As Worksheet
    Dim Cel As Range
    Dim DerLig As Long
    With Application
        .DisplayAlerts = False
        '.ScreenUpdating = False
    End With
    For Each Sh In Sheets
        If Sh.Name <> "Data" And Sh.Name <> "Modèle" Then
            Sh.Delete
        End If
    Next Sh
    Sheets("Modèle").Visible = True
    With Sheets("Data")
        Columns("A:C").Select
        .Sort.SortFields.Clear
        .Sort.SortFields.Add Key:=Range("C2:C10000"), _
                             SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .Sort.SetRange Range("A1:C10000")
        .Sort.Header = xlYes
        .Sort.MatchCase = False
        .Sort.Orientation = xlTopToBottom
        .Sort.SortMethod = xlPinYin
        .Sort.Apply
        Range("A1").Select
        DerLig = .[A65000].End(xlUp).Row
        .Range("A1:C" & DerLig).Name = "Base"
        .[Z1] = .[C1]
        .Range("C1:A" & DerLig).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=.Range("Z1"), Unique:=True
        For Each Cel In .Range("Z2:Z" & .[Z65000].End(xlUp).Row)
            If Cel.Value <> "" Then
                .[Z2] = Cel.Value
                Sheets("Modèle").Copy After:=Sheets(Sheets.Count)
                ActiveSheet.Name = Cel.Value
                .Range("Base").AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=.Range("Z1:Z2"), _
                                              CopyToRange:=Range("A1:C1"), Unique:=False
                ActiveSheet.Cells.EntireColumn.AutoFit
            End If
            Cells(1, 1).Select
        Next Cel
        .Columns(26).Clear
        .Select
    End With
    Sheets("Data").[A1].Select
    With Application
        .DisplayAlerts = True
        .ScreenUpdating = True
    End With
    Sheets("Modèle").Visible = False
End Sub

A+ à tous

 

[BOISGONTIER]

Re : Tri automatique dans plusieurs feuille

Bonjour,

Sub Extrait()
  Set f = Sheets("Data")
  Application.DisplayAlerts = False
  Application.ScreenUpdating = False
  '--- Liste des services
  f.[A1:C10000].AdvancedFilter Action:=xlFilterCopy, CopyToRange:=f.[G1], Unique:=True
  For Each c In f.Range("G2:G" & f.[G65000].End(xlUp).Row) ' pour chaque service
    f.[G2] = c.Value
    On Error Resume Next
    Sheets(CStr(c.Value)).Delete
    On Error GoTo 0
    Sheets.Add After:=Sheets(Sheets.Count) ' création
    ActiveSheet.Name = c.Value
    '-- extraction
    f.[A1:C10000].AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=f.[G1:G2], CopyToRange:=[A1]
  Next c
End Sub