Si imbriquer multi-condition

[ALEXCEL]

Bonjour à tous,

J'avais imbriquer des fonctions SI et je me suis rendu compte que seulement les deux premières fonctionnent, la dernière n'est pas pris en compte :
=(SI(OU(G6=9;G6=31;G6>=55);A26+G6;(SI(OU(8>=G6;30>=G6>=15;51>=G6>=43);C26+G6;(SI(OU(14>=G6>=10;42>=G6>=32;54>=G6>=52);B26+G6)))))

En gros, cette formule fonctionne pour :
=(SI(OU(G6=9;G6=31;G6>=55);A26+G6;(SI(OU(8>=G6;30>=G6>=15;51>=G6>=43);C26+G6)

Avez vous une explication ou une solution?

Merci

ALEXCEL

 

[ALEXCEL]

Re : Si imbriquer multi-condition

J'ai essayé en remplaçant un OU par un ET :
=(SI(OU(G6=9;G6=31;G6>=55);A26+G6;(SI(ET(8>=G6;30>=G6>=15;51>=G6>=43);C26+G6;(SI(OU(14>=G6>=10;42>=G6>=32;54>=G6>=52);B26+G6)))))

Mais la formule ne fonctionne pas correctement ni pour 30>=G6>=15 ni pour 51>=G6>=43

 

[supercrapaud]

Re : Si imbriquer multi-condition

un petit fichier pour voir ? Que souhaites-tu faire en fait ?

 

[ALEXCEL]

Re : Si imbriquer multi-condition

En fait je rentre une valeur en G6, J'obtiens alors trois résultats différents en A26,B26 et C26.

Et en fonction de la valeur rentré en G6 je souhaite utiliser une des trois cellules A26,B26 ou C26 pour le calcul de la cellule E26.

 

[Fred0o]

Re : Si imbriquer multi-condition

Bonjour ALEXCEL, supercrapaud.

ALEXCEL, peux-tu nous donner en clair les conditions que tu souhaites appliquer ? Quand je lis la condiition suivante, je me pose des question !

ET(14>=G6>=10;42>=G6>=32;54>=G6>=52)

Premièrement, EXCEL ne sait pas interpréter une condition du style "14>=G6>=10". Il faut lui décomposer en ET(14>=G6;G6>=10). Ensuite, si je relis littéralement ta condition, tu veux que G6 soit inférieur ou égal à 14 et supérieur ou égal à 10. Jusque là, ça va. Ensuite, il faut qu'il soit également inférieur ou égal à 42 (OK) mais aussi supérieur ou égal à 32 !
Cela n'est pas possible puisqu'il est compris entre 14 et 10 ! En conclusion, ta condition sera toujours fausse.

En attendant d'avoir plus d'éléments

A+

 

[ALEXCEL]

Re : Si imbriquer multi-condition

Bonjour Fred0o,
C'est en effet de ma faute je n'ai pas été très rigoureux, je voulais mettre une sorte de OU (ET) OU....C'est bien une condition en OU qui m'intéresse mais pour les 3 calculs différents.
Merci pour l'information du "14>=G6>=10" , je ne savais pas qu'il fallait décomposer la condition.

 

[Fred0o]

Re : Si imbriquer multi-condition

Bonsoir ALEXCEL,

Essaie donc en décomposant et si tu n'y arrives pas, donnes moe en détail tes conditions pour que je puisse t'aider à construire ta formule.

A+

 

[ALEXCEL]

Re : Si imbriquer multi-condition

Re Bonjour,

J'ai essayé la décomposition mais j'ai toujours deux conditions sur 3 qui fonctionnent
Je rappelle le problème:

Je rentre une valeur en G6, j'ai alors 3 résultats en A26,B26 et C26.
J'ai ensuite un calcul en E26.

Si G6 est égale à 9,31 ou supérieure 55, j'effectue le calcul en E26 avec la valeur de A26.

Si G6 est compris entre 10 et 14, 32 et 42 ou 52 et 54; j'effectue le calcul en E26 avec la cellule B26.

Maintenant si G6 est inférieur à 8 ou compris entre 15 et 30 ou 43 et 51, le calcul devrait utiliser la cellule C26 pour le calcul en E26, mais cela ne fonctionne pas.

J'espère avoir été compréhensible, voir le fichier ci-joint

 

[Fred0o]

Re : Si imbriquer multi-condition

Re-bonsoir ALEXCEL,

J'ai construit la formule que tu souhaitais et elle me semble fonctionner.

=G6+SI(OU(G6=9;G6=31;G6>55);A26;SI(OU(ET(G6>=10;G6<=14);ET(G6>=32;G6<=42);ET(G6>=52;G6<=54));B26;SI(OU(G6<8;ET(G6>=15;G6<=30);ET(G6>=43;G6<=51));C26;"?")))

A toi de le confirmer. Cependant, d'après les critères que tu as donné, il y a 2 valeurs pour lesquelles on ne sait pas quoi faire. Ce sont les valeurs 8 et 55. Adapte la formule à ton besoin.

A+

 

[ALEXCEL]

Re : Si imbriquer multi-condition

Super!! c'est exactement ça! J'avais essayer de rajouter des "ET" mais sans succès
merci!

 

[natorp]

Re : Si imbriquer multi-condition

bonsoir a vous

j'avais trouve ca :

=SI(OU(G6=9;G6=31;G6>=55);A26+G6;SI(G6<=8;C26+G6;SI(G6<=14;B26+G6;SI(G6<=30;C26+G6;SI(G6<=42;B26+G6;SI(G6<=51;C26+G6;SI(G6<=54;B26+G6;"")))))))

cordialement Gerard