SVP confirmation : rechercheV et valeur arrondie supérieure

[ju_fra]

re bonjour,


J'ai un souci, avec rechercheV:

si ma cellule cible affiche une valeur qui n'est pas dans mon tableau
Alors RechercheV cherche systematiquement "la valeur inferieure la plus proche" a ma cellule cible

Or je veux fonctionner par seuil, c'est a dire que rechercheV chercher "la valeur superieure la plus proche" !

J'ai passé 3h dessus, j'ai trouvé une fonction qui marche mais qui est lourde

=RECHERCHEV(C7;$E$13:$F$23;2;VRAI)+SI(INDEX($E$13:$F$23;EQUIV(RECHERCHEV(C7;$E$13:$F$23;2;VRAI);$F$13:$F$23;1);1)=C7;0;1)

n'y a t'il pas plus simple ??? (Sans VBA)

MERCI !

 

[Monique]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

Fais un essai comme ça :

=INDEX(F13:F23;EQUIV(C7-1/10000;E13:E23;1)+1)

 

[ju_fra]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Ralala merci bcp !!!

En plus, cette fonction dépasse largement la mienne, puisque la mienne ne fonctionnait qu'a condition que la valeur a rapporter ne soit incrementée que de maniere simple (+1 ou +2 ... )


Vraiment merci !

Maintenant ... il faut que je comprenne le sens de votre formule ( sa logique )

 

[ju_fra]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Compris !

remarquez que cette formule ne fonctionne qu'a la condition que la premiere colonne soit classée dans l'ordre croissant ( puisque vous programmé un +1, qui dit en fait rajouter 1 au numéro de colonne renvoyé par equiv).

Ca fonctionne dans mon cas, c'est tres bien et je vous remercie, mais mon esprit de "doctrinisateur" me pousse a vous demander s'il existe une formule qui renvoie la valeur sans que le tableau soit classé !

merci par avance !

 

[job75]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonsoir ju fra,

Monique a du aller faire dodo.

Cette formule fonctionne même si la colonne E n'est pas classée :

=INDEX(F13:F23;EQUIV(MIN(SI(E13:E23>=C7;E13:E23));E13:E23;0))

Formule matricielle à valider par Ctrl+Maj+Entrée.

Edit : elle fonctionne même si des valeurs alpha sont intercalées parmi les valeurs numériques ou s'il y a des cellules vides, car on utilise l'argument 0 dans EQUIV.

A+

 

[Monique]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

A essayer :

[FONT=Verdana]=MIN(SI(E13:E23>=C7;F13:F23))[/FONT]

Formule matricielle, à valider par ctrl, maj et entrée

 

[ju_fra]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Merci a vous, effectivement cela fonctionne.

C'est dommage que l'on ne puisse pas parametrer "rechercheV" plus simplement.

 

[tibj26]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

bonjour,

Je me permet de relancer ce post, car avec mes connaissances limitées sur excel, je n'arrive pas à appliquer ces formules, de manière à obtenir le resultat voulu.
J'ai cherché partout depuis un bon moment sans comprendre.

Le probleme c'est l'incapacité de la fonction recherchev à trouver une valeur supérieure directement, dommage.
Voici mon probleme, c'est peut etre simple mais...

Le plus simple est que je joigne un fichier, non?

La fonction recherche me donne dans le cas, les mauvais resultats car ne se fixe pas sur le seuil le plus haut.

merci beaucoup!!!

 

[job75]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour tibj26,

Comme les températures en colonne A ont un pas de 0,5 °C utiliser la fonction PLAFOND :

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;1;VRAI)

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;2;VRAI)

qu'on peut d'ailleurs résumer en une seule formule en F3 :

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;COLONNES($F:F);VRAI)

à tirer à droite et vers le bas.

A+

 

[job75]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Re,

Bon OK, en A2 et A3 il y a 0 et 15...

Donc si en colonne E il y a des températures < 15 °C, mettre en F3 la formule :

=RECHERCHEV(PLAFOND(E3;SI(E3<15;15;1/2));$A$2:$B$31;COLONNES($F:F);VRAI)

A+

 

[hoerwind]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour, salut job,

Il y a aussi en G3, formule à copier vers le bas :

=RECHERCHEV(E3+4/10;A$1:B$31;2;1)

4/10 pouvant être remplacé par 0.4 ou 0,4 suivant le type de séparateur décimal

 

[tibj26]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

bonjour.

Génial j'ai adapaté tres légèrement à mon cas reel et ca marche nickel.

Merci à vous, et en plus super réactifs!

bye

 

[mapomme]

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

Si les valeurs de température sont 'rangées' de manière aléatoire, on peut essayer cette formule matricielle en G3:
=INDEX($B$2:$B$31;(EQUIV(MIN(SI($A$2:$A$31-E3>=0;$A$2:$A$31-E3;""));$A$2:$A$31-E3;0)))

Cette formule est une formule matricielle. Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique. Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}. Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.