SI avec plusieurs imbrications valeurs Vrai

[herve62]

Bonjour
Les formules imbriquées c'est pas trop mon truc ..... je ne sais pas si il y a une méthode pour ne pas oublier un ";" ou "(" ...etc, lorsque c'est à rallonge !!

Je n'ai pas trouvé comment IMBriquer Plusieurs valeurs VRAI ( si cela existe !!)
SI ( condi ; val Vrai1, val Vrai2 , val Vrai3 ; val Faux)

J'ai une cellule ex : C61 ensuite dans 3 cellules D61 , E61 , F61 je dois afficher certains dépassements ( 20, 40,60) suivant la valeurs de C61
1) en D61 je met cette formule pour avoir la valeur Sup à 20 ET INF à 40 , MAIS .... si Sup à 40 il doit y avoir 20
SI(ET(C61>20;C61<=40);C61-20;si(c61>40;c61=20;"");"") > me dit que j'ai trop d'arguments ??

2) En E61 , idem avec C61>40 ET C61<=60 , on garde 20 en D61 et on met le reste , mais si encore Sup à 60 on remet 20 en E61
Là je sais déjà plus quelle formule mettre .... les conditions VRAI se cumulent !!!!!!!

3) En F61 SI D61>60 : on met le supplement mais on garde 20 en D61 , 20 en E61

les 3 cas :
C61 D61 E61 F61
30 ...10
45 ...20.... 5
65 ...20... 20... 5

Merci , je pense qu'il n'y a pas lieu de joindre un fichier !!!!!!

 

[joss56]

Re : SI avec plusieurs imbrications valeurs Vrai

Bonjour,
si j'ai bien compris...!
=si(cellule>40;instruction;si(cellule>20;instruction;instruction)) doit suffire

A+
Jocelyn

 

[herve62]

Re : SI avec plusieurs imbrications valeurs Vrai

Bonjour Jocelyn
Bon ca fait 2h que je cherche et j'ai trouvé ça :
en D61 : SI(ET(C61>20;C61<=40);C61-20;SI(C61<=20;"";20))
en E61 : SI(ET(C61>40;C61<=60);C61-40;SI(C61<=40;"";20))
en F61 : SI(C61>60;C61-60;"")
Ca a l'air de fonctionner
Mais Peut-on mettre plus d'un résultat si VRAI ?

Je n'ai pas trouvé comment IMBriquer Plusieurs valeurs VRAI ( si cela existe !!)
SI ( condi ; val Vrai1, val Vrai2 , val Vrai3 ; val Faux)

 

[JNP]

Re : SI avec plusieurs imbrications valeurs Vrai

Bonjour le fil ,
Dans ta première formule, tu avait 4 conditions alors qu'un si n'en prend que 3 ...
Euh, le SI est-il obligatoire ?
En D61

=(C61>20)*(C61<=40)*(C61-20)+(C61>40)*20

En E61

=(C61>40)*(C61<=60)*(C61-40)+(C61>60)*20

En F61

=MAX(C61-60;0)

Par contre, pas clair du côté de plusieurs valeurs pour Vrai ...
Bonne suite
Ajout : Salut Marc

 

[tototiti2008]

Re : SI avec plusieurs imbrications valeurs Vrai

Bonjour hervé, Bonjour joss,

Ou peut-être

=MIN(20;MAX(C61-20;0))
=MIN(20;MAX(C61-40;0))
=MAX(C61-60;0)

Je n'ai pas trouvé comment IMBriquer Plusieurs valeurs VRAI ( si cela existe !!)

Non, il faut remettre un SI dans le "vrai"

Edit : Bonjour Jean-Noël

 

[Misange]

Re : SI avec plusieurs imbrications valeurs Vrai

Mais Peut-on mettre plus d'un résultat si VRAI ?

Bonjour
Non on ne peut pas. excel connait vrai et faux mais pas "peut être" ou "vrai1" ou "des fois que" ou "ça se pourrait"

Pour la construction des formules imbriquées petites astuces :
on peut dans la barre de formule parfaitement faire des retours chariot comme on le fait dans une cellule en faisant un alt+entrée. Ca permet sur des formules longues de bien séparer les différents arguments. On peut aussi ajouter des espaces pour identifier les blocs.
Quand tu tapes la première parenthèse d'un argument, tape de suite la parenthèse fermante, ça t'évite de compter.
Quand tu écris des formules compliquées, commence par écrire la structure avant de mettre les valeurs de cellules.
Par exemple tu écris dans la barre de formule
=si(test;"valeur si vrai";"valeur si faux")
puis tu remplaces test par
A1=A2
tu valides et tu vois si tu as fait une faute dans ta formule
ensuite tu ajoutes un niveau de complexité par exemple en remplaçant test par un et(A1=A2;A1<100)
puis tu t'attaques au valeur si vrai. Là tu peux remplacer par un second si ou par un recherchev ou ce que tu veux. Mais on n'écrit presque jamais une formule super compliquée sans tester par petits bouts !

 

[herve62]

Re : SI avec plusieurs imbrications valeurs Vrai

Re
Merci à tous .....Miam . Miam
Je vais pouvoir étudier tout cela à tête reposée !!!
Merci Misange pour ta méthode d'écriture de formule ( souvent je pars en VBA)
Sinon

Non on ne peut pas. excel connait vrai et faux mais pas "peut être" ou "vrai1" ou "des fois que" ou "ça se pourrait"

Non c'est du SUR !!! Si Vrai alors : A1=15 , A2=20 ... mais je crois que je dis une "Connnnnerrrie" ( a la Barthez)
On peut pas aller mettre une valeur ailleurs ??

 

[JNP]

Re : SI avec plusieurs imbrications valeurs Vrai

Re ,

On peut pas aller mettre une valeur ailleurs ??

Non, une formule ne peut écrire que dans la cellule où elle est ...
VBA par contre peux ...
Bonne suite

 

[Misange]

Re : SI avec plusieurs imbrications valeurs Vrai

Pour compléter la réponse de Jean Noel
Une formule renvoie une valeur dans la cellule ou elle est écrite
tu peux écrire en B1
=si(A1=2;"vrai";faux")
ça sous entend
=si(A1=2; B1 (là ou tu écris) = vrai;B1=faux)

mais tu ne peux pas écrire
=si(A1=2;B2=4;B2=0)

donc pour tous tes vrais tu es obligé d'écrire toutes les formules dans toutes les cellules concernées.
Ou alors effectivement par VBA.

Je comprends que tu préfères écrire les trucs compliqués en VBA, j'ai fait ça très longtemps car je trouve plus facile de suivre le déroulement d'une macro que de suivre celui d'une formule, même si l'outil d'évaluation de formules st très utile pour ça. Mais l'argument ++ pour les formules c'est que c'est beaucoup plus rapide que le VBA..
Et puis quand tu commences à te prendre au jeu, c'est franchement rigolo.

 

[herve62]

Re : SI avec plusieurs imbrications valeurs Vrai

Ok , merci pour la leçon
mais quand je vois :
=SI(ESTVIDE($A$2);0;SI(L3=0;SI($A$1=1;"123456789";SI((NB.SI(vLigne;$A$1-1)+NB.SI(vColonne;$A$1-1)+NB.SI(vCarre;$A$1-1))>0;SUBSTITUE(V3;$A$1-1;"");V3));L3))
Ca vient d'une infime partie de la résolution de SUDOKU , je trouve pas ça Rigolo !!!! à moins de savoir Jongler avec tout ça !

A+

 

[Misange]

Re : SI avec plusieurs imbrications valeurs Vrai


en fait quand tu as toi même construit des formules compliquées comme ça, ça te fait moins peur de décortiquer celles des autres.