SOMMESI ou SOMMEPROD ?

[ThomasL]

Bonjour,

Je suis loin d'être un expert en excel, et la je me retrouve dans une impasse.

Pour faire simple :

Au final je cherche un nombre.

J'ai deux colonne A et B, dans A il y a des caractères et dans B des nombres, dans ma formule je voudrais :

1) Repérer dans ma colonne A tout les mots commençant par "Bug" (ça peut être Bug_xxx ou Bug_zzz)

2) Additionner les valeurs de la colonne B correspondant

J'arrive à trouver le nombre de fois que le mot Bug apparait :

=SOMMEPROD((NBCAR(A2:A27)-NBCAR(SUBSTITUE(A2:A27;"Bug";"")))/NBCAR("Bug"))

J'arrive aussi à additionner les valeurs de la colonne B mais je suis obligé de mettre la chaîne de caractère exacte :

=SOMME.SI(A2:A27;"Bug_xxx";H2:H27)

Je cherche sans y parvenir à trouver la somme totale des chiffres contenu dans la colonne B, chiffres qui correspondent au chaîne de caractère commençant par "Bug".


Merci d'avance pour votre aide, si un point ne vous semble pas clair, je reste à proximité pour l'éclaircir.

Thomas

 

[Monique]

Re : SOMMESI ou SOMMEPROD ?

Bonjour,

Fais un essai comme ça :

=SOMMEPROD((GAUCHE(A2:A27;3)="Bug")*1;B2:B27)

 

[Raja]

Re : SOMMESI ou SOMMEPROD ?

Bonjour, Salut Monique,

En complément de la formule de Monique, puisque les données à tester de la colonne A commencent toujours par la chaine "Bug", voici une autre façon d'y arriver par la formule SOMME.SI :

=SOMME.SI(A2:A27;"Bug*";B2:B27)

PS : il me semble que le caractère générique "*" n'est pas accepté par la formule SOMMEPROD.

édit : je profite de féliciter Monique pour son 6000ème message. Bravo, bonne continuation Monique

 

[Monique]

Re : SOMMESI ou SOMMEPROD ?

Re,
Eh oui !
J'allais compléter mon message

 

[ROGER2327]

Re : SOMMESI ou SOMMEPROD ?

Re

Et aussi :

{=SOMME($B$2:$B$27*(1-ESTERR(CHERCHE("Bug*";$A$2:$A$27))))}

ou

=SOMMEPROD($B$2:$B$27;(1-ESTERR(CHERCHE("Bug*";$A$2:$A$27))))

Bonne journée !
ROGER2327

 

[ThomasL]

Re : SOMMESI ou SOMMEPROD ?

Bonjour,

Fais un essai comme ça :

=SOMMEPROD((GAUCHE(A2:A27;3)="Bug")*1;B2:B27)

Merci pour ta réponse monique et l'apport de Raja,

La formule fonctionne, mais le résultat me donne 45 au lieu de 60, sachant que j'ai trois valeurs qui sont concernées: 30, 15, 15

2iéme EDIT : un simple quote s'était glissé devant un de mes nombres, ca fonctionne YATAA !

Je ne vois pas pourquoi il en aurait ajouté que deux sur trois... mais on approche

@Roger : merci Roger mais je n'arrive pas a faire fonctionner tes formules, la première me donne un "#VALEUR !" (j'ai enlevé les accolades, car si ca commence pas par = il me l'affiche en texte) et la deuxième me donne la valeur 0.

Je vais créer un fichier excel avec mon exemple, afin de clarifier ma demande.
Merci encore pour votre aide.


EDIT : En faisant un nouvel exemple sur un nouvelle feuille cela fonctionne...

Avec la formule :

=SOMMEPROD((GAUCHE(A2:A27;3)="Bug")*1;B2:B27)

Je doit surement avoir une erreur dans ma feuille originale, dans tous les cas je vous remercie infiniment !

Bonne journée !

Thomas

 

[ROGER2327]

Re : SOMMESI ou SOMMEPROD ?

Re bonjour ThomasL

Bien que votre problème semble réglé, je reviens sur votre remarque :

(...) j'ai enlevé les accolades, car si ca commence pas par = il me l'affiche en texte (...)

En effet, il ne faut pas mettre les accolades dans l'écriture de la formule. Ces accolades signifient seulement que la formule est matricielle.
Pour utiliser une telle formule, on l'écrit en commençant par le signe =, et on la valide par Ctrl + Maj + Entrée. C'est à cet instant qu'apparaissent les accolades, comme confirmation de la saisie d'une formule matricielle.
D'autre part, j'essaie toujours les formules et les procédures avant de les proposer sur ce forum. Il se peut qu'elles ne donnent pas le résultat escompté, mais elles fonctionnent.
Enfin, comme le prouve l'une des formules, le caractère générique "*" est parfaitement utilisable dans la fonction SOMMEPROD.​

Cordialement,
ROGER2327