Somme glissante

[Engue]

Bonjour

Je voudrais faire une somme d'une plage de valeurs qui change en fonction de la valeur d'une cellule
Je fais la comptabilité de ma copropriété, dans la feuille solde les recettes sont la somme dune plage 12*4
Mais cette plage décale tous les ans de 4

J'aimerai la faire dépendre de la cellule B1 de la feuille 1 (Si B1=2012 alors la somme(D6:G17) si B1=2013 alors la somme(H6:K17) et ainsi de suite

Merci davance

 

[JBARBE]

Re : Somme glissante

Bonsoir,

tu peux mettre cette formule dans la feuille SOLDE cellule B5

=SI(ET(B4=Feuil1!B1;B4=Recettes!D5);SOMME(Recettes!D6:G17);SI(ET(B4=Feuil1!B1;B4=Recettes!H5);SOMME(Recettes!H6:K17);SI(ET(B4=Feuil1!B1;B4=Recettes!H5);SOMME(Recettes!L6:O17);"")))

Nota : cette formule va jusqu'en 2014 comme ton exemple, pour aller au delà il suffit de la prolonger !

 

[JBARBE]

Re : Somme glissante

Celle-ci jusqu’en 2017

=SI(ET(B4=Feuil1!B1;B4=Recettes!D5);SOMME(Recettes!D6:G17);SI(ET(B4=Feuil1!B1;B4=Recettes!H5);SOMME(Recettes!H6:K17);SI(ET(B4=Feuil1!B1;B4=Recettes!H5);SOMME(Recettes!L6:O17);SI(ET(B4=Feuil1!B1;B4=Recettes!P5);SOMME(Recettes!P6:S17);SI(ET(B4=Feuil1!B1;B4=Recettes!T5);SOMME(Recettes!T6:W17);SI(ET(B4=Feuil1!B1;B4=Recettes!X5);SOMME(Recettes!X6:AA17);""))))))

 

[Mytå]

Re : Somme glissante

Salut le forum

Avec la fonction DECALER

=SI(ESTNUM(EQUIV($B$4;Recettes!$D$5:$O$5;0)-1);SOMME(DECALER(Recettes!$D$6;0;4*($B$4-Recettes!$D$5);12;4));"N/A")

Mytå

 

[frangy]

Re : Somme glissante

Bonjour,

J'aurais bien vu quelque chose comme ça

=SOMME((DECALER(Recettes!D6;0;(Feuil1!B1-2012)*4) :DECALER(Recettes!G17;0;(Feuil1!B1-2012)*4)))

Cordialement.

 

[Mytå]

Re : Somme glissante

Re le forum

JBARBE, ta formule contient deux fois la même condition.

SI(ET(B4=Feuil1!B1;B4=Recettes!H5)

Mytå

 

[JBARBE]

Re : Somme glissante

En effet on peut se contenter de la cellule "B4=Recettes!D5" qui fait référence à la cellule B1 de la Feuille 1!

Je n'avais pas remarqué la formule dans B4 ( =Feuil1!B1)!

=SI(B4=Recettes!D5;SOMME(Recettes!D6:G17);SI(B4=Recettes!H5;SOMME(Recettes!H6:K17);SI(B4=Recettes!L5;SOMME(Recettes!L6:O17);SI(B4=Recettes!P5;SOMME(Recettes!P6:S17);SI(B4=Recettes!T5;SOMME(Recettes!T6:W17);SI(B4=Recettes!X5;SOMME(Recettes!X6:AA17);SI(B4=Recettes!AB5;SOMME(Recettes!AB6:AE17);SI(B4=Recettes!AF5;SOMME(Recettes!AF6:AI17);SI(B4=Recettes!AJ5;SOMME(Recettes!AJ6:AM17);"")))))))))

formule jusqu'en 2020 qui peut-être prolongée !

 

[nicho]

Re : Somme glissante

salut a vous tous, voila ton fichier que j'ai un bidouiller tu peut aller jusqu'à la colonne zz (tu en a pour plusieurs années )

Regarde la pièce jointe Karina(2).xlsx

 

[JBARBE]

Re : Somme glissante

sans vouloir me quereller avec tout le monde car ils ont fait un gros travail, je pense que la solution de FRANGY

=SOMME((DECALER(Recettes!D6;0;(Feuil1!B1-2012)*4) :DECALER(Recettes!G17;0;(Feuil1!B1-2012)*4)))

est la meilleur après avoir tout testé et compte tenu qu'elle est simple d'emploi et sans erreur qui s'affiche !

Désolé pour moi et les autres !

Bonne soirée !

 

[Mytå]

Re : Somme glissante

Re le forum

JBARBE, essaye avec 2009 en B1 de la Feuille 1 et un beau #REF apparaît avec la formule de FRANGY

Ma formule permet au moins de gérer cette erreur la en affichant N/A (Facilement remplaçable)

=SI(ESTNUM(EQUIV($B$4;Recettes!$D$5:$O$5;0));SOMME(DECALER(Recettes!$D$6;0;4*($B$4-Recettes!$D$5);12;4));"N/A")

Mytå

 

[mapomme]

Re : Somme glissante

Bonjour à tous,

Et hop! une autre:

=SOMME(DECALER(Recettes!D6:G17;0;4*(Feuil1!B1-2012)))

ou

=SOMME(DECALER(Recettes!D6:G17;0;EQUIV(Feuil1!B1;Recettes!D5:ZZ5;0)-1))

 

[JBARBE]

Re : Somme glissante

 

[Engue]

Re : Somme glissante

Merci beaucoup!!