Sommeprod avec conditions Excel 2010

[c.leduc12]

Bonjour,

Je suis nouvelle sur les forums et donc je ne suis pas une habituée des ces sites.

Ma question aujourd'hui concerne la fonction sommeprod.
C'est une fonction qui est nouvelle pour moi.
J'ai essayer de l'utiliser comme ceci :

=SOMMEPROD((B2:B623=E2)*(1/(NB.SI(A2:A623,A2:A623))))

mais ça ne fonctionne pas

J'ai un fichier avec plusieurs livraisons sur différentes lignes avec différents code d'articles et quantités.
Cependant, la livraison peut se répété plusieurs fois.
Je veux connaitre le nombre de livraisons différentes (donc sans les doublons) avec comme critère les articles.

Le but à la fin étant de calculer une moyenne de quantité de produit par livraison.

J'ai joint un exemple avec 2 articles mais mon fichier réel en contient une centaine.
(en espérant que ça l'aie fonctionner)

Pour l'article 1 je sais qu'il y a 12 livraisons différentes (étaler sur 28 lignes) pour un total de 590 unités.
Je veux donc que le calcul soit 590/12 et non 590/28.

Est-ce qu'il y a une personne qui pourrais m'aider ?

Merci à l'avance

 

[Denis132]

Re : Sommeprod avec conditions Excel 2010

Bonjour c.leduc12 et bienvenue sur le forum,

Un essai, j'ai essayé comme toi des formules mais ...alors

@+

Denis

 

[c.leduc12]

Re : Sommeprod avec conditions Excel 2010

Bonjour,

Merci, ce que tu as fait fonctionne.

Cependant pour le besoin que j'ai à en faire c'est un peu complexe à utiliser.
J'ai une centaine d'article et je dois faire des comparatif par mois.

Il faudrait donc que j'aie un sommaire de tous les articles et pas seulement aller chercher l'information en sélectionnant article par article.

Merci beaucoup pour l'astuce par contre.

 

[gosselien]

Re : Sommeprod avec conditions Excel 2010

Bonjour,

pas mieux que ça

 

[mapomme]

Re : Sommeprod avec conditions Excel 2010

Bonsoir c.leduc12 et bienvenue sur XLD ,

Un essai avec une formule matricielle à valider par la combinaison des trois touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée.

La formule est en G2; une fois validée par Ctrl+Maj+Entrée, elle peut être recopiée vers le bas.

=SOMME(N(FREQUENCE(SI($B$2:$B$777=E2;EQUIV($A$2:$A$777;$A$2:$A$777;0);"");SI($B$2:$B$777=E2;EQUIV($A$2:$A$777;$A$2:$A$777;0);""))>0))

Edit: bonsoir Denis132, gosselien.

 

[job75]

Re : Sommeprod avec conditions Excel 2010

Bonsoir c.leduc12, Denis132, gosselien, mapomme,

Si comme ici le tableau est trié sur la colonne B la formule en G2 est assez simple :

=SOMMEPROD(1/NB.SI(DECALER(A$1;EQUIV(E2;B:B;0)-1;;NB.SI(B:B;E2));DECALER(A$1;EQUIV(E2;B:B;0)-1;;NB.SI(B:B;E2))))

Fichier joint.

Bonne fin de soirée.

 

[job75]

Re : Sommeprod avec conditions Excel 2010

Re,

Si le tableau n'est pas trié la formule en G2 est plus simple mais matricielle :

=NB(LN(EQUIV(A$1:A$623;SI(B$1:B$623=E2;A$1:A$623);0)=LIGNE(A$1:A$623)))

A valider par Ctrl+Maj+Entrée.

Fichier (2).

Bonne nuit.

 

[job75]

Re : Sommeprod avec conditions Excel 2010

Bonjour le fil, le forum,

Complément pour un tableau non trié.

Si en colonne A les numéros sont toujours numériques on peut éviter la validation matricielle :

=SOMMEPROD(N(ESTNUM(LN(EQUIV(A$1:A$1000;(B$1:B$1000=E2)*A$1:A$1000;0)=LIGNE(A$1:A$1000)))))

Fichier (2 bis).

Bonne journée.

 

[job75]

Re : Sommeprod avec conditions Excel 2010

Re,

J'ai mesuré les durées d'exécution de la formule en G2 :

- post #5 de mapomme (avec 623 au lieu de 777) => 10 millisecondes

- post #6 fichier (1) => 57 millisecondes

- posts #7 et #8 (avec 623 au lieu de 1000) => 4 millisecondes.

A+

 

[c.leduc12]

Re : Sommeprod avec conditions Excel 2010

Bonjour tout le monde !!
Merci énormément pour vos réponse !!
J'ai réussi à obtenir le résultat que je voulais.
Merci beaucoup de votre aide

Bonne journée