XL 2013 Top 10 Actions prioritaires

[Jeykwo]

Bonjour,

Ci-joint un template de suivi de projet.
Dans la feuille action items le but est de lister les action avec différentes caractéristiques et notamment l'échéance (Due Date) et le statut (Status).

Mon but serait de faire apparaitre dans la feuille Dashboard dans l'emplacement "Top Priority Actions"
Les 10 prochaines actions.
Du coup il faudrait faire apparaitre les 10 actions dont le status n'est pas "FINALIZED" avec la DUE DATE la plus faible...
Le champ à faire remonter est la colonne B de la feuille Action Items. Car a partir de la je pourrai faire une recherchev

Je n'arrive pas à m'en sortir

Merci beaucoup à vous pour votre aide et vos conseils.

Jeykwo

 

[CISCO]

Bonjour

Cf. en pièce jointe, avec une formule matricielle à valider avec les 3 touches Ctrl+maj+entrer, valable (je l'espère), pour un tableau allant jusqu'à la ligne 100 uniquement. J'ai mis des +LIGNE(....)/1000 pour différencier les actions ayant la même DUE DATE.

@ plus

 

[Jeykwo]

Hello Cisco !

Merci beaucoup !
Par contre cela remonte le "Type" alors que j'aimerai faire remonter le N° de l'action ?
J'avoue avoir du mal à cerner ta formule ))

 

[CISCO]

Rebonjour

Il suffit que tu remplaces INDEX('ACTION ITEMS'!C$1:C$100; dans la formule par INDEX('ACTION ITEMS'!B$1:B$100;, toujours en validant ensuite avec les 3 touches Ctrl+maj+entrer.

@ plus

 

[Jeykwo]

C'est nickel !
merci beaucoup !
Si je dépasse les 100 lignes je remplace tes 100 par 200?

 

[CISCO]

Re

1) Une petite explication :
Histoire de faire plus court, j'ai changé le nom de la première feuille. On a :

SIERREUR(INDEX(ACT!B$1:B$100;MIN(SI(PETITE.VALEUR(SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100)+LIGNE($6:$100)/1000;LIGNES($1:1)+NB.SI(ACT!K$6:K$100;"="&"FINALIZED")+NB.SI(ACT!K$6:K$100;""))=SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100+LIGNE($6:$100)/1000);LIGNE(ACT!J$6:J$100))));"")

SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100)+LIGNE($6:$100)/1000 liste les DUE DATE + n° de la ligne /1000. Pour les actions non finalisées, cela donne des nombres relatifs grands, et pour les FAUX (obtenus à cause du SI) et les cellules vides de la plage ACT!J$6:J$100 , cela renvoie des nombres commençant par 0,.

PETITE.VALEUR(SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100)+LIGNE($6:$100)/1000;LIGNES($1:1)+NB.SI(ACT!K$6:K$100;"="&"FINALIZED")+NB.SI(ACT!K$6:K$100;"")) renvoie la plus petite de ces valeurs, ne commençant pas par 0,.. grace au NB.SI(ACT!K$6:K$100;"="&"FINALIZED")+NB.SI(ACT!K$6:K$100;"") qui compte toutes les cellules contenant le terme FINALIZED ou du vide (elles renvoient 0,..., donc elles ne nous intéressent pas).

SI(PETITE.VALEUR(SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100)+LIGNE($6:$100)/1000;LIGNES($1:1)+NB.SI(ACT!K$6:K$100;"="&"FINALIZED")+NB.SI(ACT!K$6:K$100;""))=SI(ACT!K$6:K$100<>"FINALIZED";ACT!J$6:J$100+LIGNE($6:$100)/1000);LIGNE(ACT!J$6:J$100))) renvoie une liste de FAUX et le n° de la ligne contenant la DUE DATE + LIGNE(...)/1000

MIN(....) ne renvoie que le n° de cette ligne

INDEX(plage;MIN(....)) renvoie la valeur sur la ligne considérée dans la plage.

2) Oui, tu remplaces les 100 par des 200. Si ton fichier s'agrandit davantage, tu pourras encore utiliser la même méthode, en remplaçant le 200 par le... La méthode fonctionnera tant que le n° de la dernière ligne sera < 1000.

@ plus

PS : Pour comprendre le fonctionnement de la formule, remplaces les 100 par des 13 pour travailler avec une plage plus petite. Ensuite, pour voir les calculs intermédiaires --> Onglet Formules --> Evaluation de formule --> Pas à pas ou Suivant.

@ plus

 

[Dugenou]

Bonjour jeykwo, Cisco,
je l'ai fait donc je le poste : dans le même genre mais au prix d'une colonne ajoutée (qui fait la différence entre le maître et le petit padawan que je suis )
Cordialement

 

[Jeykwo]

Merci pour les explications ! c'est beaucoup plus clair !

Et merci Dugenou