Si avec plusieurs conditions

[Plumette]

Bonjour,

Après plusieurs heures de recherches google et de tests infructueux, je me permet de poser mon problème sur ce forum.

J'ai un fichier excel (excel 2010) où dans 1 onglet, il y a des informations sur des contrats (anciens contrats et contrats récents). Dans un autre onglet, il y a un tableau où j'entre les sommes des factures (heures prestées par nos employés chez des clients).

Dans ce 2ème onglet, je voudrais que lors ce que je tape le nom de la personne dans la colonne B, il me mette automatiquement le numéro de contrat actif dans la colonne A. Le seul moyen de savoir si le contrat est actif, c'est dans le premier onglet, colonne C (Actif/Non-actif).

La dernière formule que j'ai tentée est: =SI(ET(B2<>;RECHERCHEV(B2;Contrats!A:A;Contrats!C:C)=Actif);RECHERCHEV(B2;Contrats!A:A;Contrats!B:B);"") mais Excel me dit qu'elle contient une erreur (mais ne me dit pas où est l'erreur...).

J'espère que ma question est claire, j'ai joint un fichier excel d'exemple.

D'avance merci à ceux qui répondront.

 

[herve62]

Re : Si avec plusieurs conditions

Bonjour
1 : Ou est cette formule ?
2 : ET (condition1 ;.......) la je vois B2<>; C'est quoi la condition ??? il faudrait exemple : B2<>A2 ou ,B2<>"" ....etc

 

[Plumette]

Re : Si avec plusieurs conditions

Je cherche une formule à mettre dans le deuxième onglet, colonne A
Effectivement, j'ai oublié les guillemets après B2<>""

Ma "logique" derrière cette formule est la suivante: Si, dans le deuxième onglet, une information est entrée dans la colonne B, rechercher cette info dans le premier onglet, colonne A, et copier la valeur correspondante de la colonne B du premier onglet dans la colonne A du deuxième onglet si il y a le mot "Actif" dans la colonne C

Merci !

 

[Modeste]

Re : Si avec plusieurs conditions

Bonjour Plumette et bienvenue, bonjour Herve62,

Pour autant que j'aie bien compris et à condition qu'il n'y ait pas de doublons dans les noms et qu'il n'y ait qu'un contrat actif renseigné pour chaque nom, tester cette formule en A2:

=SI(NB.SI(Contrats!$A$2:$A$7;B2)=0;"";INDEX(Contrats!$B$2:$B$7;MIN(SI((Contrats!$C$2:$C$7="Actif")*(Contrats!$A$2:$A$7=B2);LIGNE(Contrats!$B$2:$B$7)-1))))

Valider avec Ctrl+Shift+Enter

 

[JBOBO]

Re : Si avec plusieurs conditions

Bonjour,

Sans certitude :

=INDIRECT("'Base de données'!B"&SOMMEPROD(('Base de données'!$A$2:$A$7=B2)*('Base de données'!$C$2:$C$7="Actif");LIGNE('Base de données'!$B$2:$B$7)))

 

[ralph45]

Re : Si avec plusieurs conditions

Bonjour tout le monde,

A tester en cellule A2 de l'onglet "Formulaire" :

=SI(RECHERCHEV(B2;'Base de données'!$A$2:$C$7;3;FAUX)="Actif";RECHERCHEV(B2;'Base de données'!$A$2:$C$7;2;FAUX);"-")

Explications :
La 1ère formule RECHERCHEV ne va chercher que les personnes dont le contrat est actif.
Si le contrat est actif, la 2ème formule RECHERCHEV va trouver la référence voulue (ici, N° du contrat).

A+

 

[Plumette]

Re : Si avec plusieurs conditions

Bonjour,

Merci à tous pour vos réponses rapides !

J'ai essayé la formule de Modeste dans mon exemple et c'est exactement ce qu'il me fallait (Mille mercis Modeste) ! Je l'essaierai cet après-midi dans le vrai fichier excel.

Bonne journée à tous